Фильтрация по полям

Private Sub FormRefilter()
'Рефильтр Формы.
'
'--------------------------------------------------------------------------
  
Dim s$
 
 
On Error GoTo FormRefilter_Err
 
'фильтр по датам (не универсальный пока - дабы не запутывать ТС)
    If IsNull(Me!datas) = False And IsNull(Me!datae) = False Then 'указаны обе даты
        'Фильтрация по обоим полям
        s = " AND data Between " & Format(Me!datas, "\#mm\/dd\/yyyy\#") & " AND " & Format(Me!datae, "\#mm\/dd\/yyyy\#")
    
    Else 'указана только одна из дат
        If IsNull(Me!datas) = False Then
            s = " AND data >= " & Format(Me!datas, "\#mm\/dd\/yyyy\#")
        End If
        If IsNull(Me!datae) = False Then
            s = " AND data <= " & Format(Me!datae, "\#mm\/dd\/yyyy\#")
        End If
    End If
 
'фильтр по фамилии
    If IsNull(Me!txtF) = False Then
        s = s & " AND [f] = '" & Me!txtF & "'"
    End If
   
 'фильтр по Дело
    If Me!txtDelo.ListIndex <> -1 Then 'значение выбрано в списке ....
        s = s & " AND delo = '" & Me!txtDelo & "'"
    End If
   
   
    If Len(s) > 5 Then
      s = Mid(s, 6)
      Me.Filter = s
      Me.FilterOn = True
    Else
      Me.Filter = ""
      Me.FilterOn = False
   End If
    
    'Debug.Print s
 
 
 
FormRefilter_Bye:
    Exit Sub
 
FormRefilter_Err:
    MsgBox "Error: " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
    "in Sub: FormRefilter in module: Form_dats", vbCritical, "Error in Application"
    Err.Clear
    Resume FormRefilter_Bye
End Sub