Построение таблицы значений функции

function Sum(x, e: real; q, f: integer): real;
var
  a, m, d1, d2, s: real;
  k: integer;
begin
  d1 := (f - 1) * 0.5 - 0.25; // для первой суммы получится -0.25, для второй 0.25
  d2 := d1 + 0.5; // для первой суммы получится 0.25, для второй 0.75
  m := -pi * pi * x * x * x * x / 16;
  if f = 1 then a := x else a := pi * x * x * x / 3; // a_0
  k := 0;
  s := a;
  while (abs(a) > e) and (k < q - 1) do
    begin
      inc(k);
      a := m * a / (k + d1) / (k + d2);
      s := s + a
    end;
  Sum := s
end;
 
const
  zmin = 0;
  zmax = 5;
  hor = '+----------+--------------------+';
var
  zn, zk, hz, z, Cz, eps, t: real;
  n, p: integer;
begin
  repeat
    write('Начальная граница итервала ', zmin, ' <= zn < ', zmax, ';  zn = ');
    readln(zn)
  until (zmin <= zn) and (zn < zmax);
  repeat
    write('Конечная граница итервала ', zn:0:2, ' < zk <= ', zmax, ';  zn = ');
    readln(zk)
  until (zn < zk) and (zn <= zmax);
  repeat
    write('Шаг 0 < hz <= ', zk-zn:0:2, ';  hz = ');
    readln(hz)
  until (0 < hz) and (hz <= zk - zn);
  repeat
    writeln('1 - считать суммы с заданной точностью');
    writeln('2 - суммировать заданное количество членов');
    write('Ваш выбор: ');
    readln(p)
  until p in [1, 2];
  if p = 1 then
    begin
      repeat
        write('0 < eps < 1;  eps = ');
        readln(eps)
      until (0 < eps) and (eps < 1);
      eps := eps / 2;
      n := MaxInt
    end
  else
    begin
      repeat
        write('n > 0;  n = ');
        readln(n)
      until n > 0;
      eps := 0
    end;
    writeln;
    writeln('Таблица для нтеграла френеля');
    writeln(hor);
    writeln('|     z    |         C(z)       |');
    writeln(hor);
  z := zn;
  zk := zk + hz / 2;
  while z < zk do
    begin
      t := pi * z * z / 2;
      Cz:= cos(t) * Sum(z, eps, n, 1) + sin(t) * Sum(z, eps, n, 2);
      writeln('| ', z:8:6, ' | ', Cz:18:15, ' |');
      z := z + hz
    end;
  writeln(hor);
  readln
end.