Помощь по задаче "баланс скобок"

program Project1;
 
const
  (*Открывающие скобки.*)
  D1 = ['(', '[', '{'];
  (*Закрывающие скобки.*)
  D2 = [')', ']', '}'];
 
var
  (*Анализируемая строка.*)
  StrSrc: String;
  (*True - согласованы. False - иначе.*)
  Balance: Boolean;
  
  (*Переменные для организации работы стека.*)
  Stack: array[1..100] of Char;
  StackPnt: Integer;
 
(*Подпрограммы для работы со стеком.*)
 
(*Добавить в стек элемент.*)
procedure StackPush(const aCh: Char);
begin
  Inc(StackPnt);
  Stack[StackPnt] := aCh;
end;
 
(*Взять из стека элемент.
True - стек не пуст, через параметр aCh возвращён элемент из вершины стека.
False - стек пуст.*)
function StackPop(var aCh: Char): Boolean;
begin
  StackPop := False;
  if StackPnt > 0 then begin
    aCh := Stack[StackPnt];
    Dec(StackPnt);
    StackPop := True;
  end;
end;
 
(*Для закрывающей скобки возвращает соответствующую открывающую скобку.*)
function GetOpen(const aCh: Char): Char;
begin
  case aCh of
    ')': GetOpen := '(';
    ']': GetOpen := '[';
    '}': GetOpen := '{';
  else
  (*Ошибка.*)
    GetOpen := '*';
  end;
end;
 
(*Анализ строки на предмет согласованности скобок.*)
procedure Proc;
var
  i: Integer;
  Ch: Char;
begin
  StackPnt := 0;
  Balance := True;
  for i := 1 to Length(StrSrc) do 
  begin
    if StrSrc[i] in D1 then begin
      (*Нашли открывающую скобку - добавляем её в стек.*)
      StackPush( StrSrc[i] );
    end else if StrSrc[i] in D2 then begin;
      (*Нашли закрывающу скобку - берём элемент из вершины стека.*)
      if StackPop(Ch) then begin
        (*Стек не пуст.*)
        if Ch <> GetOpen(StrSrc[i]) then begin
          (*Взятая из вершины стека скобка не соответствует текущей закрывающей скобке.
          Согласованность нарушена.*)
          Balance := False;
          Break;
        end;
      end else begin
        (*Стек пуст. Значит нет соответствия текущей закрывающей скобке.
        Согласованность нарушена.*)
        Balance := False;
        Break;
      end;
    end;
  end;
end;
 
 
procedure getFromFile();
var inFile: text;
inFileName: string;
begin
  writeln('Enter a file name');
  readln(inFileName);
  assign(inFile, inFilename);
  reset(inFile);
  while not eof(inFile) do
  begin
    readln(inFile, StrSrc);
    writeln(StrSrc);
    proc;
    if Balance then
    Writeln('Скобки согласованы.')
    else
    Writeln('Скобки не согласованы.');
 
  end;
  close(inFile);
end;
 
begin
  getfromfile;
  readln;
end.

Balance:= (StackPnt = 0); (*если стек не пуст значит скобки не согласованы*)