Найти сумму элементов, у которых сумма делителей меньше данного числа Х

function numberIsCorrect(number : integer; sumDivider : integer) : boolean;
var
   i   : integer;
   sum : integer;
begin
   result := true;
   if number <> 0 then
   begin
      sum := 0;
      for i := 1 to abs(number) div 2 do
      begin
         if (abs(number) mod i = 0) then sum := sum + i;
         if sum >= sumDivider then
         begin
            result := false;
            break;
         end;
      end;
   end;
   numberIsCorrect := result;
end;
 
//######################################################################
 
procedure fillRandomArray(var arr : array of integer; startRange : integer; endRange : integer);
var 
  i : integer;
  
begin
   if length(arr) > 0 then
   begin
      randomize;
      for i := 0 to length(arr) - 1 do arr[i] := random(endRange + 1 - startRange) + startRange;
   end;
end;
 
//######################################################################
 
function toString(arr : array of integer) : String;
var
   i : integer;
begin
   result := '[';
   if length(arr) > 0 then
   begin
      for i := 0 to length(arr) - 1 do
      begin
         result := result + arr[i];
         if i <> length(arr) - 1 then result := result + ', ';
      end;
   end;
   toString := result + ']';
end;
 
//######################################################################
 
function readConsole(text : String; startRange : integer; endRange : integer) : integer;
begin
   result := startRange - 1;
   while (result < startRange) or (result > endRange) do
   begin
      write(text);
      readln(result);
   end;
   readConsole := result;
end;
 
//######################################################################
 
function sumNumber(arr : array of integer; sumDivider : integer) : integer;
var
   i : integer;
   
begin
   result := 0;
   if length(arr) > 0 then
   begin
      for i := 0 to length(arr) - 1 do
      begin
         if numberIsCorrect(arr[i], sumDivider) then result := result + arr[i]; 
      end;
   end;
   sumNumber := result;
end;
 
//######################################################################
 
var
   arr  : array of integer;
   n, x : integer;
   
begin
   n := readConsole('Введите размер массива (1 <= n <= 50): ', 1, 50);
   x := readConsole('Введите Х (предел суммы делителей числа): ', 1, 1000);
   setLength(arr, n);
   fillRandomArray(arr, 1, 100);
   writeln('Массив: ', toString(arr));
   write('Сумма чисел в массиве, у которых сумма делителей не более ', x, ' равна ', sumNumber(arr, x));
end.