Построить график функции

uses GraphABC;
 
const
  n = 500;
  w = 50;
 
var
  a, b, fMin, fMax, mx, my, dx, dy: real;
  x0, y0: integer;
 
//Набор функций:
function f(n: byte; x: real): real;
begin
  case n of { Сюда можно добавлять больше функций: }
    1: f := x;
    2: f:= 9 * x * x;
    3: f := 8 * x
  end
end;
 
procedure MinMax(a, b: real; var fMin, fMax: real);
var
  i: integer;
  x, y: real;
begin
  fMin := f(1, a); fMax := f(1, b);
  for i := 0 to n do begin
    x := a + (b - a) * i / n;
    y := f(1, x);
    if y > fMax then fMax := y;
    if y < fMin then fMin := y
  end;
end;
 
///Масштаб системы координат относительно размеров окна и интервалов функции
procedure mashtab(str: string; a, b: real; d: integer; var m: real);
begin
  if str = 'OX' then m := d / (b - a)
  else
  if str = 'OY' then
    if a < 0 then
      if b > 0 then m := d / (b - a)
      else m := D / abs(a)
    else m := d / b;
end;
 
///Процедура вычисляет начало координат x0, y0
procedure NachaloCoordinat(a, b, fMin, fMax, mx, my: real);
begin
  if a < 0 then
    if b < 0 then x0 := WindowWidth - w
    else x0 := trunc(abs(a) * mx) + w
  else x0 := w;
  if fMin < 0 then
    if fMax < 0 then y0 := w + 0
    else y0 := WindowHeight - trunc(abs(fMin) * my) - w
  else y0 := WindowHeight - w;
end;
 
///Рисуем систему координат
procedure SystemCoordinate;
var
  N: real;
  i, j, x, y, x1: integer;
  s: string;
begin
  Line(20, y0, WindowWidth - 20, y0);  //OX
  Line(x0, 20, x0, WindowHeight - 20); //OY
  SetFontSize(8);
  { Çàñå÷êè íà îñè OX: }
  j := round((b - a) / dx) + 1;//количество засечек
  for i := 1 to j do begin
    N := a + (i - 1) * dx;
    x := w + trunc((i - 1) * Mx * dx);
    Line(x, y0 - 3, x, y0 + 3); //рисуем засечки на оси OX
    { Вертикальная сетка: }
    SetPenColor(RGB(200, 200, 200));
    SetpenStyle(psDot);
    if abs(N) > 0.000001 then begin
      Line(x, w, x, y0 - 15); //
      Line(x, y0 + 30, x, WindowHeight - w) //
    end;
    { Надписи на OX: }
    SetPenColor(RGB(0, 0, 0));
    SetpenStyle(psSolid);
    str(N, s);
    SetFontColor(clRed);
    if abs(N) > 0.0000001 then TextOut(x - TextWidth(s) div 2, y0 + 10, s)
  end;
  { Засечки на оси OY: }
  if fMin * fMax < 0 then j := round((Fmax - Fmin) / dy) + 1
  else
    if abs(fMax) > abs(fMin) then  j := round(abs(fMax) / dy) + 1
    else j := round(abs(fMin) / dy) + 1;
  for i := 1 to j do begin
    if fMin < 0 then N := fMin + (i - 1) * dy
    else N := (i - 1) * dy;
    y := WindowHeight - w - trunc((i - 1) * My * dy);
    Line(x0 - 3, y, x0 + 3, y); //рисуем засечки на оси Oy
    { Горизональная сетка: }
    SetPenColor(RGB(200, 200, 200));
    SetpenStyle(psDot);
    if abs(N) > 0.000001 then begin
      Line(w, y, x0 - 10, y); //
      Line(x0 + 20, y, WindowWidth - w, y) //
    end;
    { Надписи на ОY: }
    SetPenColor(RGB(0, 0, 0));
    SetpenStyle(psSolid);
    str(N, s);
    SetFontColor(clBlue);
    if abs(N) > 0.00000001 then TextOut(x0 + 7, y - TextHeight(s) div 2, s)
  end
end;
 
///Данный интервал [a, b] заменяем на новый (наиболее подходящий для данного шага d)
procedure Interval(d: real; var a, b: real);
begin
  if frac(a / d) <> 0 then begin
    a := trunc(a / d) * d - d;
    if a >= 0 then a := a + d
  end;
  if frac(b / d) <> 0 then begin
    b := trunc(b / d) * d;
    if b > 0 then b := b + d
  end
end;
 
//Процедура рисования графика f(m, x)
procedure Graphik(m: byte);
var
  x, y: real;
  i: integer;
begin
 { Ставим первую точку на графике: }
  if (a < 0)and(b < 0) then MoveTo(x0 - round((b - a) * mx), y0 - round(my * f(m, a)))
  else
  if (a > 0)and(b > 0) then MoveTo(x0, y0 - round(my * f(m, a)))
  else MoveTo(x0 + round(a * mx), y0 - round(my * f(m, a)));
 { Строим график с помощью маленьких отрезков: }
  for i := 0 to n do begin
    x := a + i * (b - a) / n;
    if x <> 0 then
      if (abs(f(m, x)) < 1000000) then y := f(m, x);
      if (a > 0)and(b > 0) then x := x - a
      else
      if (a < 0)and(b < 0) then x := x - b;
    if abs(x) > 0.0000001 then LineTo(x0 + round(x * mx), y0 - round(y * my))
  end
end;
 
begin
  MaximizeWindow;
  //SetWindowSize(800, 600);
  
  a := -0.3; b := 0.3;  //диапазон
  dx := 0.02; dy := 0.05; //шаг по x и по y
  
  Interval(dx, a, b);
  mashtab('OX', a, b, WindowWidth - 2 * w, mx);
  MinMax(a, b, fMin, fMax);
  Interval(dy, fMin, fMax);
  mashtab('OY', fMin, fMax, WindowHeight - 2 * w, my);
  NachaloCoordinat(a, b, fMin, fMax, mx, my);
  SystemCoordinate;
  SetPenWidth(2);
  { Вызываем процедуры рисования графиков: }
  SetPenColor(clGreen); Graphik(1);
  SetPenColor(clBlue);  Graphik(2);
  SetPenColor(clBrown); Graphik(3)
end.