Возможно ли вывести в ListBox название всех файлов по заданному пути

Public Class Form1
    Dim WithEvents LBX As ListBox
 
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        ' создаем новый листбокс и даем ему нужные атрибуты
        LBX = New ListBox
        With LBX
            .Location = New Point(0, 0)
            .Dock = DockStyle.Fill
            .IntegralHeight = False
            .SelectionMode = SelectionMode.One
        End With
        Me.Controls.Add(LBX)
        ' заполняем его итемами типа MyListItem
        'For Each _file As String In IO.Directory.GetFiles("D:\Юпатов.КБ-7\Юпатов\Справочники", "*.txt", IO.SearchOption.AllDirectories) ' это с фильтром по текстовикам
        For Each _file As String In IO.Directory.GetFiles("D:\Юпатов.КБ-7\Юпатов\Справочники", "*", IO.SearchOption.AllDirectories)
            Dim NMLI As New MyListItem(_file)
            Me.LBX.Items.Add(NMLI)
        Next
    End Sub
 
    Private Sub LBX_DoubleClick(ByVal sender As Object, ByVal e As System.EventArgs) Handles LBX.DoubleClick
        Dim nmli As MyListItem = CType(Me.LBX.SelectedItem, MyListItem)
        Process.Start(nmli.FullPath)
    End Sub
 
    Private Sub LBX_SelectedIndexChanged(ByVal sender As Object, ByVal e As System.EventArgs) Handles LBX.SelectedIndexChanged
        Dim nmli As MyListItem = CType(Me.LBX.SelectedItem, MyListItem)
        Me.Icon = nmli.ItemIcon
    End Sub
End Class
 
''' <summary>
''' Класс, описывающий некоторые необходимые атрибуты добавляемого в ListBox итема (полный путь файла, имя без расширения, ассоциированный с данным расширением значок)
''' </summary>
''' <remarks></remarks>
Public Class MyListItem
    Friend FullPath As String
    Friend FileName As String
    Friend ItemIcon As Icon
 
    ''' <summary>
    ''' Создание нового экземпляра
    ''' </summary>
    ''' <param name="FP">полный путь к файлу</param>
    ''' <remarks></remarks>
    Public Sub New(ByVal FP As String)
        FullPath = FP
        FileName = IO.Path.GetFileNameWithoutExtension(FP)
        ItemIcon = Icon.ExtractAssociatedIcon(FP)
    End Sub
 
    ' своя функция приведения к строке (выдает значение FileName)
    Public Overrides Function ToString() As String
        Return FileName
    End Function
End Class