Кривая Серпинского

uses GraphABC;
 
type
  TPoint = auto class
    X, Y: real;
  end;
 
procedure RLine(x, y, x1, y1: real) := Line(Round(x), Round(y), Round(x1), Round(y1)); 
 
procedure Draw(pA, pB: TPoint; invert: boolean; angle: integer);
var
  p1, p2: TPoint;
 
begin
  var r := Sqrt(Sqr(pB.X - pA.X) + Sqr(pB.Y - pA.Y)) / 2;
  var v := 1 - 2 * Ord(invert);
  var ang1 := DegToRad(angle - 60 * v);
  p1 := new TPoint(pA.X + r * Cos(ang1), pA.Y + r * Sin(ang1));
  
  var ang2 := DegToRad(angle - 120 * v);
  p2 := new TPoint(pB.X + r * Cos(ang2), pB.Y + r * Sin(ang2));
  
  if r < 10 then
  begin
    RLine(pA.X, pA.Y, p1.X, p1.Y);
    RLine(p1.X, p1.Y, p2.X, p2.Y);
    RLine(p2.X, p2.Y, pB.X, pB.Y);
  end
  else
  begin
    Draw(pA, p1, not invert, angle - 60);
    Draw(p1, p2, invert, angle);
    Draw(p2, pB, not invert, angle + 60);
  end;
end;
 
begin
  Draw(new TPoint(100, 300), new TPoint(500, 300), false, 0); // Изначально в качестве угла передается 0.
end.

uses GraphABC;
 
procedure RLine(x, y, x1, y1: real) := Line(Round(x), Round(y), Round(x1), Round(y1)); 
 
function GetAngle(x, y, x2, y2: real): real;
begin
  var angle := Abs(RadToDeg(ArcTan((y2 - y) / (x2 - x))));
  if (x2 = x) and (y2 = y) then
    Result := 0
  else
    if x2 > x then
      if y2 > y then Result := angle else Result := 360 - angle
    else
      if y2 > y then Result := 180 - angle else Result := 180 + angle;
end;
 
procedure Draw(x, y, x1, y1: real; inverted: boolean);
begin
  var angle := GetAngle(x, y, x1, y1);
  var s := 1 - 2 * Ord(inverted);
  var r := Sqrt(Sqr(x1 - x) + Sqr(y1 - y)) / 2;
  
  var ang1 := DegToRad(angle - 60 * s);
  var xA := x + r * Cos(ang1);
  var yA := y + r * Sin(ang1);
  
  var ang2 := DegToRad(angle - 120 * s);
  var xB := x1 + r * Cos(ang2);
  var yB := y1 + r * Sin(ang2);
  
  if 2 * r < 8 then
  begin
    RLine(x, y, xA, yA);
    RLine(xA, yA, xB, yB);
    RLine(xB, yB, x1, y1);
  end
  else
  begin
    Draw(x, y, xA, yA, not inverted);
    Draw(xA, yA, xB, yB, inverted);
    Draw(xB, yB, x1, y1, not inverted);
  end;
end;
 
begin
  Draw(100, 100, 400, 450, false);
end.