Открытие папок в ListBox и переход "назад"

Imports System.IO
Public Class FileListView
    Inherits ListView
    Private _Path As String
 
    Public Sub New()
        Me.View = Windows.Forms.View.Details
        Me.Columns.Add("FileName", "Имя", 200)
        Me.Columns.Add("Type", "Тип", 50)
        Me.Columns.Add("Size", "Размер", 70)
        Me.Columns.Add("ModifyDate", "Дата", 70)
        Me.Columns.Add("ModifyTime", "Время", 60)
    End Sub
    Public Property Path As String
        Get
            Return _Path
        End Get
        Set(value As String)
            Me.Items.Clear()
            _Path = value
            If _Path = "" Then Exit Property
            Dim di As New DirectoryInfo(_Path)
            For Each d In di.GetDirectories
                Dim i As ListViewItem
                i = Me.Items.Add("[" & d.Name & "]") 'Имя
                i.SubItems.Add("") 'Тип
                i.SubItems.Add("<DIR>") 'Размер
                i.SubItems.Add(d.LastWriteTime.ToShortDateString) 'Дата
                i.SubItems.Add(Format(d.LastWriteTime, "hh:mm:ss")) 'Время
            Next
            For Each f In di.GetFiles
                Dim i As ListViewItem
                i = Me.Items.Add(System.IO.Path.GetFileNameWithoutExtension(f.Name))
                i.SubItems.Add(f.Extension)
                i.SubItems.Add(f.Length)
                i.SubItems.Add(f.LastWriteTime.ToShortDateString)
                i.SubItems.Add(f.LastWriteTime.ToLongTimeString)
            Next
        End Set
    End Property
 
End Class

Imports System.IO
Public Class FileListView
    Inherits ListView
    Private _Path As String
 
    Public Property ConnectedFileListView As FileListView 'связанный FileListView (как во всех "коммандерах", вторая панель)
 
    Public Sub New()
        Me.MultiSelect = True 'возможно "выбрать" несколько элементов
        Me.View = Windows.Forms.View.Details 'выставляем самый удобный вид
        Me.Columns.Add("FileName", "Имя", 200) 'Имя файла
        Me.Columns.Add("Type", "Тип", 50) 'Тип (расширение)
        Me.Columns.Add("Size", "Размер", 70) 'размер
        Me.Columns.Add("ModifyDate", "Дата", 70) 'дата последней правки файла
        Me.Columns.Add("ModifyTime", "Время", 60) 'время последней правки файла
    End Sub
 
    Public Property Path As String
        Get
            Return _Path
        End Get
        Set(ByVal value As String)
            'установлен новый путь к текущей папке
            Me.Items.Clear() 'сперва удаляем все элементы списка
 
            If value = "" Then 'если новое значение пустое, то
                _Path = value 'сохраняем в локальную переменную пустой путь
                Exit Property 'и уходим
            Else
                'если новое значение нормальное, то заполняем список сперва папками, потом файлами
                Dim di As New DirectoryInfo(value)
                Dim i As ListViewItem
 
                'когда возможно, самый первый будет элемент "..", который позволит пользователю подняться на уровень выше
                If Not IsNothing(di.Parent) Then
                    i = Me.Items.Add("..") 'добавляем его
                    i.Tag = di.Parent 'записываем в тэг элемента вышестоящий каталог
                    Me.FocusedItem = i
                End If
 
                For Each d In di.GetDirectories 'папки
                    i = Me.Items.Add("[" & d.Name & "]") 'Имя
                    i.Tag = d 'для дальнейшего удобства кидаем "текущую папку" в тэг
                    i.SubItems.Add("") 'Тип
                    i.SubItems.Add("<DIR>") 'Размер, в него пишем <DIR>, как у тотала
                    i.SubItems.Add(d.LastWriteTime.ToShortDateString) 'Дата
                    i.SubItems.Add(Format(d.LastWriteTime, "hh:mm:ss")) 'Время
                Next
                For Each f In di.GetFiles 'файлы
                    i = Me.Items.Add(System.IO.Path.GetFileNameWithoutExtension(f.Name))
                    i.Tag = f 'для дальнейшего удобства кидаем "текущий файл" в тэг
                    i.SubItems.Add(f.Extension) 'тип (расширение)
                    i.SubItems.Add(f.Length) 'размер
                    i.SubItems.Add(f.LastWriteTime.ToShortDateString) 'дата
                    i.SubItems.Add(Format(f.LastWriteTime, "hh:mm:ss")) 'время
                Next
                _Path = value
            End If
        End Set
    End Property
 
    Public Sub Fill()
 
    End Sub
 
    Private Sub FileListView_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
        'что происходит при нажатии клавиши
        If IsNothing(Me.FocusedItem) Then Exit Sub 'если фокус не установлен - выходим
        Select Case e.KeyCode
            Case Keys.Enter ' нажатие на ENTER, нужно "войти" (в папку/файл)
                Select Case Me.FocusedItem.Tag.GetType.Name
                    Case "DirectoryInfo"
                        Dim CurrentDir As DirectoryInfo
                        CurrentDir = Me.FocusedItem.Tag
                        Me.Path = CurrentDir.FullName
                    Case "FileInfo"
                        Dim CurrentFile As FileInfo
                        CurrentFile = Me.FocusedItem.Tag
                        Process.Start(CurrentFile.FullName)
                End Select
            Case Keys.F5 'копировать
                CopySelectedFiles()
        End Select
    End Sub
 
    Private Sub CopySelectedFiles()
        'Метод копирует все выбранные файлы/каталоги в папку, открытую в связанном FileListView
        Dim Item As ListViewItem
        For Each Item In Me.SelectedItems
            Select Case Item.Tag.GetType.Name
                Case "DirectoryInfo"
                    Dim CurrentDir As DirectoryInfo
                    CurrentDir = Item.Tag
                    MsgBox(CurrentDir.FullName)
                    MsgBox(Me.ConnectedFileListView.Path)
                Case "FileInfo"
                    Dim CurrentFile As FileInfo
                    CurrentFile = Item.Tag
                    FileCopy(CurrentFile.FullName, System.IO.Path.Combine(Me.ConnectedFileListView.Path, CurrentFile.Name))
            End Select
        Next
    End Sub
End Class