Калькулятор в одну строчку

@Akiva · Регистрация: 05.07.2011

Студворк — интернет-сервис помощи студентам

Нашел на Форуме.
Немного переделал, добавил и изменил.
В функциях Cos,Sin,Tan вместо Radian, градусы.
С уважением, Akiva

@Akiva · 09.09.2012, 02:09 **[ТС]**

Немного переделал и добавил
счетчик ASCII.

@GD · 25.10.2012, 14:14

а как можно создать калькулятор времени ( часы и минуты)?

@Pro_grammer · 26.10.2012, 10:20

Время можно складывать и вычитать как обычные числа.Библиотека PureBasic - Date содержит всё для этого. Она оперирует секундами. Можно использовать так же AddDate

@GD · 28.10.2012, 00:55

а как сделать строку для ввода времени а именно (чч:мм).

@Pro_grammer · 28.10.2012, 15:48

Сообщение от GD

а как сделать строку для ввода времени а именно (чч:мм).

Обычная строка, StringGadget. Или проще две, одна для часов, другая для минут.

Сообщение от GD

калькулятор времени

Как вообще это должно выглядеть на практике?

@GD · 28.10.2012, 21:04

Сообщение от Pro_grammer

Как вообще это должно выглядеть на практике?

что то типо такого только без календаря, он лишний там, и что б то время можно было отправить в другие две стоки, в одну что б тупо скопировалось а в другую добавило 2 с половиной часа

@GD · 28.10.2012, 21:13

Сообщение от Pro_grammer

Обычная строка, StringGadget. Или проще две, одна для часов, другая для минут.

я делал две отдельные строки stringGadget, получилось что если введу например 12:06, после нажатия кнопки оно отправляется в другую строку и там отображает (тоже в двух строках) [12]:[6], и получается что один ноль украли

@Pro_grammer · 29.10.2012, 08:23

Сообщение от GD

получается что один ноль украли

Мне проще готовую программу написать:

