По координатам вершин треугольников определить, какой из них имеет большую площадь

{
PascalABC
 
Дано координаты вершин двух треугольников.
Определить, какой из них имеет большую площадь.
Примечание: расстояние между двумя точками вычисляется по формуле
l=sqrt((х2-х1)^2+(у2-у1)^2).
}
 
Program ProgramTryangle;
 
type
  // тип координата точки
  TypePoint = record
    x,y: real;
  end;
 
// функция вычисления расстояния между дыумя точками
function GetDistance(const t1,t2: TypePoint): real;
begin
  Result:=sqrt(sqr(t1.x-t2.x)+sqr(t1.y-t2.y));
end;
 
type
  // координаты вершин треугольника
  TypeVerticesOfTryangle = array[1..3]of TypePoint;
  
// вычисление площади треугольника по формуле Герона
function GetAreaOfTryangle(const Tryangle: TypeVerticesOfTryangle): real;
var
  a,b,c: real;  // длины сторон треугольника
  p: real;      // полупериметр треугольника
begin
  a:=GetDistance(Tryangle[1], Tryangle[2]);
  b:=GetDistance(Tryangle[2], Tryangle[3]);
  c:=GetDistance(Tryangle[1], Tryangle[3]);
  p:=(a+b+c)/2;
  Result:=Sqrt(p*(p-a)*(p-b)*(p-c));
end;
 
const
  nTryangle = 2;  // количество треугольников для сравнения площадей.
 
Var
  // координаты вершин треугольников
  Tryangle: array[1..nTryangle]of TypeVerticesOfTryangle;
  // периметр треугольника
  AreaOfTryangle: array[1..nTryangle]of real;
  // индекс треугольника с наибольшой площадью
  indexAreaOfTryangle: integer;
  
  i,nt: integer;
 
Begin
  // ввод данных
  for nt:=1 to nTryangle do
  begin
    writeln('Tryangle #', nt, '.');
    for i:=1 to 3 do
    begin
      Write('Enter x', i, ', y', i, ': ');
      Readln(Tryangle[nt][i].x, Tryangle[nt][i].y);
    end;
  end;
 
  // вычисление
    // вычисление площадей треугольников
  for nt:=1 to nTryangle do
    AreaOfTryangle[nt]:=GetAreaOfTryangle(Tryangle[nt]);
    // вычисление индекса треугольника с наибольшой площадью
  indexAreaOfTryangle:=1;  // допустим, что максимальную площадь имеет треугольник номер один
  for nt:=2 to nTryangle do
    if AreaOfTryangle[indexAreaOfTryangle]<AreaOfTryangle[nt] then
    indexAreaOfTryangle:=nt;
 
  // вывод результата
  Writeln;
  Writeln('Result: Tryangle #', indexAreaOfTryangle);
End.