Программа, реализующая стек

@Notralore · Регистрация: 08.12.2019

Студворк — интернет-сервис помощи студентам

Нужно сделать программу, реализующую стек в виде динамической структуры данных. Информационной частью элемента стека является символ. В программе создать меню с выбором выполняемой операции: запись в стек, чтение из стека, проверка стека на пустоту, обнуление стека, просмотр стека, выход из программы.
Есть кусочек программы, в которой что-то явно не так(т.к при вводе программа падает). Ткните носом, пожалуйста.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
Program Stek;
type
  Tinf=integer;
  List=^TList;
  TList=record 
    data:TInf;  
    next:List;
  end;
 
{Процедура добавляющая элемент в стек}
procedure AddElem(var stek1:List;znach1:TInf);
var
  tmp:List;
begin
  tmp^.next:=stek1;
  tmp^.data:=znach1; 
  stek1:=tmp; 
end;
 
{Процедура вывода стека}
procedure Print(stek1:List);
begin
  if stek1=nil then {проверка на пустоту стека}
  begin
    writeln('Стек пуст.');
    exit;
  end;
  while stek1<>nil do 
  begin   
    Write(stek1^.data, ' ');
    stek1:=stek1^.next  
  end;
end;
 
var
  Stk,
  tmpl:List;
  znach:Tinf; 
  ch:char;
  f:text;
  k:integer;
 
begin
    Stk:=nil;
    k := 1;
    repeat
    Write('Программа для работы со ');
    Writeln('стеком.');
    Writeln('Выберите желаемое действие:');
    Writeln('1) Добавить элемент.');
    Writeln('2) Вывод стека.');
    Writeln('3) Проверка стека на пустоту');
    Writeln('4) ');
    Writeln('5) Выход.');
    writeln;
    readln(ch);
    case ch of 
      '1':begin
            write('Введите значение добавляемого элемента: ');
            readln(znach); 
            AddElem(Stk,znach);
          end;
      '2':begin
            Print(Stk); 
          end;
      '3':begin
          
          end;
      '4':begin
            
            readln(znach); 
          end;
      
    end;
  until ch='5';
end.

@mr-Crocodile · 18.02.2020, 15:47

Сообщение от Notralore

Информационной частью элемента стека является символ.

а в коде - integer:

Сообщение от Notralore

Pascal
1
Tinf=integer;

но проблема не в этом, а в том, как ты добавляешь.
запомни. Если есть указатели, то нужно обязательно выделять память (см. процедуру New( ))

в твоём случае я бы написал процедуру, например, так:

Pascal
1
2
3
4
5
6
7
8
9
10
{Процедура добавляющая элемент в стек}
procedure AddElem(var stek1:List;znach1:TInf);
var
  tmp:List;
begin
  New(tmp);
  tmp^.next:=stek1;
  tmp^.data:=znach1; 
  stek1:=tmp; 
end;

ну и раз выделил память, то неплохо бы было бы в конце её освободить (см. Dispose() )

ну и в процедуре Print я бы так написал:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
{Процедура вывода стека}
procedure Print(stek1:List);
var  tmp:List;
begin
  if stek1=nil then {проверка на пустоту стека}
    writeln('Стек пуст.')
  else begin
    tmp:=stek1;
    while tmp<>nil do begin   
       Write(tmp^.data, ' ');
       tmp:=tmp^.next  
    end;
  end;
end;

@Notralore · 18.02.2020, 19:56 **[ТС]**

Ооо, большое спасибо за помощь.) Я стал чуть ближе к разгадке.

Добавлено через 31 минуту
А какую процедуру сделать чтобы очистить стек?

@JuriiMW · 19.02.2020, 06:59

Во-первых, если пишем на английском, то хотя бы смотрим в переводчик!
Стек — по английски «Stack».

Во-вторых, заголовок программы „program [имя программы]“ ни кому не нужен.

В-третьих, обычно над стеком определены две операции:
push — толкнуть значение в стек (поместить в стек)
pop — вытолкнуть из стека (получить элемент из вершины стека и удалить его)

