Получить URL из тега HTML

Option Explicit
Dim oFSO, oDict, oHTTP, oHTML, R, S, n, i, iURL, Arr, URL, Name, BName, Ext
'Posters from cinematerial.com/movies/0-i[IMDb ID without leading 0]
Const Num="349825"
'
Set oFSO  = CreateObject("Scripting.FileSystemObject")
Set oDict = CreateObject("Scripting.Dictionary")
Set oHTTP = CreateObject("MSXML2.ServerXMLHTTP.6.0")
Set oHTML = CreateObject("htmlfile")
R = Array(-230,-225,-246,698,-24,-24)
S = Split(": ? * "" / |")
'13056 or 12288
oHTTP.setOption(2) = 13056
oHTML.designMode = "on"
 
For Each n in Split(Num)
   oHTTP.Open "GET", "https://www.cinematerial.com/movies/0-i" & N, 0
   oHTTP.send : oHTML.Write oHTTP.ResponseText: oHTTP.abort
   For Each iURL in oHTML.links
      If InStr(iURL, "about:") = 1 Then
         iURL = "https://www.cinematerial.com" & Replace(Replace(iURL, "about:blank", ""), "about:", "")
         If InStr(iURL, "/p/") Then oDict.Add iURL, Empty
      End If
   Next
   If oDict.Count Then
      N = Split(oHTML.Title, ")")(0) & ")"
      For i = 0 To 5: N = Replace(N, S(i), ChrW(R(i))): Next
      If Not oFSO.FolderExists(N) Then oFSO.CreateFolder N
      For Each iURL in oDict.Keys
         oHTTP.Open "GET", iURL, False : oHTTP.Send
         oHTML.Write oHTTP.ResponseText: oHTTP.Abort
         For Each i In oHTML.getElementsByTagName("meta")
            If i.getAttribute("property") = "og:image" Then URL = i.content: Exit For
         Next: oHTML.Close
         URL = Left(URL, InStrRev(URL, "?") - 1)
         oHTTP.Open "GET", URL, False: oHTTP.Send
         Name = oFSO.GetFileName(URL): BName = oFSO.GetBaseName(Name)
         Ext  = oFSO.GetExtensionName(Name): i = 0
         While oFSO.FileExists(oFSO.BuildPath(N, Name))
            i = i + 1: Name = BName & "_" & i & "." & Ext
         Wend
         With CreateObject("SAPI.SpFileStream")
            .Format.Type = 1: .Open oFSO.BuildPath(N, Name), 3: .Write oHTTP.ResponseBody: .Close
         End With
         oHTTP.Abort
      Next
   Else oHTML.Close
   End If
   oDict.RemoveAll
Next
 
CreateObject("WScript.Shell").Popup "Done!",1,"Downloading posters",4160
Set oDict = Nothing: Set oHTTP = Nothing: Set oHTML = Nothing: Set oFSO = Nothing