Массив множеств на паскале

uses crt;
const max=50;//максимальное количество чисел
type mnoz=set of byte;//тип множества
var n,i,j,k:byte;
    a:longint;//числа
    m:array[1..max] of mnoz;//массив множеств
    mn,mn1:mnoz;//множества
begin
clrscr;
repeat
write('Количество чисел, не более ',max,' n=');
readln(n);
until n in [1..max];
writeln('Введите ',n,' целых чисел:');
for i:=1 to n do
 begin
  write('a=');readln(a);
  m[i]:=[];//создаем множество из цифр числа
  while a>0 do
   begin
    m[i]:=m[i]+[a mod 10];
    a:=a div 10;
   end;
  end;
mn:=m[1];//запомним первое множество
for i:=2 to n do
mn:=mn*m[i];//найдем его пересечение с остальными
if mn=[] then writeln('Цифр, которые есть во всех числах, нет!')//если пустое
else//иначе
 begin
  writeln('Во всех числах есть цифры:');
  for i:=0 to 9 do
  if i in mn then write(i,' ');//выводим цифры этого множества
 end;
writeln;
mn1:=[];//множество цифр, входящих в одно число
for i:=1 to n do//для каждого множества
 begin
  mn:=[];
  for j:=1 to n do
  if j<>i then mn:=mn+m[j];//делаем множество из цифр, котрые входят в другие числа
  for k:=0 to 9 do
  if (k in m[i])and not(k in mn) then mn1:=mn1+[k];//если цифра есть в этом множестве, 
//но ее нет в других, то записываем ее в новое множество
 end;
if mn1=[] then writeln('Цифр, которые входят только в одно число, нет!')
else
 begin
  writeln('Цифры, которые входят только в одно число:');
  for i:=0 to 9 do
  if i in mn1 then write(i,' ');
 end;
readln
end.