Множества. Вывести все глухие согласные буквы, которые входят в каждое нечётное слово и не входят хотя бы в одно чётное

uses crt;
const gl=['к','п','с','т','ф','х','ц','ч','ш','щ'];{букв не 8, а 10}
type mnoz=set of char;{тип множество символов}
procedure Vvod(var s:string);{ввод, проверка и форматирование строки}
begin
repeat
writeln('Введите предложение, оканчивающееся точкой, между словами пробелы:');
readln(s);
if (s[length(s)]<>'.')or(pos(' ',s)=0) then
writeln('Предложение введено неверно. Повторите ввод.');
until(s[length(s)]='.')and(pos(' ',s)>0)  ;{должен быть хоть один пробел и точка последней}
s[length(s)]:=' ';{заменим точку на пробел}
while pos('  ',s)>0 do {пока есть 2 пробела рядом}
delete(s, pos('  ',s),1);{один удаляем, в апостофах обязательно по 2 пробела, если 1, все сольется}
end;
procedure Mnozestvo(s:string;var m:mnoz);{создание множества из слова}
var i:byte;
begin
m:=[];
for i:=1 to length(s) do
if s[i] in gl then m:=m+[s[i]];{все нужные буквы заносим в множество}
end;
 
var s,s1:string;
    m1,mi:mnoz;
    i,j:byte;
begin
clrscr;
Vvod(s);{вводим и готовим строку}
s1:=copy(s,1,pos(' ',s));{берем первое слово}
Mnozestvo(s1,m1);{делаем множество по условию}
delete(s,1,pos(' ',s));{удаляем его}
i:=1;{одно слово уже было}
while pos(' ',s)>0 do{пока есть пробелы}
 begin
  s1:=copy(s,1,pos(' ',s));{копируем первое слово}
  i:=i+1;{считаем}
  Mnozestvo(s1,mi);{делаем множество}
  if i mod 2=0 then m1:=m1-mi {если слово четное, убираем из множества встреченные буквы по условию}
  else m1:=m1*mi; {если нечетное, убираем из множества  буквы, которые не во всех нечетных словах}
  delete(s,1,pos(' ',s));{удаляем слово, следующее первое}
 end;
if m1=[] then{если ни одной буквы}
 begin
  write('Указанных по условию букв нет!');
  readln;
  exit;{выходим из программы}
 end;
writeln('Множество указанных по условию букв:');{}
for i:=170 to 233 do{178 - код символа к, 233 - щ}
if chr(i) in m1 then write(chr(i),' ');
readln
end.

program Project1;
 
{Перевод букв строки в верхний регистр. Для кодовой страницы CP866 (DOS).}
function UpCase866(const aStr : String) : String;
var
  S : String;
  i : Integer;
begin
  S := aStr;
  for i := 1 to Length(S) do
    if S[i] in ['а'..'п'] then
      S[i] := Chr(Ord(S[i]) - 32)
    else if s[i] in ['р'..'я'] then
      S[i] := Chr(Ord(S[i]) - 80)
    else if S[i] = 'ё' then
      S[i]:='Ё'
    else
      S[i] := UpCase(S[i]);
  UpCase866 := S;
end;
 
const
  {Множество разделителей слов.}
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  {Множество русских глухих согласных букв.}
  Da = ['К', 'П', 'С', 'Т', 'Ф', 'Х', 'Ц', 'Ч', 'Ш', 'Щ'];
var
  S : String;
  Dw, D1, D2, DRes : set of Char;
  Ch : Char;
  i, Len, Cnt : Integer;
begin
  repeat
    Writeln('--------------------------------------------------');
    Writeln('Задайте текст:');
    Readln(S);
 
    {Решение.}
    S := UpCase866(S); {Приводим буквы строки к верхнему регистру.}
    Len := Length(S);  {Длина строки.}
    Dw := []; {Множество глухих согласных букв, которые входят в текущее слово.}
    D1 := []; {Множество глухих согласных букв, которые входят в каждое нечётное слово.}
    D2 := []; {Множество глухих согласных букв, которые входят в каждое чётное слово.}
    Cnt := 0; {Счётчик слов.}
    for i := 1 to Len do
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        {Если текущая буква является глухой согласной, то добавляем её во множество
        глухих согласных букв текущего слова.}
        Dw := Dw + [S[i]] * Da;
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          Inc(Cnt); {Порядковый номер текущего слова.}
          if Cnt = 1 then {Если текущее слово является первым нечётным словом в тексте.}
            D1 := Dw      {Начальное содержимое множества D1.}
          else if Cnt = 2 then {Иначе, если текущее слово является первым чётным словом в тексте.}
            D2 := Dw           {Начальное содержимое множества D2.}
          else if Cnt mod 2 <> 0 then {Иначе, если текущее слово является нечётным.}
            D1 := D1 * Dw  {Глухие согласные буквы, которые входят в текущее нечётное слово и во все предыдущие нечётные слова.}
          else {Иначе (если текущее слово является чётным).}
            D2 := D2 * Dw; {Глухие согласные буквы, которые входят в текущее чётное слово и во все предыдущие чётные слова.}
          Dw := []; {Обнуление множества глухих согласных букв текущего слова.}
        end;
      end;
 
    {Множество глухих согласных букв, которые входят в каждое нечётное слово (D1)
    и которые не входят хотя бы в одно чётное слово (Da - D2).}
    DRes := D1 * (Da - D2);
 
    {Ответ.}
    Writeln('Ответ:'
      + #13#10'Множество глухих согласных букв, которые входят в каждое нечётное слово'
      + #13#10'и которые не входят хотя бы в одно чётное слово:');
    if DRes = [] then
      Writeln('Таких букв в тексте нет.')
    else
    begin
      for Ch := #0 to #255 do
        if Ch in DRes then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Write('Повторить - Enter. Выход - любой символ + Enter. ');
    Readln(S);
  until S <> '';
end.