Стандарты рисования алгоритмов

rab:            ; основной цикл программы
rab_a:   setb p_fyxed   ; считаем, что точка 0 сразу зафиксирована
rab_b:  mov phase, #0   ; считаем, что клавиши выдачи не нажимались
rab_c:   acall getkey   ; ввод с клавиатуры
push acc
clr c
subb a, #0ah   ; цифра 0-9 ?
pop acc
jnc rab_h   ; нет: 0ah и более - обработка служебных клавиш
rab_c2:   jnb p_fyxed, rab_d   ; продолжается набор адреса
rab_c3:   mov key0, #0   ; начало набора другого адреса
rab_c1: clr p_fyxed   ; начали нажимать цифры - хотят сменить адрес
rab_d:   mov key1,key0   ; была нажата цифра
mov key0, a   ; задвигаем в буфер
rab_e:   mov sym1, key1   ; сюда, чтобы индицировать
mov a, key1   ; символ в десятках 0?
jnz rab_g
rab_f:   mov sym1, #18h   ; вместо ведущего 0 отображаем пробел
rab_g:   mov sym0, key0   ; символы готовы для отображения
acall ind
sjmp rab_c
rab_h:   cjne a, #0dh, rab_h1   ; команда активизации D ?
sjmp rab_h2      ; да - уходим на активизацию точки
rab_h1:   jnb p_fyxed, rab_v   ; если нажимали цифры, то надо нажать D
; любая другая клавиша - сбрасываем в 0
rab_i:   cjne a, #0eh, rab_l   ; нет. это * ?
rab_j:   mov r2, phase      ; да, начало команды выдачи
cjne r2, #0, rab_b   ; если фаза не 0, а снова нажали *, сбрасываем
rab_k:   mov phase, #1      ; да, был 0 и нажата *. Теперь фаза 1.
sjmp rab_c
rab_l:   cjne a, #0ah, rab_o   ; это не *. Может, это A?
rab_m:   mov r2, phase      ; это A
cjne r2, #1, rab_b
rab_n:   mov phase, #2           ; и фаза была 1, значит, переходим в фазу 2
sjmp rab_c
rab_o:   cjne a, #0bh, rab_r   ; это не A. Может, это B?
pab_p:   mov r2, phase      ; это B
cjne r2, #2, rab_b
rab_q:   mov phase, #3           ; и фаза была 2, значит, переходим в фазу 3
sjmp rab_c
rab_r:   cjne a, #0ch, rab_x1   ; это не B. Если это и не C, проверим #.
rab_s:   mov r2, phase      ; если C и фаза была 3, настала пора выдачи
cjne r2, #3, rab_b   ; а если фаза не 3, сбрасываем
rab_t:   acall sompay      ; команда выдачи для POINT
sjmp rab_a
rab_h2:   setb p_fyxed      ; адрес зафиксирован
rab_u:   mov a, key1        ; вычисляем POINT как KEY1*10+KEY0
mov b, #10
mul ab              ; в A число десятков * 10
add a, key0      ; в A адрес точки
mov point, a      ; запоминаем
push acc
clr c
subb a, #40h      ; POINT меньше 64?
pop acc
jc rab_w      ; нормально - уходим активизировать точку
rab_v:   acall inderr      ; слишком большой! - обнуляем POINT
mov point, #0
mov key1, #0
mov key0, #0      ; чтобы не оставалась набранная ранее цифра
mov sym1, #18h
mov sym0, #0
acall ind         ; отображаем _0.
acall somact      ; выключаем все точки
ajmp rab_c      ; продолжаем работу
rab_w:   acall somact      ; активизируем точку POINT
sjmp rab_e      ; уходим на индикацию и далее снова ввод
rab_x1:   cjne a, #0fh, rab_x4   ; если код # не опознан, продолжаем
rab_x2:   acall getpass      ; было нажато # - набор пароля
jnz rab_x3
ajmp rab_v      ; в аккумуляторе 0 - пароль не опознан
rab_x3:   dec a
jz outstat              ; 1 - введен пароль для распечатки
dec a
jz risitstat      ; 2 - введен пароль для обнуления
rab_x4:   ajmp rab_c      ; код возврата не опознан - ошибка процессора
risitstat:
mov r2, #1      ; начинаем с точки 1 - двоичное число
mov r3, #1      ; десятичное число для индикации
mov r5, #63      ; всего 63 точки
res_1:   mov a, r3
push acc
anl a, #0f0h      ; старшая цифра на индикатор десятков
swap a
mov sym1, a
pop acc
anl a, #00fh      ; младшая цифра
mov sym0, a
acall ind      ; отображаем номер точки
mov r4, #5      ; передаем команду 5 раз для тех, кто в танке
res_2:   mov sbuf, r2      ; передать адрес точки
jnb ti, $
clr ti
mov sbuf, #0f4h      ; F4 команда обнулить статистику
jnb ti, $
clr ti
djnz r4, res_2
yms r2         ; следующая точка
mov a, r3
clr c
clr ac
add a, #1
da a
mov r3, a
mov a, #1
acall zadr      ; пауза 70 мс перед следующей точкой
djnz r5, res_1
ajmp rab_e      ; конец - высветить адрес точки из KEY1,0
;-) -----------------------------------------------------------------------