Получить ID только что добавленной записи (ID - autoincrement)

SET NOCOUNT ON;
USE tempdb;
IF OBJECT_ID(N'T','U') IS NOT NULL DROP TABLE T;
IF OBJECT_ID(N'TT','U') IS NOT NULL DROP TABLE TT;
CREATE TABLE T(ID INT NOT NULL IDENTITY(0,1));
CREATE TABLE TT(ID INT NOT NULL IDENTITY);
INSERT T DEFAULT VALUES;
GO
/*Для неправильного результата OUTPUT и SCOPE_IDENTITY()*/
CREATE TRIGGER InsteadOfInsertT ON T INSTEAD OF INSERT AS INSERT T DEFAULT VALUES;
GO
CREATE TRIGGER AfterInsertT ON T FOR INSERT AS
/*Для неправильного результата IDENT_CURRENT()*/
INSERT T DEFAULT VALUES;
DELETE T WHERE ID=SCOPE_IDENTITY();
/*Для неправильного результата @@IDENTITY*/
INSERT TT DEFAULT VALUES;
INSERT TT DEFAULT VALUES;
GO
 
/*Вставляем одну запись*/
DECLARE @T TABLE(ID INT NULL);
INSERT T OUTPUT inserted.ID INTO @T(ID) DEFAULT VALUES;
 
/*Пытаемся получить вставленное значение колонки IDENTITY...*/
SELECT ID[OUTPUT] FROM @T;
SELECT @@IDENTITY[@@IDENTITY];
SELECT SCOPE_IDENTITY()[SCOPE_IDENTITY()];
SELECT IDENT_CURRENT(N'T')[IDENT_CURRENT()];
/*...а на самом деле...*/
SELECT * FROM T;
 
IF OBJECT_ID(N'T','U') IS NOT NULL DROP TABLE T;
IF OBJECT_ID(N'TT','U') IS NOT NULL DROP TABLE TT;