Иногда ещё используют top — получение верхнего элемента стека без его удаления.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
type
  tInf = Integer;
  tStack = ^pStack;
  pStack = record 
    data : tInf;  
    next : tStack;
  end;
 
{Процедура добавляющая элемент в стек}
procedure Push(var Stack : tStack; data : tInf);
var
  tmp : tStack;
begin
  New(tmp);
  tmp^.next := stack;
  tmp^.data := data;
  stack := tmp; 
end;
 
function Pop(var Stack : tStack) : tInf;
var
  Res : tInf;
  Tmp : tStack;
begin
  if Stack <> nil then
    begin
      Tmp := Stack;
      Stack := Stack^.next;
      Res := Tmp^.data;
      Dispose(Tmp);
    end;
  Pop := Res;
end;
 
{Процедура вывода стека}
procedure Print(Stack : tStack);
var
  tmp : tStack;
begin
  if Stack = nil then {проверка на пустоту стека}
    WriteLn('Стек пуст.')
  else
    begin
      tmp := Stack;
      while tmp <> nil do
        begin
          Write(tmp^.data, ' ');
          tmp := tmp^.next;
        end;
      WriteLn;
    end;
  WriteLn;
end;
 
procedure addToStack(var Stack : tStack);
var
  data : tInf;
begin
  Write('Введите значение добавляемого элемента: '); ReadLn(data); 
  Push(Stack, data);
  WriteLn;
end;
 
procedure clearStack(var Stack : tStack);
begin
  while Stack <> nil do
    Pop(Stack);
end;
 
var
  Stack : tStack;
  ch : char;
 
begin
  Stack := nil;
  repeat
    Write('Программа для работы со ');
    Writeln('стеком.');
    Writeln('Выберите желаемое действие:');
    Writeln('1) Добавить элемент.');
    Writeln('2) Вывод стека.');
    Writeln('3) Проверка стека на пустоту');
    Writeln('4) Очистить стек');
    Writeln('5) Выход.');
    writeln;
    readln(ch);
    
    case ch of 
      '1' : addToStack(Stack);
      '2' : Print(Stack); 
      '3' : WriteLn('Стек пуст = ', Stack=nil);
      '4' : clearStack(Stack);
    end; {case ch}
    
  until ch='5';
  
  clearStack(Stack);
end.

@Notralore · 20.02.2020, 21:41 **[ТС]**

Первые два пункта можно было не объяснять

Транслит и просто так введённый заголовок.)
За остальное - огромное спасибо, не знаю что бы делал без вас.

Новые блоги и статьи Все статьи Все блоги /
Реалии Hrethgir 01.03.2026 Нет, я не закончил до сих пор симулятор. Эта задача сложнее. Не получилось уйти в плавсостав, но оно и к лучшему, возможно. Точнее получалось - но сварщиком в палубную команду, а это значит, в моём. . .	Ритм жизни kumehtar 27.02.2026 Иногда приходится жить в ритме, где дел становится всё больше, а вовлечения в происходящее — всё меньше. Плотный график не даёт вниманию закрепиться ни на одном событии. Утро начинается с быстрых,. . .	SDL3 для Web (WebAssembly): Сборка библиотек: SDL3, Box2D, FreeType, SDL3_ttf, SDL3_mixer и SDL3_image из исходников с помощью CMake и Emscripten 8Observer8 27.02.2026 Недавно вышла версия 3. 4. 2 библиотеки SDL3. На странице официальной релиза доступны исходники, готовые DLL (для x86, x64, arm64), а также библиотеки для разработки под Android, MinGW и Visual Studio. . . .	SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .
Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.

@Notralore 0 / 0 / 0 Регистрация: 08.12.2019 Сообщений: 23
	18.02.2020, 19:56 [ТС]
	Ооо, большое спасибо за помощь.) Я стал чуть ближе к разгадке. Добавлено через 31 минуту А какую процедуру сделать чтобы очистить стек? 0

@Notralore 0 / 0 / 0 Регистрация: 08.12.2019 Сообщений: 23
	20.02.2020, 21:41 [ТС]
	Первые два пункта можно было не объяснять Транслит и просто так введённый заголовок.) За остальное - огромное спасибо, не знаю что бы делал без вас. 0

Программа, реализующая стек

Решение