Написать модуль, определяющий для произвольного выпуклого многоугольника максимальную длину стороны и диагонали

unit unit1;
interface
uses crt,graphABC;
const nmax=15;
      t=0.01;//точность для сравнения длин линий
type point=record
           x,y:real;
           end;
     mas=array[1..nmax+1] of point;
procedure Vvod(var a:mas; var n:byte);
procedure MaxStorona(a:mas; n:byte; var mxs:real;var i1,i2:byte);
procedure MaxDiagonal(a:mas; n:byte; var mxd:real;var i1,i2:byte);
procedure Vyvod(a:mas;n:byte;mxs,mxd:real;s1,s2,d1,d2:byte);
procedure Polygon(a:mas;n:byte;mxs,mxd:real);
 
implementation
//ввод данных
procedure Vvod(var a:mas; var n:byte);
var i:byte;
begin
repeat
write('Количество вершин от 4 до ',nmax,' n=');//треугольник не нужно, в нем нет диагоналей
read(n);
until n in [4..nmax];
writeln('Введите координаты вершин в порядке обхода:');
for i:=1 to n do
 begin
  writeln('Вершина ',i);
  write('X=');read(a[i].x);
  write('Y=');read(a[i].y);
 end;
a[n+1].x:=a[1].x;
a[n+1].y:=a[1].y;
write('Нажмите Enter');
readln;
end;
//определение длины стороны
Function Dlina(a,b:point):real;
begin
result:=sqrt(sqr(a.x-b.x)+sqr(a.y-b.y));
end;
function Perimetr(a:mas;n:byte):real;
var i:byte;
begin
result:=0;
for i:=2 to n+1 do
result:=result+Dlina(a[i],a[i-1]);
end;
//площадь через векторное произведение
function Ploshad(a:mas;n:byte):real;
var i:byte;
begin
result:=0;
for i:=1 to n do
result:=result+(a[i+1].y+a[i].y)*(a[i+1].x-a[i].x)/2;
result:=abs(result);//может получиться и отрицательное произведение
end;
//длинная сторона
procedure MaxStorona(a:mas; n:byte; var mxs:real;var i1,i2:byte);
var i:byte;
begin
mxs:=Dlina(a[1],a[2]);
i1:=1;
i2:=2;
for i:=3 to n+1 do
if Dlina(a[i],a[i-1])>mxs then
 begin
  mxs:=Dlina(a[i],a[i-1]);
  i1:=i-1;
  i2:=i;
 end;
end;
//длинная диагональ
procedure MaxDiagonal(a:mas; n:byte; var mxd:real;var i1,i2:byte);
var i,j:byte;
begin
mxd:=Dlina(a[1],a[3]);
i1:=1;
i2:=3;
for i:=1 to n-1 do
for j:=i+2 to n do
if Dlina(a[i],a[j])>mxd then
 begin
  mxd:=Dlina(a[i],a[j]);
  i1:=i;
  i2:=j;
 end;
end;
//вывод входных данных и результатов
procedure Vyvod(a:mas;n:byte;mxs,mxd:real;s1,s2,d1,d2:byte);
var i,j:byte;
begin
clrscr;
writeln('Координаты вершин многоугольника:');
write('X:');
for i:=1 to n do
write(a[i].x:5:1);
writeln;
write('Y:');
for i:=1 to n do
write(a[i].y:5:1);
writeln;
writeln('Длины сторон в порядке обхода:');
for i:=2 to n+1 do
 begin
  write('Сторона ',i-1,'-',i,'=');
  writeln(Dlina(a[i],a[i-1]):5:2);
 end;
writeln('Периметр=',Perimetr(a,n):0:2);
writeln('Площадь=',Ploshad(a,n):0:2);
writeln('Сторона с максимальной длиной ',s1,'-',s2,' длина=',mxs:0:2);
writeln('Длины диагоналей в порядке обхода:');
for i:=1 to n-1 do//от первой до предпоследней=начало
for j:=i+2 to n do//от i+2 до последней=конец
if (i=1)and(j=n) then continue//первую с последней не нужно, это сторона
else
 begin
  write('Диагональ ',i,'-',j,'=');
  writeln(Dlina(a[i],a[j]):5:2);
 end;
