Разработать программу, моделирующую колебания маятника Ньютона

@Aziza94 · Регистрация: 24.04.2013

Студворк — интернет-сервис помощи студентам

разработать программу моделирующую колебания маятника Ньютона

@ermolay · 06.08.2013, 10:20

маятник (колыбель) Ньютона, упрощенная версия:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
uses
  graphABC, crt;
 
var
  i, j, x, y, x1, y1, s, r, k, d: integer;
 
begin
  setWindowWidth(640);
  setWindowHeight(480);
  lockdrawing;
  s := 1;
  r := 25; // радиус шара
  x := 320; y := 150;
  repeat
    case s of
      1: // первый шар поднимается
        begin
          i := 90; d := 9;
          while i < 135 do
          begin
            ClearWindow;
            rectangle(150, 137, 490, 150);
            for j := 0 to 3 do  // остальные шары с нитями
            begin
              k := 270 + j * 50;
              circle(k, y + 200, r);
              line(k, y, k, y + 200 - r);
            end;
            // расчитываем x, y центра шара
            x1 := x - 4 * r + round(200 * cos(i * pi / 180));
            y1 := y + round(200 * sin(i * pi / 180));
            i := i + d;
            line(220, y, x1, y1);  // нить движущегося шара
            circle(x1, y1, r);     // сам шар
            sleep(18);
            redraw;
            dec(d);
          end;
        end;
      2: // первый шар опускается
        begin
          i := 135; d := 0;
          while i > 90 do
          begin
            ClearWindow;
            rectangle(150, 137, 490, 150);
            for j := 0 to 3 do // остальные шары с нитями
            begin
              k := 270 + j * 50;
              circle(k, y + 200, r);
              line(k, y, k, y + 200 - r);
            end;
            // расчитываем x, y центра шара
            x1 := x - 4 * r + round(200 * cos(i * pi / 180));
            y1 := y + round(200 * sin(i * pi / 180));
            i := i - d;
            line(220, y, x1, y1); // нить движущегося шара
            circle(x1, y1, r);    // сам шар
            sleep(18);
            redraw;
            inc(d);
          end;
        end;
      3:  // последний шар поднимается
        begin
          i := 90; d := 9;
          while i > 45 do
          begin
            ClearWindow;
            rectangle(150, 137, 490, 150);
            for j := 0 to 3 do // остальные шары с нитями
            begin
              k := 220 + j * 50;
              circle(k, y + 200, r);
              line(k, y, k, y + 200 - r);
            end;
            // расчитываем x, y центра шара
            x1 := x + 4 * r + round(200 * cos(i * pi / 180));
            y1 := y + round(200 * sin(i * pi / 180));
            i := i - d;
            line(420, y, x1, y1); // нить движущегося шара
            circle(x1, y1, r);    // сам шар
            sleep(18);
            redraw;
            dec(d);
          end;
        end;
      4: // последний шар опускается
        begin
          i := 45; d := 0;
          while i < 90 do
          begin
            ClearWindow;
            rectangle(150, 137, 490, 150);
            for j := 0 to 3 do // остальные шары с нитями
            begin
              k := 220 + j * 50;
              circle(k, y + 200, r);
              line(k, y, k, y + 200 - r);
            end;
            // расчитываем x, y центра шара
            x1 := x + 4 * r + round(200 * cos(i * pi / 180));
            y1 := y + round(200 * sin(i * pi / 180));
            i := i + d;
            line(420, y, x1, y1); // нить движущегося шара
            circle(x1, y1, r);    // сам шар
            sleep(18);
            redraw;
            inc(d);
          end;
        end;
    end;
    inc(s); if s = 5 then s := 1;
  until KeyPressed;
end.

@ermolay · 25.08.2013, 20:00

в аксонометрии:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
uses
  graphABC, crt;
 
const
  x0 = 270; // x центра первого шара
  y0 = 315; // y центра первого шара
  h = 25;   // расстояние между шарами по горизонтали
  r = 25;   // радиус шара
  l = 150;  // длина нити
  p = 40;   // "плечо" нити
  h2 = round(r / sqrt(3));  // расстояние между шарами по вертикали
  // верхние координаты нитей
  xl1 = x0 - p;
  yl1 = y0 - l - round(p / sqrt(3));
  xl2 = x0 + p;
  yl2 = y0 - l + round(p / sqrt(3));
 
  a = (l + r) * 0.7;  // меньшая ось эллипса
  b = (l + r) * 1.22; // большая ось эллипса
  u = 30 * pi / 180;  // угол поворота эллипса
