Дана последовательность слов

program Project1;
 
const
  //Имя файла.
  FileName = 'data.txt';
 
//Извлекает из строки aStr слова, обрабатывает их согласно заданию и записывает
//в файл.
procedure ProcStr(const aStr : String);
const
  //Множество разделителей.
  Delims = [' ', '.', ',', ':', ';', '!', '?', '-'];
var
  //Файловая переменная для текстового файла.
  F : Text;
  //Индексы символов строки.
  i : Integer;
  //Позиции начала и конца очередного слова.
  //Pos2 также играет роль флага: если Pos2 = 0 - "конец слова не найден".
  //Иначе, если Pos2 > 0 - "конец слова найден".
  Pos1, Pos2 : Integer;
  //Cтрока, представляющая отдельное слово.
  StrWord : String;
begin
  //Связываем файловую переменную с именем файла.
  Assign(F, FileName);
  //Создаём/перезаписываем файл.
  Rewrite(F);
 
  //Обработка строки и запись в файл.
 
  //Флаг, показывающий обнаружен ли конец слова.
  Pos2 := 0;
  //Перебор всех символов строки.
  for i := 1 to Length(aStr) do begin
    //Если очередной символ не является буквой - пропускаем итерацию.
    if aStr[i] in Delims then Continue;
 
    //Если очередной символ является буквой.
 
    //Отслеживаем начало слова.
    if i = 1 then
      Pos1 := i
    else if aStr[i - 1] in Delims then
      Pos1 := i;
    ;
    //Отслеживаем конец слова.
    if i = Length(aStr) then
      Pos2 := i
    else if aStr[i + 1] in Delims then
      Pos2 := i
    ;
    //Если конец слова обнаружен - обрабатываем это слово и записываем его в файл.
    if Pos2 > 0 then begin
      //Копируем слово из исходной строки.
      StrWord := Copy(aStr, Pos1, Pos2 - Pos1 + 1);
      //Если слово состоит из нечётного количества букв, тогда букву в середине меняем на цифру.
      if (Length(StrWord) > 1) and ( (Length(StrWord) mod 2) > 0 ) then begin
        StrWord[ Length(StrWord) div 2 + 1 ] := '1';
      end;
      //Записываем слово в файл.
      Writeln(F, StrWord);
 
      //Значение флага устанавливаем в: "конец слова не найден".
      Pos2 := 0;
    end;
  end;
 
  //Закрытие файла.
  Close(F);
end;
 
//Чтение из файла слов и показ их на экране.
procedure ShowWords;
var
  //Файловая переменная.
  F : Text;
  //Строка, представляющая слово.
  StrWord : String;
begin
  //Связываем файловую переменную с имненем файла.
  Assign(F, FileName);
  //Открываем файл в режиме "только чтение".
  Reset(F);
  //Читаем слова и показываем их на экране.
  while not Eof(F) do begin
    Readln(F, StrWord);
    Writeln(StrWord);
  end;
  //Закрываем файл.
  Close(F);
end;
 
var
  //Исходная строка.
  StrSrc : String;
  //Строка для прочих вычислений.
  StrTmp : String;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(StrSrc);
    //Обработка строки и запись слов в файл.
    ProcStr(StrSrc);
    //Чтение из файла слов и показ их на экране.
    ShowWords;
 
    Writeln('Для повтора нажмите Enter. Выход - любой символ + Enter.');
    Readln(StrTmp);
  until StrTmp <> '';
end.