Список: Из группы подряд идущих элементов с одинаковыми значениями оставить только первый

program Project1;
 
type
  {Тип основных данных списка.}
  TData = Integer;
  {Тип указателя на элемент списка.}
  TPElem = ^TElem;
  {Тип элемента списка.}
  TElem = record
    Data : TData;   {Основные данные элемента.}
    PNext : TPElem; {Указатель на следующий элемент списка.}
  end;
  {Тип, описывающий однонаправленный список.}
  TDList = record
    PFirst, PLast : TPElem; {Указатели на первый и последний элементы списка.}
  end;
 
{Инициализация списка. Внимание! Эту процедуру можно выполнять только
в отношении пустого списка. Иначе - будут утечки памяти.}
procedure Init(var aList : TDList);
begin
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
{Добавление элемента в конец однонаправленного списка.}
procedure Add(var aList : TDList; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.PNext := nil;
  if aList.PFirst = nil then
    aList.PFirst := PElem
  else
    aList.PLast^.PNext := PElem;
  aList.PLast := PElem;
end;
 
{Освобождение памяти, выделенной под список и инициализация.}
procedure LFree(var aList : TDList);
var
  PNext, PDel : TPElem;
begin
  PNext := aList.PFirst;
  while PNext <> nil do begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
  Init(aList);
end;
 
{Распечатка однонаправленного списка.}
procedure LWriteln(const aList : TDList);
var
  PElem : TPElem;
begin
  if aList.PFirst = nil then begin
    Writeln('Список пуст.');
    Exit;
  end;
 
  PElem := aList.PFirst;
  while PElem <> nil do begin
    if PElem <> aList.PFirst then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  end;
  Writeln;
end;
 
var
  L : TDList;
  PElem, PPrev, PDel : TPElem;
  Data : TData;
  i, Code : Integer;
  S : String;
begin
  {Начальная инициализация списка.}
  Init(L);
 
  repeat
    {Создание списка.}
    Writeln('Создание списка.');
    Writeln('Прекратить ввод - пустая строка + Enter.');
    i := 0;
    repeat
      Write('Элемент ', i + 1, ': ');
      Readln(S);
      if S <> '' then begin
        Val(S, Data, Code);
        if Code = 0 then begin
          Inc(i);
          Add(L, Data);
        end else
          Writeln('Неверный ввод. Повторите.');
      end;
    until S = '';
    Writeln('Составлен список:');
    LWriteln(L);
 
    {Удаляем из списка одинаковые, подряд идущие элементы, кроме первого
    в каждой группе.}
    i := 0;
    if L.PFirst <> nil then begin
      PPrev := L.PFirst;     {Предыдущий элемент.}
      PElem := PPrev^.PNext; {Текущий элемент.}
      while PElem <> nil do
        {Если предыдущий элемент равен текущему, то удаляем текущий элемент.}
        if PPrev^.Data = PElem^.Data then begin
          {Указатель на удаляемый элемент.}
          PDel := PElem;
          {Исключаем текущий элемент из списка.}
          PElem := PElem^.PNext;
          PPrev^.PNext := PElem;
          {Если удаляется последний элемент в списке.}
          if PDel = L.PLast then L.PLast := PPrev;
          {Освобождение памяти, занятой под элемент.}
          Dispose(PDel);
          {Количество удалённых элементов стало на 1 больше.}
          Inc(i);
        {Если предыдущий элемент НЕ равен текущему, то переходим к следующему элементу.}
        end else begin
          PPrev := PElem;
          PElem := PElem^.PNext;
        end;
    end;
 
    Writeln('Удалено элементов: ', i);
    Writeln('Список после обработки:');
    LWriteln(L);
 
    {Освобождение памяти, занятой под список.}
    LFree(L);
    Writeln('Память, выделенная для списка, освобождена.');
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.