Пояснения к коду

type
  mas = array of integer;
 
var
  n: integer;
  F: file of integer;
 
procedure genfile(F: file of integer; n: integer);
var
  i: integer;
begin
  assign(F, 'FileData.dat');
  rewrite(F);
  for i := 1 to n do
    write(F, random(100));
  close(F)
end;
 
procedure QuickSort(var arr: mas; Left, Right: Integer);{Left - левая граница массива}
var
  I, J, Y: Integer;{Right - правая граница массива}
begin
  I := Left;
  J := Right;
  Y := arr[(Left + Right) div 2];
  repeat
    while arr[I] < Y do Inc(I);
    while Y < arr[J] do Dec(J);
    if I <= J then
    begin
      swap(arr[i], arr[j]);
      Inc(I);
      Dec(J);
    end;
  until I >= J;
  if Left < J then QuickSort(arr, Left, J);
  if I < Right then QuickSort(arr, I, Right);
end;
 
procedure showfile(F: file of integer);
var
  x: integer;
begin
  reset(F);
  while not eof(F) do
  begin
    read(F, x);
    write(x:4);
  end;
  writeln;
  close(F)
end;
 
procedure mastofile(arr: mas; F: file of integer);
var
  i: integer;
begin
  rewrite(F);
  for i := 0 to length(arr) - 1 do
    write(F, arr[i]);
  close(F)
end;
 
procedure filetomas(F: file of integer);
var
  i: integer; arr: mas;
begin
  reset(F);
  setlength(arr, filesize(F));
  for i := 0 to high(arr) do
    read(F, arr[i]);
  QuickSort(arr, 0, length(arr) - 1);
  mastofile(arr, F);
end;
 
procedure slivfile(F1, F2: file of integer; F: file of integer);
var
  x, y: integer;
begin
  reset(F1);
  reset(F2);
  rewrite(F);
  while not eof(F1) and not eof(F2)  do
  begin
    read(F1, x);
    read(F2, y);
    if x < y
    then
    begin
      write(F, x);
      seek(F2, FilePos(F2) - 1)
    end
    else
    begin
      write(F, y);
      seek(F1, FilePos(F1) - 1)
    end;
  end;
  if not eof(F1) or not eof(F2) then
  begin
    while not eof(F2) do
    begin
      read(F2, x);
      write(F, x)
    end;
    while not eof(F1) do
    begin
      read(F1, x);
      write(F, x)
    end;
  end;
  close(F);
  close(F1);
  close(F2)
end;
 
procedure sortfile(F: file of integer; name: string);
var
  x, n: integer; F1, F2: file of integer; name1, name2: string;
begin
  reset(F);
  if filesize(F) <= 10 
    then
    filetomas(F)
  else
  begin
    name1 := name + '1.dat';
    assign(F1, name1);
    rewrite(F1);
    name2 := name + '2.dat';
    assign(F2, name2);
    rewrite(F2);
    n := filesize(F) div 2;
    while not eof(F) do
      if FilePos(F) <= n
      then 
      begin
        read(F, x);
        write(F1, x)
      end
      else
      begin
        read(F, x);
        write(F2, x)
      end;
    close(F);
    sortfile(F1, name + '1');
    sortfile(F2, name + '2');
    slivfile(F1, F2, F);
  end;
  DeleteFile(name1);
  DeleteFile(name2)
end;
 
begin
  writeln('Введите длину массива:');
  readln(n);
  genfile(F, n);
  writeln('До сортировки:');
  showfile(F);
  sortfile(F, 'FileData');
  writeln('После сортировки:');
  showfile(F)
end.