Сформировать новую матрицу из данной, чтобы неотрицательные элементы каждого столбца располагались в начале столбца

 type
       matr= array[1..5, 1..5] of integer;
 var
       mass: matr;
 
      procedure input (a: matr);
      var
      i,j : integer;
       begin
             for i:=1 to 5 do
              for j:=1 to 5 do
                randomize;
                a[i,j]:= random (100)-100;
                  for i:=1 to 5 do
                    write (a[i,j], ' ');
       end;
       
       procedure sort (b: matr);
       var i,j,n,m, s: integer;
        begin
          for j:=1 to 5 do
            begin
               for i:=1 to 5 do
                  begin
                     if b[i,j]>=0 then
                         begin
                            s:=b[n,m];
                            b[n,m]:=b[i,j];
                            b[i,j]:=s;
                            n:=n+1;
                          end;
                       m:=m+1;
                    end;
              end;
          end;
 
        procedure output (b: matr);
          var i,j : integer;
          begin
            for i:=1 to 5 do
               begin
                  for j:=1 to 5 do
                  write (b[i,j], ' ');
               end;
           end;
  begin
   input (mass);
   sort (mass);
   output (mass);
    end.

const m = 5; //если нужно будет менять размер матрицы, то только здесь, а не по всей программе
 
type matr = array[1..m, 1..m] of integer;
 
procedure gen_prn(var a: matr); //не указали var, название процедуры являлось ключевым словом
var i, j: integer;
begin
  randomize; //вызывать нужно только один раз, а не в цикле
  writeln('Исходный массив:'); //ну хоть какой-то интерфейс должен быть, а то не пойёшь что выводится
  for i := 1 to m do
    begin
      for j := 1 to m do //**** в этом цикле у Вас вызывалось только randomize
        begin
          a[i, j] := random(199) - 99; //**** а это было вне цикла. Ещё исправил диапазон с [-1..99] на [-99..99]
          write (a[i, j] :4) //исправлен нелепый, неверный и некрасивый вывод строки массива
        end;
      writeln //переход на новую строку перед печатью очередной строки массива, у Вас этого не было
    end;
end;
 
procedure sort(var b: matr); //не указали var
var i, j, n, p: integer;
    c: array[1..m] of integer; //карман, отрицательные пишем в конец, остальные - в начало
begin
  for j := 1 to m do //цикл по столбцам
    begin
      p := 0; //начальная позиция для "неотрицательного" кармана
      n := m + 1; //начальная позиция для "отрицательного" кармана
      for i := 1 to m do //цикл по строкам (по элементам столбца)
        if b[i, j] < 0 //если отрицательное,
          then begin //то
            dec(n); //смещаем "отрицательную" позицию кармана
            c[n] := b[i, j] //помещаем элемент в "отрицательный" карман
          end
          else begin //иначе
            inc(p); //смещаем "неотрицательную" позицию кармана
            c[p] := b[i, j] //помещаем элемент в "неотрицательный" карман
          end;
      for i := 1 to p do b[i, j] := c[i]; //переписываем в столбец из кармана неотрицательные
      for i := n to m do b[i, j] := c[m - i + n] //переписываем в столбец из кармана отрицательные
    end;
end;
 
procedure prn(const b: matr); //забыли const, название процедуры являлось ключевым словом
var i, j: integer;
begin
  writeln('Отсортированный массив:'); //добавлено
  for i := 1 to m do
    begin
      for j:=1 to m do write (b[i,j] :4); //исправлен несуразный вывод
      writeln //перевод строки, про него Вы забыли
    end;
end;
 
var mass: matr; //глобальная переменная объявлялась до подпрограмм, что могло вызывать трудно локализуемые ошибки
begin
  gen_prn(mass);
  sort(mass);
  prn(mass);
  readln //ожидание <Enter> перед закрытием программы, убрать, если не нужно
end.