Ошибка окна предпросмотра при печати

'кнопка предпросмотр
    Private Sub ToolStripButton1_Click(sender As Object, e As EventArgs) Handles ToolStripButton1.Click
        'Инициализируем переменные
        PrintDocument1.DocumentName = FilePath
        stringPrintText = Note.Text
        StartPage = 1
        NumPages = PrintDialog1.PrinterSettings.MaximumPage
        PageNumber = 1
        'Показываем диалог
        PrintPreviewDialog1.ShowDialog()
    End Sub
 
        Private Sub PrintDocument1_PrintPage(sender As Object, e As Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
        'Создаем экземпляр graph класса Graphics
        Dim graph As Graphics = e.Graphics
        'Создаем объект font, которому устанавливаем 
        ' шрифт элемента Note
        Dim font As Font = Note.Font
        'Получаем значение межстрочного интервала — высоту шрифта Т1, 134
        Dim HeightFont As Single = font.GetHeight(graph)
        'Создаем экземпляр stringformat класса StringFormat для определения 
        'дополнительных параметров форматирования текста.
        Dim stringformat As New StringFormat()
        'Создаем экземляры  rectanglefFull и rectanglefText класса RectangleF для 
        'определния областей печати и текста. Т1, 104
        Dim rectanglefFull As RectangleF, rectanglefText As RectangleF
        'Создаем переменные для подсчета числа символов и строк.
        Dim NumberSymbols As Integer, NumberLines As Integer
        'В качестве области печати устанавливаем объект rectanglefFull
        If graph.VisibleClipBounds.X < 0 Then
            rectanglefFull = e.MarginBounds
        Else
            'Определяем   объект  rectanglefFull
            'Устанавливаем координату  X  
            'Устанавливаем координату  Y
            'Устанавливаем ширину области
            'Устанавливаем высоту области
            'rectanglefFull = New RectangleF(e.MarginBounds.Left - (e.PageBounds.Width - graph.VisibleClipBounds.Width) / 2, e.MarginBounds.Top - (e.PageBounds.Height - graph.VisibleClipBounds.Height) / 2, e.MarginBounds.Width, e.MarginBounds.Height)
            rectanglefFull = New RectangleF(40, 40, e.PageBounds.Width - 80, e.PageBounds.Height - 40)
        End If
        'rectanglefText = RectangleF.Inflate(rectanglefFull, 0, -2 * HeightFont)
        rectanglefText = RectangleF.Inflate(rectanglefFull, 0, -2 * HeightFont)
        'Определяем число строк
        Dim NumDisplayLines As Integer = CInt(Math.Floor(rectanglefText.Height / HeightFont))
        'Устанавливаем высоту области
        rectanglefText.Height = NumDisplayLines * HeightFont
 
        If Note.WordWrap Then
            stringformat.Trimming = StringTrimming.Word
        Else
            stringformat.Trimming = StringTrimming.EllipsisCharacter
            stringformat.FormatFlags = stringformat.FormatFlags Or StringFormatFlags.NoWrap
        End If
        'При печати выбранных страниц переходим к первой стартовой странице
        While (PageNumber < StartPage) AndAlso (stringPrintText.Length > 0)
            If Note.WordWrap Then
                'Измеряем текстовые переменные, 
                'формирующие печать,  и возвращаем число символов NumberSymbols
                'и число строк NumberLines
                graph.MeasureString(stringPrintText, font, rectanglefText.Size, stringformat, NumberSymbols, NumberLines)
            Else
                NumberSymbols = SymbolsInLines(stringPrintText, NumDisplayLines)
            End If
            stringPrintText = stringPrintText.Substring(NumberSymbols)
            'Увеличиваем число страниц 
            PageNumber += 1
        End While
        'Если длина строки stringPrintText равняется нулю (нет текста для печати),
        ' останавливаем печать
        If stringPrintText.Length = 0 Then
            e.Cancel = True
            Return
        End If
        'Выводим (рисуем) текст для печати — stringPrintText, используем для этого шрифт font,
        'кисть черного цвета  — Brushes.Black, область печати — rectanglefText,
        'передаем строку  дополнительного форматирования stringformat
        graph.DrawString(stringPrintText, font, Brushes.Black, rectanglefText, stringformat)
        'Получаем текст для следующей страницы
        If Note.WordWrap Then
            graph.MeasureString(stringPrintText, font, rectanglefText.Size, stringformat, NumberSymbols, NumberLines)
        Else
            NumberSymbols = SymbolsInLines(stringPrintText, NumDisplayLines)
        End If
        stringPrintText = stringPrintText.Substring(NumberSymbols)
        'Очищаем объект stringformat, использованный для формирования полей.
        stringformat = New StringFormat()
        'Добавляем  вывод на каждую страницу ее номера
        stringformat.Alignment = StringAlignment.Far
        graph.DrawString("Страница " & PageNumber, New Font("Courier New", 10), Brushes.Black, rectanglefFull, stringformat)
        PageNumber += 1
        'Cнова проверяем, имеется ли текст для печати и номер страницы, заданной для печати
        e.HasMorePages = (stringPrintText.Length > 0) AndAlso (PageNumber < StartPage + NumPages)
        'Для печати из окна предварительного просмотра  снова инициализируем переменные
        If Not e.HasMorePages Then
            stringPrintText = Note.Text
            StartPage = 1
            NumPages = PrintDialog1.PrinterSettings.MaximumPage
            PageNumber = 1
        End If
    End Sub
 
    Private Function SymbolsInLines(stringPrintText As String, NumLines As Integer) As Integer
        Dim index As Integer = 0
        For i As Integer = 0 To NumLines - 1
            index = 1 + stringPrintText.IndexOf(ControlChars.Lf, index)
            If index = 0 Then
                Return stringPrintText.Length
            End If
        Next
        Return index
    End Function