procedure corps(p,q: integer);
var
  x,y,i: integer;
begin
  x:=xl1; y:=yl1;
  setpencolor(clskyblue);
  moveto(x-2*h+p,y+2*h2+q);
  lineto(x+6*h+p,y-6*h2+q);
  lineto(x+6*h+p,y-6*h2+200+q);
  lineto(x+6*h+10+p,y-6*h2+200-6+q);
  lineto(x+6*h+10+p,y-6*h2-16+q);
  lineto(x-2*h-10+p,y+2*h2-6+q);
  lineto(x-2*h-10+p,y+2*h2+206+q);
  lineto(x-2*h+p,y+2*h2+200+q);
  lineto(x-2*h+p,y+2*h2+q);
  setpencolor(clblack);
end;
 
// шар и нити
procedure sphere(x_s, y_s: integer);
begin
  setPenColor(clwhite);
  circle(x_s, y_s, r);
  setPencolor(clblack);
  circle(x_s - 1, y_s - 1, r);
  floodfill(x_s, y_s, clblack);
  circle(x_s - 10, y_s - 10, 5);
  floodfill(x_s - 10, y_s - 10, clwhite);
  line(x_s, y_s, x_s - p, y_s - l - round(p / sqrt(3)));
  line(x_s, y_s, x_s + p, y_s - l + round(p / sqrt(3)));
end;
 
// неподвижные три шара
procedure three_spheres;
var
  i: byte;
begin
  for i := 3 downto 1 do
    sphere(x0 + h * i, y0 - h2 * i);
end;
 
procedure anim(i,p,q: integer);
var
  x1, y1: integer;
  x2, y2, x3, y3: real;
begin
  // координаты точек эллипса
  x2 := a * cos(i * pi / 180);
  y2 := b * sin(i * pi / 180);
  // поворот точек эллипса и движение
  x3 := x2 * cos(u) - y2 * sin(u);
  y3 := x2 * sin(u) + y2 * cos(u);
  x3 := x3 + x0 + p;
  y3 := y3 + y0 - 175 - q;
  x1 := round(x3); y1 := round(y3);
  circle(x1, y1, r);
  floodfill(x1, y1, clblack);
  circle(x1 - 10, y1 - 10, 5);
  floodfill(x1 - 10, y1 - 10, clwhite);
  moveto(xl1+p, yl1-q);
  lineto(round(x3), round(y3));
  lineto(xl2+p, yl2-q);
end;
 
var
  x1, y1, i, s, k, m, d: integer;
  x2, y2, x3, y3: real;
 
begin
  setWindowSize(640, 480);
  lockdrawing;
  s := 1;
 
  setPenColor(clSilver);
  repeat
    case s of
      1: // первый шар поднимается
        begin
          i := 45; d := 9;
          while i < 90 do
          begin
            ClearWindow;
            corps(0,0);
            corps(-2,-1);
            sphere(x0 + 4 * h, y0 - 4 * h2);
            three_spheres;
            anim(i,0,0);
            inc(i,d);
            corps(80,round(p / sqrt(3))*2);
            corps(80+2,round(p / sqrt(3))*2+1);
            sleep(30);
            redraw;
            dec(d);
          end;
        end;
      2: // первый шар опускается
        begin
          i := 90; d := 0;
          while i > 45 do
          begin
            ClearWindow;
            corps(0,0);
            corps(-2,-1);
            sphere(x0 + 4 * h, y0 - 4 * h2);
            three_spheres;
            anim(i,0,0);
            dec(i,d);
            corps(80,round(p / sqrt(3))*2);
            corps(80+2,round(p / sqrt(3))*2+1);
            sleep(30);
            redraw;
            inc(d);
          end;
        end;
      3:  // последний шар поднимается
        begin
          i := 45; d := 9;
          while i > 0 do
          begin
            ClearWindow;
            corps(0,0);
            corps(-2,-1);
            dec(i,d);
            anim(i,4*h,4*h2);
            three_spheres;
            sphere(x0, y0);
            corps(80,round(p / sqrt(3))*2);
            corps(80+2,round(p / sqrt(3))*2+1);
            sleep(30);
            redraw;
            dec(d);
          end;
        end;
      4: // последний шар опускается
        begin
          i := 0; d := 0;
          while i < 45 do
          begin
            ClearWindow;
            corps(0,0);
            corps(-2,-1);
            anim(i,4*h,4*h2);
            inc(i,d);
            three_spheres;
            sphere(x0, y0);
            corps(80,round(p / sqrt(3))*2);
            corps(80+2,round(p / sqrt(3))*2+1);
            sleep(30);
            redraw;
            inc(d);
          end;
        end;
    end;
    inc(s); if s = 5 then s := 1;
  until KeyPressed;
