Какая альтернатива switch быстрее?

#!perl
 
=pod
 
Какой вариант переключения между многоими ветвями алгоритма самый 
быстрый
 
switch takes 8 s
if-elsif takes 5 s
predefined array takes 3 s
 
при малом числе ветвлений - if-elsif
 
=cut
 
use Modern::Perl;
use Time::Piece;
use Time::Seconds;
use constant (MAX => 10_000_000);
 
$|++;
 
my ($a, $b, $c, $d, $e, $f, $g, $h, $i, $j) = 0;
my $t = localtime;
 
sub chkpoint($) {
    printf "$_[0] takes %d s\n", (localtime() - $t)->seconds;
    say "$a\t$b\t$c\t$d\t$e\t$f\t$g\t$h\t$i\t$j\n";
    ($a, $b, $c, $d, $e, $f, $g, $h, $i, $j) = 0;
    $t = localtime;
}
 
 
{
no warnings;
for (0..MAX) {
    given (int rand 10) {
        when (0) {$a++}
        when (1) {$b++}
        when (2) {$c++}
        when (3) {$d++}
        when (4) {$e++}
        when (5) {$f++}
        when (6) {$g++}
        when (7) {$h++}
        when (8) {$i++}
        when (9) {$j++}
        default {die}
    }
}
}
chkpoint "switch";
 
 
for (0..MAX) {
    my $idx = int rand 10;
    if ($idx == 0) {$a++}
    elsif ($idx == 0) {$a++}
    elsif ($idx == 1) {$b++}
    elsif ($idx == 2) {$c++}
    elsif ($idx == 3) {$d++}
    elsif ($idx == 4) {$e++}
    elsif ($idx == 5) {$f++}
    elsif ($idx == 6) {$g++}
    elsif ($idx == 7) {$h++}
    elsif ($idx == 8) {$i++}
    elsif ($idx == 9) {$j++}
    else {die}
}
chkpoint "if-elsif";
 
 
my @a = (
    sub {$a++},
    sub {$b++},
    sub {$c++},
    sub {$d++},
    sub {$e++},
    sub {$f++},
    sub {$g++},
    sub {$h++},
    sub {$i++},
    sub {$j++},
);
for (0..MAX) {
    $a[int rand 10]->();
}
chkpoint "predefined array";

#!perl
 
=pod
 
1) Какая конструкция быстрее:
 
    for (0..N) {
        given ($_) {
            when (0) { branch0() }
            when (1) { branch1() }
            ...
        }
    }
 
    for (0..N) {
        for ($_) {
            branch0() when $_ == 0;
            branch1() when $_ == 1;
            ...
        }
    }
 
    for (0..N) {
        if ($_ == 0) { branch0() }
        elsif ($_ == 1) { branch1() }
        ...
    }
 
    # @branches = ( \branch0, \branch1 )
    for (0..N) {
        $branches[$_]->()
    }
 
2) Как число "ветвей" и характеристики железа (кэш, скорость ЦП) влияют на скорость?
 
3) Ф-ции предопределённые и внедрённые в контекст в результате "кодогенерации на ходу" работают с одинаковой скоростью?
 
 
 
 "Xeon E3 1235" 1.5 - 2.8 GHz, 8M + 4x256K
 BRANCHES   первая и последняя строка Benchmark*
                       Rate   for given    if array
  3         array 1186427/s  117%  103%   15%    --
                       Rate given   for    if array
  9         array  502758/s  321%  236%   94%    --
  100       array   51355/s 2322% 1504% 1020%    --
  100       array   76615/s 2849% 1875% 1265%    --
 
 "Athlon 64 X2 5200+" 2.7 GHz, 2x512K
 BRANCHES   первая и последняя строка Benchmark
                       Rate   for given    if array
  3         array  988320/s  134%  112%   29%    --
                       Rate given   for    if array
  9         array  409951/s  272%  259%  113%    --
  100       array   37996/s 2308% 1695% 1201%    --
 
* из первой строки видно как распределились "конкуренты", последний
самый быстрый; из последней строки видно процент преимущества данной
альтернативы по отношению к каждой из остальных;
см. https://metacpan.org/pod/Benchmark#cmpthese-(-COUNT,-CODEHASHREF,-%5B-STYLE-%5D-)
 
=cut
 
use strict;
use warnings;
use Benchmark 'cmpthese';
 
use feature qw'say switch';
no warnings "experimental::smartmatch";
 
use constant
    BRANCHES => 9;
 
my @branches;
 
# создание однотипных функций-ветвей алгоритма
# каждая функция
#   возвращает число предидущих её вызовов
#   является замыканием т.е. ??? создаёт отдельный экземпляр переменной-счётчика,
#     при выходе из контекста, где объявлен счётчик my $c
#   имя функции "внедряется" в ??? "глобальный контекст"
#     см. https://perldoc.perl.org/5.30.0/perlref.html#Function-Templates
for (0 .. BRANCHES - 1) {
    no strict 'refs';
    my $c = 0; # counter
    my $n = "branch$_"; # function name: branch0, branch1,...
 
    *$n = sub { $c++ };
 
    $branches[$_] = \&$n;
}
 
#say branch1() for 1..5; # теперь они существуют
#say branch2(); # 5 or 0 ? - у каждой свой счётчик
#__END__
 
# генерирует исходный код блоков для тестирования
# каждый блок включает
#   конструкцию вызова ветви по индексу и
#   цикл обеспечивающий однократный вызов каждой ветви
# параметры:
#   начальная строка
#   callback-функция для генерации кода вызова ветви
#   конечная строка
# возвращает ссылку на анонимную ф-цию
sub make_unit($$$) {
    my $s = shift;
    my $f = shift;
    $s .= "\n\t" . $f->() . "\n" for 0 .. BRANCHES - 1;
    $s .= shift;
    $s =<<END; 
sub {
  for (0 .. BRANCHES - 1) {
    $s } }
END
    $s =~ s/^\s*\n//gms; # пустые строки
    say $s;
    eval $s // die "making unit failed: $@";
}
 
cmpthese -1, {
    'given' => make_unit(
        'given ($_) {',
        sub { "when ($_) { branch$_() }" },
        '}'
    ),
    'for' => make_unit(
        'for ($_) {',
        sub { "branch$_() when \$_ == $_;" },
        '}'
    ),
    'if' => make_unit(
        '',
        sub { ($_ ? 'elsif' : 'if') . " (\$_ == $_) { branch$_() }" },
        ''
    ),
    'array' => make_unit(
        '$branches[$_]->()',
        sub {''},
        ''
    ),
};
 
 
#say join ', ', map {eval "branch$_()"} (0 .. BRANCHES - 1);
say "\nthe number of times every branch run - " . branch0();