Строки. Реализовать шифрование текста следующим методом.

uses
  crt;
const
  maxWords = 10;  {Максимально количество слов в массиве}
  wordSize = 30;  {Размер одного слова}
  maxDelta = 10;  {Максимальное приращение к коду ASCII}
type
  WordType = string[wordSize];                          
  WordArray = array [1..maxWords] of WordType;  
  KeyArray  = array [1..maxWords] of integer;       
 
  {Запись зашифрованного текста в файл с именем fName}
  procedure WriteEncryptToFile(fName: string; words: WordArray; keys: KeyArray; amtWords: integer);
  var
    f: text;
    i: integer;
  begin
    assign(f,fName);
    rewrite(f);
    write(f,'encrypt text: ');
    for i := 1 to amtWords do
      write(f,words[i],' ');
    writeln(f);
    write(f,'delta: ');
    for i := 1 to amtWords do
      write(f,keys[i],' ');
    close(f);
  end;
 
  {Удаление пробелов в начале и в конце строки}
  function Trim(str: string): string;
  begin
    while (str > '') and (str[1] = ' ') do
      delete(str,1,1);
    while (str > '') and (str[length(str)] = ' ') do
      delete(str,length(str),1);
    Trim := str;
  end;
 
  {Выделение слов из строки и занесение их в массив words}
  function ParseTextToWords(text: string; var words: WordArray): integer;
  var
    numWord: integer;
    i: integer;
  begin
    ParseTextToWords := 0;
    numWord := 0;
    text := Trim(text);
    if (text = '') then begin
      writeln('empty text');
      exit;
    end;
    while (text > '') and (numWord < maxWords) do begin
      text := Trim(text);
      i := pos(' ',text);
      if (i = 0) then i := length(text);
      inc(numWord);
      words[numWord] := Trim(copy(text,1,i));
      delete(text,1,i);
    end;
    ParseTextToWords := numWord;
  end;
 
  {Смещение кода ASCII в слове}
  procedure MoveCharsInWord(var word: WordType; delta: integer);
  var
    i: integer;
    symbCode: integer;
  begin
    for i := 1 to length(word) do begin
      symbCode := ord(word[i]);
      word[i] := chr(symbCode + delta);
    end;
  end;
 
  {Шифрование текста с записью его в файл}
  procedure EncryptText(text: string; fName: string);
  var
    amtWord: integer;
    words: WordArray;
    keys : KeyArray;
    i: integer;
  begin
    amtWord := ParseTextToWords(text,words);
    randomize;
    for i := 1 to amtWord do begin
      keys[i] := random(maxDelta)+1;
      MoveCharsInWord(words[i],keys[i]);
    end;
    WriteEncryptToFile(fName,words,keys,amtWord);
  end;
 
var
  str    : string;
  fname  : string;
begin
  clrscr;
  write('enter text: ');
  readln(str);
  write('enter output file name: ');
  readln(fName);
  EncryptText(str,fName);
  write('press any key to exit...');
  readkey;
end.