Вывести содержимое файла (с помощью чтения) на экран

uses crt;
const nmax=20;{максимальный размер матрицы и вектора}
type matr=array[1..nmax,1..nmax] of integer;{тип матрицы}
     mas=array[1..nmax] of integer;{тип вектора}
{ввод матрицы, выхходные параметры матрица и ее размеры, входной параметр ее "имя"}
procedure Vvod(var mt:matr;var x,y:byte;c:char);
var i,j:byte;
begin
writeln('Матрица ',c);
repeat
write('Количество строк до ',nmax,'=');
readln(x);
until x in [1..nmax];
repeat
write('Количество столбцов до ',nmax,'=');
readln(y);
until y in [1..nmax];
writeln('Матрица ',c);
for i:=1 to x do
 begin
   for j:=1 to y do
    begin
     mt[i,j]:=random(40)+10;
     write(mt[i,j]:4);
    end;
   writeln;
 end;
writeln;
end;
{создание вектора, входные параметры - матрица, ее размеры, имя,
выходной параметр - вектор}
procedure Vector(mt:matr;x,y:byte;var v:mas;c:char);
var i,j:byte;
    mx:integer;
begin
for j:=1 to y do
 begin
  mx:=mt[1,j];
  for i:=1 to x do
  if mt[i,j]>mx then mx:=mt[i,j];{находим максимальный в столбце}
  v[j]:=mx;{записываем в вектор}
 end;
writeln('Вектор максимальных значений столбцов матрицы ',c);
for i:=1 to y do
write(v[i]:4);
writeln;
writeln;
end;
{функция нахождения скалярного произведения векторов}
function Proiz(v1,v2:mas;n:byte):longint;
var i:byte;
    s:longint;
begin
s:=0;
for i:=1 to n do
s:=s+v1[i]*v2[i];{перемножаем друг на друга и суммируем}
Proiz:=s;{значение функции}
end;
var a,b:matr;
    va,vb:mas;
    n,m,k,l:byte;
begin
clrscr;
randomize;
Vvod(a,n,m,'A');
Vector(a,n,m,va,'A');
Vvod(b,k,l,'B');
Vector(b,k,l,vb,'B');
write('Pres Enter...');{пауза для просмотра результатов}
readln;
{еще одна опечатка, векторы делаем из макс. в столбцах,
поэтому чтобы их можно было перемножить, должно быть равно столбцов,
а не строк и столбцов}
if m<>l then write('Количество столбцов матрицы А не равно количеству столбцов матрицы В')
else
 begin
  writeln('Количество столбцов матрицы А равно количеству столбцов матрицы В');
  write('Произведение векторов=',Proiz(va,vb,m));
 end;
readln
end.

uses crt;
const nmax=20;
type matr=array[1..nmax,1..nmax] of real;
     mas=array[1..nmax] of real;
     fail=file of real;{типизированный файл вещественных чисел для хранения векторов}
procedure Vvod(var mt:matr;var x,y:byte;c:char;var f:text);
var i,j:byte;
begin
writeln('Матрица ',c);
repeat
write('Количество строк до ',nmax,'=');
readln(x);
until x in [1..nmax];
repeat
write('Количество столбцов до ',nmax,'=');
readln(y);
until y in [1..nmax];
writeln('Матрица ',c);
writeln(f,'Matrica ',c);{заголовок в файл}
for i:=1 to x do
 begin
   for j:=1 to y do
    begin
     mt[i,j]:=10*random;
     write(mt[i,j]:5:2);
     write(f,mt[i,j]:6:2);{матрицу построно в файл}
    end;
   writeln;
   writeln(f,'');{новая строка в файле}
 end;
writeln;
writeln(f,'');
end;
procedure Vector(mt:matr;x,y:byte;var v:mas;c:char;var g:fail);
var i,j:byte;
    mx:real;
begin
for j:=1 to y do
 begin
  mx:=mt[1,j];
  for i:=1 to x do
  if mt[i,j]>mx then mx:=mt[i,j];
  v[j]:=mx;
 end;
writeln('Вектор максимальных значений столбцов матрицы ',c);
for i:=1 to y do
 begin
  write(v[i]:5:2);
  write(g,v[i]);{элементы вектора в файл}
 end;
writeln;
writeln;
end;
function Proiz(v1,v2:mas;n:byte):real;
var i:byte;
    s:real;
begin
s:=0;
for i:=1 to n do
s:=s+v1[i]*v2[i];
Proiz:=s;
end;
var a,b:matr;
    va,vb:mas;
    f:text;
    g:fail;
    n,m,k,l,i:byte;
begin
clrscr;
randomize;
{связываем файловые переменные с файлами на диске, 
у нас они будут в папке с программой, и открываем их для записи}
assign(f,'matricy.txt');
rewrite(f);
assign(g,'vector.dat');
rewrite(g);
Vvod(a,n,m,'A',f);
Vector(a,n,m,va,'A',g);
Vvod(b,k,l,'B',f);
Vector(b,k,l,vb,'B',g);
close(f);{закрываем}
close(g);
write('Pres Enter...');
readln;
clrscr;
reset(g);{открываем файл с элементами векторов для чтения}
writeln('Вектор матрицы А:');
for i:=1 to m do
 begin
  read(g,va[i]);{читаем элементы первого вектора}
  write(va[i]:5:2);
 end;
writeln;
writeln;
writeln('Вектор матрицы B:');
for i:=1 to l do
 begin
  read(g,vb[i]);{второго}
  write(vb[i]:5:2);
 end;
writeln;
writeln;
close(g);{закрываем}
if m<>l then write('Количество столбцов матрицы А не равно количеству столбцов матрицы В')
else
 begin
  writeln('Количество столбцов матрицы А равно количеству столбцов матрицы В');
  write('Произведение векторов=',Proiz(va,vb,m):0:2);
 end;
readln
end.