Множества. Какие газеты не поступают ни в один из киосков; какие газеты бывают в каждом; какие есть хотя бы в одном

@CTAJIuH · Регистрация: 16.02.2014

Студворк — интернет-сервис помощи студентам

В три газетных киоска поступают газеты из имеющегося списка. Определить какие газеты не поступают ни в один из киосков; какие газеты бывают в каждом киоске; какие есть хотя бы в одном киоске.

вот постановка задачи(записали на паре)
m1,m2,m3 - множество газет в соотв киоске;
mag - все газеты(перечисл. тип);
mk - множество газет содержащихся в каждом киоске;
mn - множество газет не состоящих ни в одном киоске(не понял как его составить поэтому в программе его нету)

вот наработка... но работает некорректно(

Pascal

program mn0;
uses crt;
type mag=(p,a,l,t,e,v,r);
     ki=set of mag;
var m1,m2,m3,mk,mn,k1,k2,k3: ki;
    per,k:mag;
    nk,num:byte;
    nazv:integer;
 
procedure vvod(m:ki);
          var num:byte;
          begin
               writeln('Газеты:');
               while num<>10 do
                     begin
                          writeln('Список газет:');  {отображение меню программы}
                          Writeln('1) Правда');
                          Writeln('2) Аргументы и факты');
                          Writeln('3) Жизнь');
                          Writeln('4) Теле7');
                          Writeln('5) Еженедельник');
                          Writeln('6) Вести');
                          Writeln('7) Работа');
                          Writeln('8) Выход');
                          writeln('Введите номер газеты');
                          readln(num);
                          writeln;
                          case num of  {меню программы}
                               1 : include(m,p);
                               2 : include(m,a);
                               3 : include(m,l);
                               4 : include(m,t);
                               5 : include(m,e);
                               6 : include(m,v);
                               7 : include(m,r);
                               8 : Begin
                                        writeln('Ввод окончен');
                                        break;
                                   end;
                          else writeln('Ошибка ввода, введите корректный номер');
                     end;
             end;
             end;
procedure vvod_M(m:ki);
          begin
              writeln('Введите номер киоска');
              readln(nk);
              case nk of
                   1 : vvod(m1);
                   2 : vvod(m2);
                   3 : vvod(m3);
                   else writeln('Такого киоска нет, введите другой номер');
                   end;
          end;
 
BEGIN
              clrscr;
              while num<>7 do
                     begin
                          writeln('MENU:');  {отображение меню программы}
                          Writeln('1) Ввод данных');
                          Writeln('2) Газеты содержищиеся тлоько в 1-ом киоске');
                          Writeln('3) Газеты содержищиеся тлоько в 2-ом киоске');
                          Writeln('4) Газеты содержищиеся тлоько в 3-ем киоске');
                          Writeln('5) газеты не содержищиеся в каждом киоске');
                          Writeln('6) Газеты не содержищиеся ни в одном киоске');
                          Writeln('7) Выход');
                          writeln('Выберите действие :');
                          read(num);
                          writeln;
                          case num of  {меню программы}
                               1 : vvod_m(m1);
                               2 : begin
                                        writeln('газеты  содержищиеся  в 1 киоске');
                                        for k:=p to r do
                                            if k in m1 then nazv:=ord(k);
                                            case nazv of
                                                 0 : Writeln('Правда');
                                                 1 : Writeln('Аргументы и факты');
                                                 2 : Writeln('Жизнь');
                                                 3 : Writeln('Теле7');
                                                 4 : Writeln('Еженедельник');
                                                 5 : Writeln('Вести');
                                                 6 : Writeln('Работа');
                                                 end;
                                   end;
                               3 : begin
                                        writeln('газеты  содержищиеся  в 2 киоске');
                                        for k:=p to r do
                                            if k in m2 then nazv:=ord(k);
                                            case nazv of
                                                 0 : Writeln('Правда');
                                                 1 : Writeln('Аргументы и факты');
                                                 2 : Writeln('Жизнь');
                                                 3 : Writeln('Теле7');
                                                 4 : Writeln('Еженедельник');
                                                 5 : Writeln('Вести');
                                                 6 : Writeln('Работа');
                                                 end;
                                   end;
                               4 : begin
                                        writeln('газеты  содержищиеся  в 3 киоске');
                                        for k:=p to r do
                                            if k in m3 then nazv:=ord(k);
                                            case nazv of
                                                 0 : Writeln('Правда');
                                                 1 : Writeln('Аргументы и факты');
                                                 2 : Writeln('Жизнь');
                                                 3 : Writeln('Теле7');
                                                 4 : Writeln('Еженедельник');
                                                 5 : Writeln('Вести');
                                                 6 : Writeln('Работа');
                                                 end;
                                   end;
                               5 : begin
                                        mk:=m1*m2*m3;
                                        writeln('газеты содержищиеся в каждом киоске');
                                        for k:=p to r do
                                            if k  in mk then nazv:=ord(k);
                                            case nazv of
                                                 0 : Writeln('Правда');
                                                 1 : Writeln('Аргументы и факты');
                                                 2 : Writeln('Жизнь');
                                                 3 : Writeln('Теле7');
                                                 4 : Writeln('Еженедельник');
                                                 5 : Writeln('Вести');
                                                 6 : Writeln('Работа');
                                                 end;
                                   end;
                               6 : begin
                                        writeln('газеты не содержищиеся ни в одном киоскае');
                                        for k:=p to r do
                                            if not (k in mk) then nazv:=ord(k);
                                            case nazv of
                                                 0 : Writeln('Правда');
                                                 1 : Writeln('Аргументы и факты');
                                                 2 : Writeln('Жизнь');
                                                 3 : Writeln('Теле7');
                                                 4 : Writeln('Еженедельник');
                                                 5 : Writeln('Вести');
                                                 6 : Writeln('Работа');
                                                 end;
                                   end;
                               7 : Begin
                                        writeln('Программа завершена');
                                        exit;
                                   end;
                          else writeln('Ошибка ввода, введите корректный номер');
                     end;
                 end;
 
END.

@bormant · 01.04.2014, 13:57

При подобном построении программ за деревьями не видно леса, к сожалению. Имелось в виду всего лишь:

Pascal

1
2
3

mk:=m1*m2*m3;
mn:=[p..r]-m1-m2-m3;
me:=m1+m2+m3;

Но раз уж так хочется меню, не стоит запутывать сверх меры, вполне достаточно:

Pascal

type
  TPaper = (truth, anf, life, tele7, weekly, news, work);
  TPapers = set of TPaper;
const
  MaxK = 3;
  PaperStr: array [TPaper] of string[20] = ('Правда','Аргументы и факты',
    'Жизнь','Теле7','Еженедельник','Вести','Работа');
var
  m: array [1..MaxK] of TPapers;
 
procedure ReadPapers(h: string; var p: TPapers);
var
  np: TPaper; n: integer;
begin
  for np:=truth to work do Write(' ',ord(np)+1,'-',PaperStr[np]); WriteLn;
  WriteLn(' 0-завершение ввода');
  if h<>'' then Write(h);
  p:=[];
  repeat
    Read(n);
    case n of
    0:;
    1..ord(work)+1: Include(p,TPaper(n-1));
    end;
  until n=0;
  ReadLn;
end;
 
procedure ShowPapers(p: TPapers);
var i: TPaper; n: integer;
begin
  n:=0;
  for i:=truth to work do
    if i in p then begin
      if n>0 then Write('; ');
      Write(PaperStr[i]);
      inc(n);
    end; WriteLn;
end;
 
procedure ReadData;
var k: integer;
begin
  Write('Введите номер киоска (1..',MaxK,'): '); ReadLn(k);
  if k in [1..MaxK] then ReadPapers('Введите список номеров газет: ', m[k])
  else WriteLn('*** Ошибка ввода.');
end;
 
procedure ShowResults;
var
  k: integer;
  mk, me, mn: TPapers;
begin
  mk:=[truth..work]; mn:=[truth..work]; me:=[];
  WriteLn('Список газет по киоскам');
  for k:=1 to MaxK do begin
    Write(k,': '); ShowPapers(m[k]);
    mk:=mk*m[k];
    mn:=mn-m[k];
    me:=me+m[k];
  end;
  WriteLn; WriteLn('В каждом киоске есть газеты:'); ShowPapers(mk);
  WriteLn; WriteLn('Ни в одном из киосков нет газет:'); ShowPapers(mn);
  WriteLn; WriteLn('Хотя бы в одном киоске есть газеты:'); ShowPapers(me);
end;
 
var
  ch: char;
begin
  repeat
    WriteLn;
    WriteLn('1) Ввод данных');
    WriteLn('2) Вывод результатов');
    WriteLn('0) Выход');
    Write('Ваш выбор: '); ReadLn(ch);
    case ch of
    '0':;
    '1': ReadData;
    '2': ShowResults;
    else WriteLn('*** Ошибка ввода.');
    end;
  until ch='0';
end.

Добавлено через 9 минут
Пример выполнения:

Код

1) Ввод данных
2) Вывод результатов
0) Выход
Ваш выбор: 1
Введите номер киоска (1..3): 1
 1-Правда 2-Аргументы и факты 3-Жизнь 4-Теле7 5-Еженедельник 6-Вести 7-Работа
 0-завершение ввода