writeln('Диагональ с максимальной длиной ',d1,'-',d2,' длина=',mxd:0:2);
write('Нажмите Enter');
readln;
end;
//рисование
procedure Polygon(a:mas;n:byte;mxs,mxd:real);
var xc,yc,x0,y0,i,j:integer;
    xmx,xmn,ymx,ymn,mx,my,m:real;
begin
hidecursor;
//установим графическое окно и его центр
setwindowsize(500,550);
clearwindow;
xc:=windowwidth div 2;
yc:=50+(windowheight-50) div 2;
//найдем максимальные и минимальные значения для рисования
xmn:=a[1].x;xmx:=a[1].x;
ymn:=a[1].y;ymx:=a[1].y;
for i:=1 to n do
 begin
  if a[i].x<xmn then xmn:=a[i].x;
  if a[i].x>xmx then xmx:=a[i].x;
  if a[i].y<ymn then ymn:=a[i].y;
  if a[i].y>ymx then ymx:=a[i].y;
 end;
//масштаб для перевода в экранные координаты
//по Х
if xmn>=0 then mx:=(2*xc-60)/xmx
else if xmx<=0 then mx:=(2*xc-60)/abs(xmn)
else if xmn*xmx<0 then mx:=(2*xc-60)/abs(xmx-xmn) ;
//по У
if ymn>=0 then my:=(2*xc-60)/ymx
else if ymx<=0 then my:=(2*xc-60)/abs(ymn)
else if ymn*ymx<0 then my:=(2*xc-60)/abs(ymx-ymn);
if mx<=my then m:=mx else m:=my;//выберем больший
//определим начало координат
if xmx<0 then x0:=2*xc-30
else if xmn>=0 then x0:=30
else if xmn*xmx<0 then  x0:=2*xc-round(2*xc*xmx/(xmx-xmn));
if ymx<=0 then y0:=80
else if ymn>=0 then y0:=windowheight-30
else if ymn*ymx<0 then y0:=50+round((2*xc-60)*ymx/(ymx-ymn));
//рисуем координатне оси(если нужно, то можно и деления нарисовать)
setpencolor(clGreen);
line(0,y0,2*xc,y0);
textout(2*xc-10,y0-20,'X');
line(x0,55,x0,2*yc);
textout(x0-15,55,'Y');
//рисуем многоугольник
setpenwidth(3);
for i:=1 to n do
 begin
  if abs(Dlina(a[i],a[i+1])-mxs)<t then setpencolor(clRed)//максимальные стороны красным
  else setpencolor(clBlack);//остальные черным
  line(x0+round(a[i].x*m),y0-round(a[i].y*m),x0+round(a[i+1].x*m),y0-round(a[i+1].y*m));
 end;
//рисуем диагонали, соединяем каждую вершину с каждой кроме соседних
setpenwidth(1);
for i:=1 to n-1 do//от первой до предпоследней=начало
for j:=i+2 to n do//от i+2 до последней=конец
if (i=1)and(j=n) then continue//первую с последней не нужно, это сторона
else
 begin
  if abs(Dlina(a[i],a[j])-mxd)<t then setpencolor(clBlue)//максимальные диагонали синим
  else setpencolor(clBlack);//остальные черным
  line(x0+round(a[i].x*m),y0-round(a[i].y*m),x0+round(a[j].x*m),y0-round(a[j].y*m));
 end;
setpenwidth(3);
setpencolor(clRed);
line(5,10,30,10);
textout(35,10,'Стороны максимальной длины');
setpenwidth(1);
setpencolor(clBlue);
line(5,30,30,30);
textout(35,30,'Диагонали максимальной длины');
end;
end.

uses Unit1;
var a:mas;
    n,s1,s2,d1,d2:byte;
    mxs,mxd:real;
begin
Vvod(a,n);
MaxStorona(a,n,mxs,s1,s2);
MaxDiagonal(a,n,mxd,d1,d2);
Vyvod(a,n,mxs,mxd,s1,s2,d1,d2);
Polygon(a,n,mxs,mxd);
end.