Нечетная длина элементов списка

@DmitryM5 · Регистрация: 27.08.2013

Студворк — интернет-сервис помощи студентам

Что не так,я не пойму?
%1)Определить предикаты "чет" и "нечет" определяющие чётность и нечётность длины списка (предикат "длина" не использовать).

Prolog
1
2
3
%odd_list(spisok).
odd_list([],Temp):-Temp mod 2=0.
odd_list([_|T],Temp):-odd_list(T,Temp1),Temp is Temp1+1.

@Black Fregat · 20.03.2015, 01:24

Прежде всего, Вы смешиваете два разных подхода к обработке списков.

Стандартный способ: от хвоста к голове. Обработка непустого списка начинается с рекурсивной обработки хвоста, затем голова как-то примешивается к полученному результату. Выход из рекурсии, как правило, на пустом списке, результат для которого задается напрямую, отдельным правилом.

Prolog
1
2
3
4
process([], <некоторая константа>).
process([H|T], R) :-
    process(T, RT),
    R is <некоторые действия с H и RT>.

Способ с накоплением: от головы к хвосту. Требует использования дополнительного параметра для накопления результата. Этот параметр должен быть каким-то образом установлен в начальное значение (например, в обертывающем предикате). На каждом шаге голова списка как-то примешивается к накопленному значению, а затем рекурсивно обрабатывается хвост уже с новым значением накопителя. Выход из рекурсии, как правило, на пустом списке, при этом результат сопоставляется с накопленным значением.

Prolog
1
2
3
4
5
6
7
process_envelop(L, R) :-
    process(L, <некоторая константа>, R).
 
process([], R, R).
process([H|T], R1, R) :-
    R2 is <некоторые действия с H и R1>,
    process(T, R2, R).

Добавлено через 16 минут
Ваш предикат работает с непустыми списками по первой схеме: он вначале вычисляет значение для хвоста, а потом прибавляет к нему единицу. Это значит, что на пустом списке никакого значение еще не будет. На пустом списке только-только должно возникнуть самое первое значение, которое затем, по мере выхода из предикатов будет дополняться обработкой каждой очередной головы.

Вместо этого Вы пытаетесь что-то сделать с этим значением, как будто оно уже существует. Такое возможно только при работе по второй схеме - с накоплением.

Если задаться целью довести до ума Вашу идею, нужно переписать одно из правил по другой схеме. Кроме того, обёртка понадобится в любом случае.

Схема 1:

Prolog
1
2
3
4
5
6
7
8
odd_list_1(L) :-
    odd_list_count(L, N),
    N mod 2 =:= 1.
 
odd_list_count([], 0).
odd_list_count([_|T], N) :-
    odd_list_count(T, NT),
    N is NT+1.

Схема 2:

Prolog
1
2
3
4
5
6
7
8
odd_list_2(L) :-
    odd_list_accum(L, 0, N),
    N mod 2 =:= 1.
 
odd_list_accum([], N, N).
odd_list_accum([_|T], N1, N) :-
    N2 is N1+1,
    odd_list_accum(T, N2, N).

Добавлено через 2 минуты
Но на самом деле нужный предикат можно написать гораздо проще, если отделять сразу по два элемента:

Prolog
1
2
3
odd_list([_]).
odd_list([_, _|T]) :-
    odd_list(T).

Добавлено через 5 минут
Для чётных списков в обеих схемах нужно поставить

Prolog
1
    N mod 2 =:= 0.

А в кратком варианте поменять выход из рекурсии:

Prolog
1
2
3
even_list([]).
even_list([_, _|T]) :-
    even_list(T).

Добавлено через 2 минуты
Примечание.
Схему 2 можно написать в кратком варианте:

Prolog
1
2
3
4
5
6
7
8
odd_list_2(L) :-
    odd_list_accum(L, 0).
 
odd_list_accum([], N) :-
    N mod 2 =:= 1.
odd_list_accum([_|T], N1) :-
    N2 is N1+1,
    odd_list_accum(T, N2).

@DmitryM5 · 20.03.2015, 17:55 **[ТС]**

Спасибо за разъяснения!

@ITyuri · 23.09.2018, 01:02

Ой, спасибо большое! После С++ на Prolog не догоняю.

@arlat · 28.09.2018, 18:13

Prolog
1
2
3
4
5
6
7
8
9
10
11
% если пустой список считать четным :)
length_oe([], even).
length_oe([_], odd).
length_oe([_, _ | T], OE) :-
    length_oe(T, OE).
 
% если пустой список нельзя - неудача
length_oe1([_, _], even).
length_oe1([_], odd).
length_oe1([_, _ | T], OE) :-
    length_oe1(T, OE).

Black Fregat уже и так все сказал, это я так

Новые блоги и статьи Все статьи Все блоги /
Ритм жизни kumehtar 27.02.2026 Иногда приходится жить в ритме, где дел становится всё больше, а вовлечения в происходящее — всё меньше. Плотный график не даёт вниманию закрепиться ни на одном событии. Утро начинается с быстрых,. . .	SDL3 для Web (WebAssembly): Сборка SDL3 и Box2D из исходников с помощью CMake и Emscripten 8Observer8 27.02.2026 Недавно вышла версия 3. 4. 2 библиотеки SDL3. На странице официальной релиза доступны исходники, готовые DLL (для x86, x64, arm64), а также библиотеки для разработки под Android, MinGW и Visual Studio. . . .	SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .
Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»

@DmitryM5 Консультант Витте 106 / 86 / 45 Регистрация: 27.08.2013 Сообщений: 1,356 Записей в блоге: 1
	20.03.2015, 17:55 [ТС]
	Спасибо за разъяснения! 0

@ITyuri 0 / 0 / 0 Регистрация: 23.09.2018 Сообщений: 1
	23.09.2018, 01:02
	Ой, спасибо большое! После С++ на Prolog не догоняю. 0

Нечетная длина элементов списка

Решение