Введите список номеров газет: 1 2 3 4 0

1) Ввод данных
2) Вывод результатов
0) Выход
Ваш выбор: 1
Введите номер киоска (1..3): 2
 1-Правда 2-Аргументы и факты 3-Жизнь 4-Теле7 5-Еженедельник 6-Вести 7-Работа
 0-завершение ввода
Введите список номеров газет: 2 3 4 5 0

1) Ввод данных
2) Вывод результатов
0) Выход
Ваш выбор: 1
Введите номер киоска (1..3): 3
 1-Правда 2-Аргументы и факты 3-Жизнь 4-Теле7 5-Еженедельник 6-Вести 7-Работа
 0-завершение ввода
Введите список номеров газет: 3 4 5 6 0

1) Ввод данных
2) Вывод результатов
0) Выход
Ваш выбор: 2
Список газет по киоскам
1: Правда; Аргументы и факты; Жизнь; Теле7
2: Аргументы и факты; Жизнь; Теле7; Еженедельник
3: Жизнь; Теле7; Еженедельник; Вести

В каждом киоске есть газеты:
Жизнь; Теле7

Ни в одном из киосков нет газет:
Работа

Хотя бы в одном киоске есть:
Правда; Аргументы и факты; Жизнь; Теле7; Еженедельник; Вести

1) Ввод данных
2) Вывод результатов
0) Выход
Ваш выбор: 0

Опции темы