PureBasic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
;{ Windows
Enumeration
  #Window_0
EndEnumeration
;}
;{ Gadgets
Enumeration
  #String_0
  #String_1
  #Text_2
  #Button_3
  #Button_4
  #String_5
  #Text_6
  #String_7
  #Text_8
  #String_9
EndEnumeration
;}
Define.l Event, EventWindow, EventGadget, EventType, EventMenu
;}
Procedure OpenWindow_Window_0()
  If OpenWindow(#Window_0, 822, 180, 283, 90, "калькулятор времени", #PB_Window_SystemMenu|#PB_Window_SizeGadget|#PB_Window_MinimizeGadget|#PB_Window_TitleBar)
    StringGadget(#String_0, 5, 35, 25, 20, "10", #ES_CENTER)
    StringGadget(#String_1, 40, 35, 25, 20, "30", #ES_CENTER)
    TextGadget(#Text_2, 30, 35, 10, 20, ":", #PB_Text_Center)
    ButtonGadget(#Button_3, 75, 20, 30, 20, "+")
    ButtonGadget(#Button_4, 75, 45, 30, 20, "-")
    StringGadget(#String_5, 115, 35, 25, 20, "08", #ES_CENTER)
    TextGadget(#Text_6, 140, 35, 10, 20, ":", #PB_Text_Center)
    StringGadget(#String_7, 150, 35, 25, 20, "40", #ES_CENTER)
    TextGadget(#Text_8, 180, 35, 20, 20, "=", #PB_Text_Center)
    StringGadget(#String_9, 205, 35, 60, 20, "", #ES_CENTER)
  EndIf
EndProcedure
 
OpenWindow_Window_0()
 
;{- Event loop
Repeat
  Event = WaitWindowEvent()
  Select Event
    ; ///////////////////
    Case #PB_Event_Gadget
      EventGadget = EventGadget()
      EventType = EventType()
      If EventGadget = #Button_3
        min=Val(GetGadgetText(#String_0))*60+Val(GetGadgetText(#String_1))
        hm=AddDate(0, #PB_Date_Minute,min) ; Первое время
        
        min2=Val(GetGadgetText(#String_5))*60+Val(GetGadgetText(#String_7))
        hm2=AddDate(0, #PB_Date_Minute,min2) ; Второе время
      
       SetGadgetText(#String_9,FormatDate("%hh:%ii", AddDate(0, #PB_Date_Second ,hm+hm2))) ; Складываем
       
      ElseIf EventGadget = #Button_4
       min=Val(GetGadgetText(#String_0))*60+Val(GetGadgetText(#String_1))
        hm=AddDate(0, #PB_Date_Minute,min) ; Первое время
        
        min2=Val(GetGadgetText(#String_5))*60+Val(GetGadgetText(#String_7))
        hm2=AddDate(0, #PB_Date_Minute,min2) ; Второе время
      
       SetGadgetText(#String_9,FormatDate("%hh:%ii", AddDate(0, #PB_Date_Second ,hm-hm2))) ; Вычитаем
      
      EndIf
    ; ////////////////////////
    Case #PB_Event_CloseWindow
      EventWindow = EventWindow()
      If EventWindow = #Window_0
        CloseWindow(#Window_0)
        Break
      EndIf
  EndSelect
ForEver
;
;}

Если что в коде непонятно, то можно спрашивать.

@GD · 29.10.2012, 14:22

Сообщение от Pro_grammer

Define.l Event, EventWindow, EventGadget, EventType, EventMenu

а что это за строка?

@locm · 29.10.2012, 15:19

Если не задано никаких <переменных>, ключевое слово Define используется для изменения типа по умолчанию для будущих переменных без типа (включая параметры процедур, параметры методов интерфейсов и данные для чтения с помощью ключевого слова Read). Начальный тип по умолчанию integer (.i). Каждая переменная может иметь значение по умолчанию, сразу же присвоенное ей.

Если заданы переменные, ключевое слово Define только объявляет эти переменные с "типом объявления" и не изменяет тип по умолчанию. Если вы не присвоите здесь значение переменным, значение будет 0.

http://purebasic.ru/manual.php?id=1061&lng=rus

@sergesneg · 26.10.2014, 12:22

А как на PureBasic строки расбирать? Типа "Sin(2.32)^2+2*(3+x^2)". Есть что нить подобное как Eval или тексты программ где можно покопать? Или готовый кусок текста интерпритатора на PB?

@Никита Однороб · 28.10.2014, 20:23

sergesneg

PureBasic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
Declare.f eval(str.s)
Declare.f level1()
Declare.f level2()
Declare.f level3()
Declare.f level4()
Declare.f level5()
Declare.f level6()
Declare.f level7()
Declare.f level8()
Declare.f level9()
Declare.f primitive()
Declare.f calc(op.s, num1.f, num2.f)
Declare.f unary(op.s, num.f)
Declare rewind()
Declare.f letVar(var.s, num.f)
Declare.f getVar()
Declare.f clearVars()
Declare gettoken()
Declare isFunc(str.s)
Declare isCommand(str.s)
Declare isMinus(str.s)
Declare isParenth(str.s)
Declare isDelim(str.s)
Declare notDelim(str.s)
Declare isAlpha(str.s)
Declare isDigit(str.s)
Declare isSpace(str.s)
Declare notVailidop(op.s)
Declare isErr(str.s)
 
Global expr.s, progr.l, token.s, ttype.l
 
#MAXVARS = 1000
Global Dim varNames.s(#MAXVARS)
Global Dim vars.f(#MAXVARS)
 
#MAXFNC = 11
Global Dim fnc.s(#MAXFNC)
fnc(0) = "ACOS": fnc(1) = "ASIN": fnc(2) = "ATAN": fnc(3) = "ABS"
fnc(4) = "COS": fnc(5) = "INT": fnc(6) = "LOG": fnc(7) = "LOG10"
fnc(8) = "SIN": fnc(9) = "SQR": fnc(10) = "TAN"
 
#MAXCMD = 1
Global Dim cmd.s(#MAXCMD)
cmd(0) = "CLEAR"
 
#DELIM = 1
#VARIABLE = 2
#NUMBER = 3
#FUNCTION = 4
#COMMAND = 5
 
Global error.s
Global ERR_SYNTAX.s, ERR_PARENTH.s, ERR_NOEXPR.s, ERR_DIVZERO.s
ERR_SYNTAX = "SYNTAX ERROR"
ERR_PARENTH = "UNBALANCED PARENTHESES"
ERR_NOEXPR = "NO EXPRESSION"
ERR_DIVZERO = "DIVISION BY ZERO"
 
Procedure.f eval(str.s)
  progr = 1
  error = ""
  expr = UCase(str)
  gettoken()
  If token = ""
    error = ERR_NOEXPR
  EndIf
  isErr(expr)
  If Len(error)
    ProcedureReturn #False
  EndIf
  ProcedureReturn level1()
EndProcedure
 
Procedure.f level1()
  typ.l
  tok.s
  If ttype= #VARIABLE
    tok = token
    typ = ttype
    gettoken()
      gettoken()
      ProcedureReturn letVar(tok, level2())
    Else
      Rewind()
      token = tok
      ttype = Typ
    EndIf
  ElseIf ttype = #COMMAND
    If token = "CLEAR"
      rewind()
      token = tok
      ttype = typ
      clearVars()
      ProcedureReturn 0
    EndIf
  EndIf
  ProcedureReturn level2()
EndProcedure
 
Procedure.f level2()
  result.f = level3()
  op.s = token
  While (op = "&") Or (op = "|")
    gettoken()
    result = calc(op, result, level3())
    op = token
  Wend
  ProcedureReturn result
EndProcedure
 
Procedure.f level3()
  result.f = level4()
  op.s = token
  While (op = "<") Or (op = ">") Or (op = "<>") Or (op = "<=") Or (op = ">=") Or (op = "==")
    gettoken()
    result = calc(op, result, level4())
    op = token
  Wend
  ProcedureReturn result
EndProcedure
 
Procedure.f level4()
  result.f = level5()
  op.s = token
  While (op = "+") Or (op = "-")
    gettoken()
    result = calc(op, result, level5())
    op = token
  Wend
  ProcedureReturn result
EndProcedure
 
Procedure.f level5()
  result.f = level6()
  op.s = token
  While (op = "*") Or (op = "/")
    gettoken()
    result = calc(op, result, level6())
    op = token
  Wend
  ProcedureReturn result
EndProcedure
 
Procedure.f level6()
  result.f = level7()
  If token = "^"
    gettoken()
    result = calc("^", result, level7())
  EndIf
  ProcedureReturn result
EndProcedure
 
Procedure.f level7()
  op.s = ""
  If (ttype = #DELIM) And ((token = "+") Or (token = "-"))
    op = token
    gettoken()
  EndIf
  result.f = level8()
  If Len(op)
    result = Unary(op, result)
  EndIf
  ProcedureReturn result
EndProcedure
 
Procedure.f level8()
  op.s = ""
  If ttype = #FUNCTION
    op = token
    gettoken()
  EndIf
  result.f = level9()
  If Len(op)
    result = calc(op, result, 0)
  EndIf
  ProcedureReturn result
EndProcedure
 
Procedure.f level9()
  result.f
  If (ttype = #DELIM) And (token = "(")
    gettoken()
    result = level1()
    gettoken()
  Else
    result = primitive()
  EndIf
  ProcedureReturn result
EndProcedure
 
Procedure.f primitive()
  result.f
  Select ttype
    Case #VARIABLE
      result = getVar()
      gettoken()
    Case #NUMBER
      result = ValF(token)
      gettoken()
    Default
      error = ERR_SYNTAX
  EndSelect
  ProcedureReturn result
EndProcedure
 
Procedure.f calc(op.s, num1.f, num2.f)
  result.f
  Select op
    Case "&"
      result = Bool(num1 And num2)
    Case "|"
      result = Bool(num1 Or num2)
    Case "<"
      If num1 < num2
        result = 1
      EndIf
    Case ">"
      If num1 > num2
        result = 1
      EndIf
    Case "<>"
      If num1 <> num2
        result = 1
      EndIf
    Case "<="
      If num1 <= num2
        result = 1
      EndIf
    Case ">="
      If num1 >= num2
        result = 1
      EndIf
    Case "=="
      If num1 = num2
        result = 1
      EndIf
    Case "-"
      result = num1 - num2
    Case "+"
      result = num1 + num2
    Case "*"
      result = num1 * num2
    Case "/"
      If num2 <> 0
        result = num1 / num2
      Else
        error = ERR_DIVZERO
        result = 0
      EndIf
    Case "^"
      result = Pow(num1, num2)
    Case "ACOS"
      result = ACos(num1)
    Case "ASIN"
      result = ASin(num1)
    Case "ATAN"
      result = ATan(num1)
    Case "ABS"
      result = Abs(num1)
    Case "COS"
      result = Cos(num1)
    Case "INT"
      result = Int(num1)
    Case "LOG"
      result = Log(num1)
    Case "LOG10"
      result = Log10(num1)
    Case "SIN"
      result = Sin(num1)
    Case "SQR"
      result = Sqr(num1)
    Case "TAN"
      result = Tan(num1)
  EndSelect
  ProcedureReturn result
EndProcedure
 
Procedure.f unary(op.s, num.f)
  If op = "-"
    ProcedureReturn -num
  EndIf
  ProcedureReturn num
EndProcedure
 
Procedure rewind()
  progr = progr - Len(token)
EndProcedure
 
Procedure.f letVar(var.s, num.f)
  i = 0
  While Len(varNames(i))
    If var = varNames(i)
      vars(i) = num
      ProcedureReturn num
    EndIf
    i + 1
  Wend
  varNames(i) = var
  vars(i) = num
  ProcedureReturn num
EndProcedure
 
Procedure.f getVar()
  i = 0
  While Len(varNames(i))
    If token = varNames(i)
      ProcedureReturn vars(i)
    EndIf
    i + 1
  Wend
  letVar(token, 0)
  ProcedureReturn getVar()
EndProcedure
 
Procedure.f clearVars()
  For i = 0 To #MAXVARS - 1
    vars(i) = 0
    varNames(i) = ""
  Next
EndProcedure
 
Procedure getToken()
  ttype = 0
  token = ""
  If progr > Len(expr)
    ProcedureReturn
  EndIf
  While isSpace(Mid(expr, progr, 1))
    Progr + 1
  Wend
  Select #True
    Case isMinus(Mid(expr, progr, 1))
      ttype = #DELIM
      token = Mid(expr, progr, 1)
      progr + 1
    Case isParenth(Mid(expr, progr, 1))
      ttype = #DELIM
      token = Mid(expr, progr, 1)
      progr + 1
    Case isDelim(Mid(expr, progr, 1))
      ttype = #DELIM
      While isDelim(Mid(expr, progr, 1))
        token + Mid(expr, progr, 1)
        progr + 1
      Wend
      If notVailidop(token)
        error = ERR_SYNTAX
      EndIf
    Case isAlpha(Mid(expr, progr, 1))
      While notDelim(Mid(expr, progr, 1))
        token + Mid(expr, progr, 1)
        progr + 1
      Wend
      If isFunc(token)
        ttype= #FUNCTION
      Else
        If isCommand(token)
          ttype = #COMMAND
        Else
          ttype = #VARIABLE
        EndIf
      EndIf
    Case isDigit(Mid(expr, progr, 1))
      ttype = #NUMBER   
      While NotDelim(Mid(expr, progr, 1))
        token + Mid(expr, progr, 1)
        progr + 1
      Wend
  EndSelect
EndProcedure
 
Procedure isFunc(str.s)
  For i = 0 To #MAXFNC - 1
    If str = fnc(i)
      ProcedureReturn #True
    EndIf
  Next
  ProcedureReturn #False
EndProcedure
 
Procedure isCommand(str.s)
  For i = 0 To #MAXCMD - 1
    If str = cmd(i)
      ProcedureReturn #True
    EndIf
  Next
  ProcedureReturn #False
EndProcedure
 
Procedure isMinus(str.s)
  If FindString("-", str, 1)
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Procedure isParenth(str.s)
  If FindString("()", str, 1)
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Procedure isDelim(str.s)
  If (FindString("&|<>+/*^=", str, 1) > 0) And (str <> "")
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Procedure NotDelim(str.s)
  If (FindString("&|<>+-/*^=()" + Chr(32) + Chr(9), str, 1) > 0) Or (str = "")
    ProcedureReturn #False
  EndIf
  ProcedureReturn #True
EndProcedure
 
Procedure isAlpha(str.s)
  If FindString("ABCDEFGHIJKLMNOPQRSTUVWXYZ", str, 1)
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Procedure isDigit(str.s)
  If FindString(".0123456789", str, 1)
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Procedure isSpace(str.s)
  If ((str = " ") Or (str = Chr(9))) And (str <> "")
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Procedure notVailidop(op.s)
  If Len(op) = 1
    ProcedureReturn #False
  EndIf
  Select token
    Case "<>"
      ProcedureReturn #False
    Case "<= "
      ProcedureReturn #False
    Case ">= "
      ProcedureReturn #False
    Case "== "
      ProcedureReturn #False
    Case "--"
      ProcedureReturn #False
  EndSelect
  ProcedureReturn #True
EndProcedure
 
Procedure isErr(str.s)
  str1.s
  str2.s
  err = 0
  str = UCase(str)
  For i = 1 To Len(str)
    If Mid(str, i, 1) = "("
      err + 1
    EndIf
    If Mid(str, i, 1) = ")"
      err - 1
    EndIf
  Next
  If err
    error = ERR_PARENTH
    ProcedureReturn #True
  EndIf
  str1 = " ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  str2 = "0123456789.&|<>+-/%*^=()" + Chr(9)
  For i = 1 To Len(str)
    If FindString(str1 + str2, Mid(str, i, 1), 1) = 0
      err + 1
    EndIf
  Next
  If err
    ProcedureReturn #True
  EndIf
  ProcedureReturn #False
EndProcedure
 
Debug eval("Sin(2.32)^2+2*(3+x^2)")

@sergesneg · 08.12.2014, 17:59

Никита Однороб

Что то я не понял куда один IF делся в процедуре первого уровня?

PureBasic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Procedure.f level1()
  typ.l
  tok.s
  If ttype= #VARIABLE
    tok = token
    typ = ttype
    gettoken()
    If ????????????????????????????????
      gettoken()
      ProcedureReturn letVar(tok, level2())
    Else
      Rewind()
      token = tok
      ttype = Typ
    EndIf
  ElseIf ttype = #COMMAND
    If token = "CLEAR"
      rewind()
      token = tok
      ttype = typ
      clearVars()
      ProcedureReturn 0
    EndIf
  EndIf
  ProcedureReturn level2()
EndProcedure

Добавлено через 7 минут
По идее должны быть равно искать? Так? ну всё равно огромное спасибачки, хоть на мыслю направил.
If token = "="

Добавлено через 20 минут
Никита Однороб

Вот, доделал, если вы не против, теперь будет работать:

PureBasic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Procedure.f level1()
  typ.l
  tok.s
  If ttype= #VARIABLE
    tok = token
    typ = ttype
    gettoken()
    If token = "="
      gettoken()
      ProcedureReturn letVar(tok, level2())
    Else
      Rewind()
      token = tok
      ttype = Typ
    EndIf
  ElseIf ttype = #COMMAND
    If token = "CLEAR"
      rewind()
      token = tok
      ttype = typ
      clearVars()
      ProcedureReturn 0
    EndIf
  EndIf
  ProcedureReturn level2()
EndProcedure

Спасибочки большое ещё раз!

Новые блоги и статьи Все статьи Все блоги /
Модель микоризы: классовый агентный подход 3 anaschu 06.01.2026 aa0a7f55b50dd51c5ec569d2d10c54f6/ O1rJuneU_ls https:/ / vkvideo. ru/ video-115721503_456239114	Owen Logic: О недопустимости использования связки «аналоговый ПИД» + RegKZR ФедосеевПавел 06.01.2026 Owen Logic: О недопустимости использования связки «аналоговый ПИД» + RegKZR ВВЕДЕНИЕ Введу сокращения: аналоговый ПИД — ПИД регулятор с управляющим выходом в виде числа в диапазоне от 0% до. . .	Модель микоризы: классовый агентный подход 2 anaschu 06.01.2026 репозиторий https:/ / github. com/ shumilovas/ fungi ветка по-частям. коммит Create переделка под биомассу. txt вход sc, но sm считается внутри мицелия. кстати, обьем тоже должен там считаться. . . .	Расчёт токов в цепи постоянного тока igorrr37 05.01.2026 / * Дана цепь постоянного тока с сопротивлениями и напряжениями. Надо найти токи в ветвях. Программа составляет систему уравнений по 1 и 2 законам Кирхгофа и решает её. Последовательность действий:. . .
Новый CodeBlocs. Версия 25.03 palva 04.01.2026 Оказывается, недавно вышла новая версия CodeBlocks за номером 25. 03. Когда-то давно я возился с только что вышедшей тогда версией 20. 03. С тех пор я давно снёс всё с компьютера и забыл. Теперь. . .	Модель микоризы: классовый агентный подход anaschu 02.01.2026 Раньше это было два гриба и бактерия. Теперь три гриба, растение. И на уровне агентов добавится между грибами или бактериями взаимодействий. До того я пробовал подход через многомерные массивы,. . .	Советы по крайней бережливости. Внимание, это ОЧЕНЬ длинный пост. Programma_Boinc 28.12.2025 Советы по крайней бережливости. Внимание, это ОЧЕНЬ длинный пост. Налог на собак: https:/ / ********/ gallery/ V06K53e Финансовый отчет в Excel: https:/ / ********/ gallery/ bKBkQFf Пост отсюда. . .	Кто-нибудь знает, где можно бесплатно получить настольный компьютер или ноутбук? США. Programma_Boinc 26.12.2025 Нашел на реддите интересную статью под названием Anyone know where to get a free Desktop or Laptop? Ниже её машинный перевод. После долгих разбирательств я наконец-то вернула себе. . .

@GD 0 / 0 / 0 Регистрация: 24.10.2012 Сообщений: 12
	25.10.2012, 14:14
	а как можно создать калькулятор времени ( часы и минуты)? 0

@Pro_grammer 6807 / 2839 / 527 Регистрация: 24.04.2011 Сообщений: 5,308 Записей в блоге: 10
	26.10.2012, 10:20
	Время можно складывать и вычитать как обычные числа.Библиотека PureBasic - Date содержит всё для этого. Она оперирует секундами. Можно использовать так же AddDate 1

@GD 0 / 0 / 0 Регистрация: 24.10.2012 Сообщений: 12
	28.10.2012, 00:55
	а как сделать строку для ввода времени а именно (чч:мм). 0

@sergesneg 0 / 0 / 0 Регистрация: 16.03.2011 Сообщений: 23
	26.10.2014, 12:22
	А как на PureBasic строки расбирать? Типа "Sin(2.32)^2+2*(3+x^2)". Есть что нить подобное как Eval или тексты программ где можно покопать? Или готовый кусок текста интерпритатора на PB? 0