Разбор программы 2

program live;
uses graphabc;
 
const n=100;              // размер поля
      r=round(500/n);    // размер клетки поля
      d=0;             // задержка после вывода на экран
 
type pole=array [0..n+1,0..n+1] of boolean;
 
var i,j,k:integer;
    p,p1:pole;
    b:boolean;
    
function sosedi(x,y:integer):integer;    // расчёт количества соседей у выбранной клетки
var i,j,s:integer;
begin
  s:=0;
  for i:=-1 to 1 do
    for j:=-1 to 1 do
      if not((i=0)and(j=0))and(p[x+i,y+j]) then s:=s+1;
  sosedi:=s;
end;
 
function endlive:boolean;    // проверка на окончание жизни
var i,j:integer;
    b:boolean;
begin
  b:=false;
  for i:=1 to n do
    for j:=1 to n do
      if p[i,j] then b:=true;
  endlive:=not b;
end;
 
procedure outlive;      // вывод всего на экран
var i,j:integer;
begin
  for i:=1 to n do
    for j:=1 to n do
    begin
      if p[i,j] then setbrushcolor(rgb(255,0,0)) else setbrushcolor(clwhite);
      if p[i,j] then setpencolor(rgb(255,0,0)) else setpencolor(clwhite);
      rectangle((i-1)*r,(j-1)*r,i*r,j*r);
    end;
end;
 
begin
k:=0;
setwindowsize(500,515);
randomize;
lockdrawing;
for i:=0 to n+1 do
begin
  p[i,0]:=false;
  p[i,n+1]:=false;
  p[0,i]:=false;
  p[n+1,i]:=false;
  p1[i,0]:=false;
  p1[i,n+1]:=false;
  p1[0,i]:=false;
  p1[n+1,i]:=false;
end;
for i:=1 to n do
  for j:=1 to n do
    if random<0.5 then p[i,j]:=true else p[i,j]:=false;
outlive;
redraw;
sleep(d);
 
repeat
  k:=k+1;
  for i:=1 to n do
    for j:=1 to n do
      if (sosedi(i,j)=2)or(sosedi(i,j)=3) then begin 
                                                 if p[i,j] then p1[i,j]:=true; 
                                                 if not(p[i,j])and(sosedi(i,j)=3) then p1[i,j]:=true; 
                                               end
                                          else if p[i,j] then p1[i,j]:=false;
  if p=p1 then b:=true else b:=false;
  p:=p1;
  outlive;
  textout(50,500,inttostr(k)+' поколение');
  redraw;
  sleep(d);
until (endlive)or(b);
setfontcolor(clblack);
if b then textout(50,50,'И жили они долго и счастливо!') else textout(50,50,'Жизнь закончилась!');
textout(50,80,'Количество поколений : '+inttostr(k));
redraw;
sleep(5000);
closewindow;
end.