end.

@chipallaxa · 23.06.2022, 16:57

Здравствуйте, скажите пожалуйста ,копирую первый код ,вставляю в abc.net и ничего не происходит. В чем проблема?

@Cyborg Drone · 23.06.2022, 21:05

Чтобы программа просто заработала, замените

Pascal
2
  graphABC;

Pascal
114
  until false;

Новые блоги и статьи Все статьи Все блоги /
Автозаполнение реквизита при выборе элемента справочника Maks 27.03.2026 Программный код из решения ниже на примере нетипового документа "ЗаявкаНаРемонтСпецтехники" разработанного в конфигурации КА2. При выборе "Спецтехники" (Тип Справочник. Спецтехника), заполняется. . .	Сумматор с применением элементов трёх состояний. Hrethgir 26.03.2026 Тут. https:/ / fips. ru/ EGD/ ab3c85c8-836d-4866-871b-c2f0c5d77fbc Первый документ красиво выглядит, но без схемы. Это конечно не даёт никаких плюсов автору, но тем не менее. . . всё может быть. . .	Автозаполнение реквизитов при создании документа Maks 26.03.2026 Программный код из решения ниже размещается в модуле объекта документа, в процедуре "ПриСозданииНаСервере". Алгоритм проверки заполнения реализован для исключения перезаписи значения реквизита,. . .	Команды формы и диалоговое окно Maks 26.03.2026 1. Команда формы "ЗаполнитьЗапчасти". Программный код из решения ниже на примере нетипового документа "ЗаявкаНаРемонтСпецтехники" разработанного в конфигурации КА2. В качестве источника данных. . .
Кому нужен AOT? DevAlt 26.03.2026 Решил сделать простой ланчер Написал заготовку: dotnet new console --aot -o UrlHandler var items = args. Split(":"); var tag = items; var id = items; var executable = args;. . .	Отправка уведомления на почту при создании или изменении элементов справочника Maks 24.03.2026 Программная отправка письма электронной почты на примере типового справочника "Склады" в конфигурации БП3. Перед реализацией необходимо выполнить настройку системной учетной записи электронной. . .	модель ЗдравоСохранения 5. Меньше увольнений- больше дохода! anaschu 24.03.2026 Теперь система здравосохранения уменьшает количество увольнений. 9TO2GP2bpX4 a42b81fb172ffc12ca589c7898261ccb/ https:/ / rutube. ru/ video/ a42b81fb172ffc12ca589c7898261ccb/ Слева синяя линия -. . .	Midnight Chicago Blues kumehtar 24.03.2026 Такой Midnight Chicago Blues, знаешь?. . Когда вечерние улицы становятся ночными, а ты не можешь уснуть. Ты идёшь в любимый старый бар, и бармен наливает тебе виски. Ты смотришь на пролетающие. . .

Разработать программу, моделирующую колебания маятника Ньютона

Решение

Решение

@Aziza94 1 / 1 / 0 Регистрация: 24.04.2013 Сообщений: 27

	Разработать программу, моделирующую колебания маятника Ньютона 05.08.2013, 14:29. Показов 2601. Ответов 4 Метки нет (Все метки) разработать программу моделирующую колебания маятника Ньютона 0

@chipallaxa 0 / 0 / 0 Регистрация: 13.06.2022 Сообщений: 5
	23.06.2022, 16:57
	Здравствуйте, скажите пожалуйста ,копирую первый код ,вставляю в abc.net и ничего не происходит. В чем проблема? 0