Получить URL из тега HTML

Option Explicit
Dim oFSO, oDict, oHTTP, oHTML, F, i, iURL, Arr, URL, Name, BName, Ext
'—————————————————————————————————————————————————————————————————————
Const URI = "https://www.cinematerial.com/movies/"
Const Adr = "slums-of-beverly-hills-i120831 north-by-northwest-i53125"
'—————————————————————————————————————————————————————————————————————
Set oFSO  = CreateObject("Scripting.FileSystemObject")
Set oDict = CreateObject("Scripting.Dictionary")
Set oHTTP = CreateObject("MSXML2.XMLHTTP.6.0")
Set oHTML = CreateObject("htmlfile")
oHTML.designMode = "on"
 
For Each F in Split(Adr)
  oHTTP.Open "GET", URI & F, False: oHTTP.Send
  oHTML.Write oHTTP.ResponseText: oHTTP.Abort
  For Each iURL in oHTML.links
     If InStr(iURL, "about:") = 1 Then
        iURL = "https://www.cinematerial.com" & Replace(Replace(iURL, "about:blank", ""), "about:", "")
        If InStr(iURL, URI & F & "/p/") = 1 Then oDict.Add iURL, Empty
     End If
  Next
  oHTTP.Abort: Arr = Split(F, "-")
  If oDict.Count Then
     F = Replace(F, "-" & Arr(UBound(Arr)), "")
     If Not oFSO.FolderExists(F) Then oFSO.CreateFolder F
     For Each iURL in oDict.Keys
        oHTTP.Open "GET", iURL, False : oHTTP.Send
        oHTML.Write oHTTP.ResponseText: oHTTP.Abort
        For Each i In oHTML.getElementsByTagName("meta")
           If i.getAttribute("property") = "og:image" Then URL = i.getAttribute("content"): Exit For
        Next: oHTML.Close
        URL = Left(URL, InStrRev(URL, "?") - 1)
        oHTTP.Open "GET", URL, False: oHTTP.Send
        Name = oFSO.GetFileName(URL): BName = oFSO.GetBaseName(Name)
        Ext  = oFSO.GetExtensionName(Name): i = 0
        While oFSO.FileExists(oFSO.BuildPath(F, Name))
           i = i + 1: Name = BName & "_" & i & "." & Ext
        Wend
        With CreateObject("SAPI.SpFileStream")
           .Format.Type = 1: .Open oFSO.BuildPath(F, Name), 3: .Write oHTTP.ResponseBody: .Close
        End With
        oHTTP.Abort
     Next
  End If
  oDict.RemoveAll
Next
MsgBox "Скачивание завершено!", 4160, " Скачивание постеров"
For Each i in Array(oDict, oHTTP, oHTML, oFSO)
  Set i = Nothing
Next

Option Explicit
Dim oFSO, oDict, oHTTP, oHTML, n, i, iURL, Arr, URL, Name, BName, Ext
'——————————— Номера на концах адресов страниц с постерами ———————————
Const Num = "120831 53125 94082 107822"
'————————————————————————————————————————————————————————————————————
Set oFSO  = CreateObject("Scripting.FileSystemObject")
Set oDict = CreateObject("Scripting.Dictionary")
Set oHTTP = CreateObject("MSXML2.XMLHTTP.6.0")
Set oHTML = CreateObject("htmlfile")
oHTML.designMode = "on"
 
For Each n in Split(Num)
  oHTTP.Open "GET", "https://www.cinematerial.com/movies/0-i" & N, 0: oHTTP.Send
  oHTML.Write oHTTP.ResponseText: oHTTP.Abort
  For Each iURL in oHTML.links
     If InStr(iURL, "about:") = 1 Then
        iURL = "https://www.cinematerial.com" & Replace(Replace(iURL, "about:blank", ""), "about:", "")
        If InStr(iURL, "/p/") Then oDict.Add iURL, Empty
     End If
  Next
  If oDict.Count Then
     N = Split(oHTML.Title, ")")(0) & ")"
     If Not oFSO.FolderExists(N) Then oFSO.CreateFolder N
     For Each iURL in oDict.Keys
        oHTTP.Open "GET", iURL, False : oHTTP.Send
        oHTML.Write oHTTP.ResponseText: oHTTP.Abort
        For Each i In oHTML.getElementsByTagName("meta")
           If i.getAttribute("property") = "og:image" Then URL = i.getAttribute("content"): Exit For
        Next: oHTML.Close
        URL = Left(URL, InStrRev(URL, "?") - 1)
        oHTTP.Open "GET", URL, False: oHTTP.Send
        Name = oFSO.GetFileName(URL): BName = oFSO.GetBaseName(Name)
        Ext  = oFSO.GetExtensionName(Name): i = 0
        While oFSO.FileExists(oFSO.BuildPath(N, Name))
           i = i + 1: Name = BName & "_" & i & "." & Ext
        Wend
        With CreateObject("SAPI.SpFileStream")
           .Format.Type = 1: .Open oFSO.BuildPath(N, Name), 3: .Write oHTTP.ResponseBody: .Close
        End With
        oHTTP.Abort
     Next
  Else oHTML.Close
  End If
  oDict.RemoveAll
Next
 
MsgBox "Скачивание завершено!", 4160, " Скачивание постеров"
For Each i in Array(oDict, oHTTP, oHTML, oFSO)
  Set i = Nothing
Next

CreateObject("WScript.Shell").Popup "Скачивание завершено!", 2, " Скачивание постеров", 4160