Нужно объединить две программы

const n=4; eps=1e-12;
type
  TFloat = Real;
  TVector = array [0..n-1] of TFloat;
  TMatrix = array [0..n-1] of TVector;
 
{ обратная матрица, определитель, решение СЛАУ
   методом элементарных преобразований Гаусса-Жордана }
function mInvGJ(var a: TMatrix; var b: TVector; var det: TFloat): Boolean;
var
  i, j, k: Integer; t: TFloat;
  e: TMatrix; v: TVector;
begin
  mInvGJ:=False; det:=1;
  for i:=0 to n-1 do for j:=0 to n-1 do e[i][j]:=0;
  for i:=0 to n-1 do e[i][i]:=1;
  for k:=0 to n-1 do begin
    j:=k; for i:=k+1 to n-1 do if Abs(a[j][k])<Abs(a[i][k]) then j:=i;
    if j>k then begin
     v:=a[j]; a[j]:=a[k]; a[k]:=v;
     v:=e[j]; e[j]:=e[k]; e[k]:=v;
     t:=b[j]; b[j]:=b[k]; b[k]:=t;
     det:=-det;
    end;
    t:=a[k][k];
    if Abs(t)<eps then begin
      det:=0; Exit;
    end;
    det:=det*t;            b[k]  :=b[k]  /t;
    for j:=n-1 downto 0 do e[k][j]:=e[k][j]/t;
    for j:=n-1 downto k do a[k][j]:=a[k][j]/t;
    for i:=0 to n-1 do if i<>k then begin
      t:=-a[i][k];       b[i]  :=b[i]  +t*b[k];
      for j:=k to n-1 do a[i][j]:=a[i][j]+t*a[k][j];
      for j:=0 to n-1 do e[i][j]:=e[i][j]+t*e[k][j];
    end;
  end;
  a:=e; mInvGJ:=True;
end;
 
procedure GetErr(const a: TMatrix; const b, x: TVector; var r: TVector);
var i, j: Integer; t: TFloat;
begin
  for i:=0 to n-1 do begin
    t:=-b[i]; for j:=0 to n-1 do t:=t+x[j]*a[i][j]; r[i]:=t;
  end;
end;
 
procedure mMul(const a, b: TMatrix; var r: TMatrix);
var i, j, k: Integer; t: TFloat;
begin
  for i:=0 to n-1 do for j:=0 to n-1 do begin
    t:=0; for k:=0 to n-1 do t:=t+a[i][k]*b[k][j]; r[i][j]:=t;
  end;
end;
 
procedure vWrite(const p: String; v: TVector; W, D: Integer);
var j: Integer;
begin
  if p<>'' then WriteLn(p);
  if W<0
  then for j:=0 to n-1 do Write(' ',v[j])
  else if D<0
  then for j:=0 to n-1 do Write(' ',v[j]:W)
  else for j:=0 to n-1 do Write(' ',v[j]:W:D);
  WriteLn;
end;
 
procedure mWrite(const p: String; const a: TMatrix; W, D: Integer);
var i, j: Integer;
begin
  WriteLn(p); for i:=0 to n-1 do vWrite('',a[i],W,D);
end;
 
const
  a: TMatrix = (
    ( 3.25, 1.54, 2.91, 5.43),
    ( 7.13, 8.21, 4.47,-2.11),
    ( 4.52, 6.73, 1.37,-9.89),
    (-6.34,-8.17,-10.2, 3.93));
  b: TVector = (
    4.14, 5.65, 2.92, 3.15);
  WW=10; DD=4;
var
  ai, e: TMatrix;
  x, r: TVector;
  det: TFloat;
begin
  mWrite('A =',a,WW,2);
  ai:=a; x:=b;
  if mInvGJ(ai,x,det) then begin
    GetErr(a,b,x,r);
    mMul(a,ai,e);
    WriteLn('| A | = ',det);
    vWrite('x   =',x,WW,DD);
    vWrite('err =',r,12,4);
    mWrite('A^-1 =',ai,WW,DD);
    mWrite('A * A^-1 = E:',e,6,4);
  end else WriteLn('Error');
end.

const n=4; eps=1e-37;
type
  TMatrix = array [0..n-1,0..n-1] of Real;
  TVector = array [0..n-1] of Real;
  TELine =  array [0..n] of Real;
  TEMatrix = array [0..n-1] of TELine;
 
function Gauss(var a: TEMatrix; var det: Real; var x: TVector): Boolean;
var
  i, j, k: Integer;
  d: Real;
  t: TELine;
begin
  Gauss:=False;
  det:=1;
  for k:=0 to n-1 do begin
    j:=k; for i:=k+1 to n-1 do if Abs(a[j,k])<Abs(a[i,k]) then j:=i;
    if k<>j then begin t:=a[k]; a[k]:=a[j]; a[j]:=t; det:=-det; end;
    for i:=k+1 to n-1 do begin
      d:=a[i,k]/a[k,k];
      for j:=k to n do a[i,j]:=a[i,j]-d*a[k,j];
    end;
  end;
  for k:=0 to n-1 do det:=det*a[k,k];
  if Abs(det)<eps then Exit;
  for k:=n-1 downto 0 do begin
    for j:=k+1 to n-1 do a[k,n]:=a[k,n]-a[k,j]*x[j];
    x[k]:=a[k,n]/a[k,k];
  end;
  Gauss:=True;
end;
 
procedure Nev(const a: TMatrix; const b, x: TVector; var r: TVector);
var i, j: Integer; t: Real;
begin
  for i:=0 to n-1 do begin
    t:=-b[i]; for j:=0 to n-1 do t:=t+x[j]*a[i,j]; r[i]:=t;
  end;
end;
 
const
  b: TVector = (4.14, 5.65, 2.92, 3.15);
  c: TMatrix = (
    ( 3.25, 1.54, 2.91, 5.43),
    ( 7.13, 8.21, 4.47,-2.11), 
    ( 4.52, 6.73, 1.37,-9.89), 
    (-6.34,-8.17,-10.2, 3.93));
var
  a: TEMatrix; x, r: TVector;
  i, j: Integer; det: Real;
begin
  for i:=0 to n-1 do begin { расширенная матрица }
    for j:=0 to n-1 do a[i,j]:=c[i,j]; a[i,n]:=b[i];
  end;
  if Gauss(a,det,x) then begin
    Nev(c,b,x,r);
    for i:=0 to n-1 do begin
      for j:=0 to n do Write(' ',a[i,j]:6:2);
      WriteLn(' | ',x[i]:6:2,' | ',r[i]);
    end;
    WriteLn('Определитель: ',det:6:2);
  end else WriteLn('Бесконечное число решений');
end.