Можно ли вставить CheckBox в заголовок DGV

Public Class HeaderCellCheckBox
    Inherits DataGridViewColumnHeaderCell
 
    Private _checkBoxRegion As Rectangle
    Private _checkAll As Boolean
 
    Public ReadOnly Property All As Boolean
        Get
            Return _checkAll
        End Get
    End Property
 
    Protected Overrides Sub Paint(ByVal graphics As Graphics, ByVal clipBounds As Rectangle, ByVal cellBounds As Rectangle, ByVal rowIndex As Integer, ByVal dataGridViewElementState As DataGridViewElementStates, ByVal value As Object, ByVal formattedValue As Object, ByVal errorText As String, ByVal cellStyle As DataGridViewCellStyle, ByVal advancedBorderStyle As DataGridViewAdvancedBorderStyle, ByVal paintParts As DataGridViewPaintParts)
        MyBase.Paint(graphics, clipBounds, cellBounds, rowIndex, dataGridViewElementState, value, formattedValue, errorText, cellStyle, advancedBorderStyle, paintParts)
        graphics.FillRectangle(New SolidBrush(cellStyle.BackColor), cellBounds)
        'Зона для прорисовки флажка
        _checkBoxRegion = New Rectangle(cellBounds.X + 1, cellBounds.Y + 2, 25, cellBounds.Height - 4)
        'Прорисовка флажка
        ControlPaint.DrawCheckBox(graphics, _checkBoxRegion, CType(IIf(_checkAll, ButtonState.Checked, ButtonState.Normal), ButtonState))
        'Зона для прорисовки текста заголовка
        Dim textRect As New Rectangle(_checkBoxRegion.Right + 1, _checkBoxRegion.Top, cellBounds.Width - _checkBoxRegion.Width, cellBounds.Height)
        'прорисовка текста
        graphics.DrawString(value.ToString(), cellStyle.Font, New SolidBrush(cellStyle.ForeColor), textRect)
    End Sub
 
    Protected Overrides Sub OnMouseClick(ByVal e As DataGridViewCellMouseEventArgs)
        _checkAll = Not _checkAll
        MyBase.OnMouseClick(e)
    End Sub
End Class

Public Class Form1
 
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim col As New DataGridViewTextBoxColumn()
        col.Name = "col1"
        col.HeaderCell = New HeaderCellCheckBox()
 
        DataGridView1.Columns.Add(col)
        For i As Integer = 0 To 100
            DataGridView1.Rows.Add(i.ToString())
        Next
    End Sub
    'Выделяем или снимаем выделение с ячеек в столбце
    Private Sub DataGridView1_ColumnHeaderMouseClick(sender As Object, e As DataGridViewCellMouseEventArgs) Handles DataGridView1.ColumnHeaderMouseClick
        If DataGridView1.Columns(e.ColumnIndex).HeaderCell.GetType() = GetType(HeaderCellCheckBox) Then
            For Each row As DataGridViewRow In DataGridView1.Rows
                row.Cells(e.ColumnIndex).Selected = CType(DataGridView1.Columns(e.ColumnIndex).HeaderCell, HeaderCellCheckBox).All
            Next
 
        End If
    End Sub
End Class

Public Class DGVcolumnheader
  Inherits Form
  Public Sub New()
    InitializeComponent()
  End Sub
  Private col As DataGridViewCheckBoxColumn
  Private chkBox As CheckBox
  Private Sub DGVcolumnheader_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    col = New DataGridViewCheckBoxColumn()
    col.Name = "Checkbox"
    col.HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleCenter
    Me.DataGridView1.Columns.Add(col)   
    chkBox = New CheckBox()
    Dim rect As Rectangle = Me.DataGridView1.GetCellDisplayRectangle(0, -1, True)
    chkBox.Size = New Size(18, 18)
    chkBox.Location = rect.Location
    AddHandler chkBox.CheckedChanged, AddressOf chkBox_CheckedChanged
    Me.DataGridView1.Controls.Add(chkBox)
  End Sub
  Private Sub chkBox_CheckedChanged(ByVal sender As Object, ByVal e As EventArgs)
    For i As Integer = 0 To Me.DataGridView1.RowCount - 1
      Me.DataGridView1(0, i).Value = Me.chkBox.Checked
    Next
    Me.DataGridView1.EndEdit()
  End Sub
End Class

 Private Sub DGView_NumbersPoint_ColumnHeaderMouseClick(ByVal sender As Object, ByVal e As DataGridViewCellMouseEventArgs) Handles DGView_NumbersPoint.ColumnHeaderMouseClick
        If sender.Columns(e.ColumnIndex).HeaderCell.GetType() = GetType(HeaderCellCheckBox) Then
        sender.CurrentCell = sender.Item(sender.Columns.GetFirstColumn(DataGridViewElementStates.Visible).Index + 1, e.ColumnIndex)
            For Each row As DataGridViewRow In sender.Rows
                row.Cells(e.ColumnIndex).Value = CType(sender.Columns(e.ColumnIndex).HeaderCell, HeaderCellCheckBox).All
            Next
        End If
    End Sub