Нахождения корня своим кодом

@cube2 · Регистрация: 29.03.2018

Author24 — интернет-сервис помощи студентам

Доброго времени суток, форумчане.
Хочу показать код нахождения корня числа. Вообще в Vb.Net для этого есть встроенная функция.

VB.NET

1	some_otvet = System.Math.Sqrt(some_chislo)

Но она может находить только квадратный корень. Для нахождения корня любой степени я сделал функцию:

Кликните здесь для просмотра всего текста

VB.NET

    Function Koren(ByVal kor As Double, ByVal ste As ULong)
        Dim otv As Double = 0.0
        Dim prev As Double = 0.0
        Dim left As Double = 0.0
        Dim right As Double = kor
        While otv <> prev    'зона поиска постепенно делится пополам, и когда дойдёт предел точности Double, искать не будет смысла 
            prev = otv    'запоминаем прошлое значение
            otv = (left / 2) + (right / 2)    'сначала делим на 2, а потом складываем во избежании переполнения Double
            If stepen(otv, ste) < kor Then
                left = otv    'сужаем левую границу поиска, если ответ слишком маленький
            ElseIf stepen(otv, ste) > kor Then
                right = otv    'сужаем правую границу поиска, если ответ слишком большой
            Else
                Exit While    'выходим из цикла, если ответ верный
            End If
        End While
        Return otv
    End Function

То есть мы ищем ste-нный корень числа kor.
Вообще, я хотел выполнить поиск корня полностью своим кодом, так что и нахождение степени брал на себя:

VB.NET

    Function stepen(osn As Double, pok As ULong) As Double
        Dim st As Double = osn
        For i As ULong = 2 To pok    'начинаем со 2й степени, так как ответ уже в первой
            st *= osn
        Next
        Return st
    End Function

Если вам это не нужно, замените в основной функции

VB.NET

1	stepen(otv, ste)

на

VB.NET

1	Math.Pow(otv, ste)

Далее идёт ~~никому не нужная~~ теория. Смотрите если интересно.

Кликните здесь для просмотра всего текста

Натуральный корень:

Кликните здесь для просмотра всего текста

Пример будет на квадратном корне из 16.
У нас есть виртуальный отрезок от 0 до 16 и его середина - 8.

Так как 8² больше 64, то приравниваем right к 8 и повторяем процедуру.

Иррациональный корень:

Кликните здесь для просмотра всего текста

Пример будет на квадратном корне из 2.
У нас есть виртуальный отрезок от 0 до 2 и его середина - 1.

Так как 1² меньше 2, то приравниваем left к 1 и повторяем процедуру.

Теперь у нас есть виртуальный отрезок от 1 до 2 и его середина - 1,5.
Так как 1,5² больше 2, то приравниваем right к 2 и повторяем процедуру.
...

Функция завершится, когда мы дойдёт до предела точности Double и значение перестанет изменяться

Результаты тестов:

Калькулятор: 1,414213562373095 (15 знаков)
Встроенный Sqrt: 1,4142135623731 (13 знаков)
Мой корень: 1,41421356237309 (14 знаков)

@ovva · 28.04.2019, 21:54

"Существует множество алгоритмов для вычисления значения квадратного корня из двух." (https://ru.wikipedia.org/wiki/... B8%D0%B7_2)
Определение квадратного корня методом Ньютона

VB.NET

Dim sq As Double = newSqrt(2, 0.000000000000001) '1.4142135623730949
Dim sqm As Double = Math.Sqrt(2) '1.4142135623730951
'…
Private Function newSqrt(ByVal x As Double, ByVal t As Double) As Double
    Dim s0 As Double = x / 2 'начальное приближение
    Dim s1 As Double
    Do While True
        s1 = 0.5 * (s0 + x / s0)
        If Math.Abs(s1 - s0) < t Then Exit Do
        s0 = s1
    Loop
    Return s1
End Function

Напомню, " с помощью числа с плавающей запятой можно аппроксимировать только десятичные числа, а точность, с которой аппроксимируется десятичное число, зависит от точности числа с плавающей запятой. По умолчанию значение Double содержит 15 десятичных цифр, хотя во внутреннем представлении может использоваться до 17 цифр."
Попробуем увеличить точность с тем же алгоритмом.

VB.NET

Dim sqdec As Decimal = newSqrtDec(2D, 1.0E-25) '1.4142135623730950488016887242D
'…
Private Function newSqrtDec(ByVal x As Decimal, ByVal t As Decimal) As Decimal
    Dim s0 As Decimal = x / 2 'начальное приближение
    Dim s1 As Decimal
    Do While True
        s1 = 0.5D * (s0 + x / s0)
        If Math.Abs(s1 - s0) < t Then Exit Do
        s0 = s1
    Loop
    Return s1
End Function

Более точно (https://sites.google.com/site/... koren-iz-3)
1,414 213 562 373 095 048 801 688 724 209 698 078 569 671 875 376 948 073 176 679 737 99…

@cube2 · 29.04.2019, 07:04 **[ТС]**

Поменял Double на Decimal, точность повысилась с

1,41421356237309 (14 знаков)

до

1,4142135623730950344523193965 (28 знаков)

Вот новый код

Кликните здесь для просмотра всего текста

VB.NET

    Function stepen(osn As Decimal, pok As ULong) As Double
        Dim st As Decimal = osn
        For i As ULong = 2 To pok
            st *= osn
        Next
        Return st
    End Function

VB.NET

    Function Koren(ByVal kor As Decimal, ByVal ste As ULong)
        Dim otv As Decimal = 0.0
        Dim prev As Decimal = 0.1
        Dim left As Decimal = 0.0
        Dim right As Decimal = kor
        While otv <> prev
            prev = otv
            otv = (left / 2) + (right / 2)
            If stepen(otv, ste) < kor Then
                left = otv
            ElseIf stepen(otv, ste) > kor Then
                right = otv
            Else
                Exit While
            End If
        End While
        Return otv
    End Function

Добавлено через 13 минут

1,4142135623730950488016887242 Ваша функция
1,4142135623730950344523193965 Моя функция

Добавлено через 3 минуты
И вообще, я ищу не корень двух, а любой корень любой степени

SoftIce · 29.04.2019, 08:27

cube2, а кроме точности, зачем это еще нужно ?

А скорость вычисления в 20 раз ниже чем у стандартного извлечения корня.

@cube2 · 29.04.2019, 08:29 **[ТС]**

Встроенное извлечение извлекает только квадратный корень, а мне нужен был любой степени

@Замабувараев · 29.04.2019, 08:32

Сообщение от cube2

Но она может находить только квадратный корень.

Корень — это показатель степени меньше единицы.
В бейсике всегда был оператор ^ для возведения числа в любую степень, даже дробную, что равносильно извлечению корня n-степени.

SoftIce · 29.04.2019, 08:37

Сообщение от Замабувараев

В бейсике всегда был оператор ^ для возведения числа в любую степень, даже дробную, что равносильно извлечению корня n-степени

Вот именно.

@ovva · 29.04.2019, 19:24

Сообщение от cube2

1,4142135623730950344523193965 Моя функция

Сравните этот результат с представленным выше точным значением (65 знаков после запятой).

Сообщение от cube2

я ищу не корень двух, а любой корень любой степени

Не вижу проблем

VB.NET

1
2
3

Dim x As Double = 22, n As Double = 1 / 3
Dim qn1 As Double = Math.Pow(x, n) '2.8020393306553868
Dim qn2 As Double = Math.Exp(n * Math.Log(x)) '2.8020393306553872

Если вы хотите контролировать точность получаемого результата то можно использовать разложение в ряд (Тейлора, полиномы Чебышева и т.п.).

Добавлено через 5 часов 28 минут
cube2, ближе к вашему подходу, но полагаю пошустрее

VB.NET

Dim qn3 As Double = RootOfDegreeN(x, 3, 0.0000000001) '2.8020393306553872
'…
Private Function RootOfDegreeN(ByVal x As Double, ByVal n As Integer, ByVal t As Double) As Double
    Dim s0 As Double = x / n, s1 As Double
    Dim dn As Double = 1 / n, ds As Double
    Do While True
        ds = (x / Power(s0, n - 1) - s0) * dn
        s1 = s0 + ds
        If Math.Abs(ds) < t Then Exit Do
        s0 = s1
    Loop
    Return s1
End Function
Private Function Power(ByVal x As Double, ByVal n As Integer) As Double
    If n = 0 Then
        Return 1
    End If
    If n Mod 2 = 0 Then
        Dim p = Power(x, n / 2)
        Return p * p
    Else
        Return x * Power(x, n - 1)
    End If
End Function

SoftIce es geht mir gut 11270 / 4752 / 1183 Регистрация: 27.07.2011 Сообщений: 11,439
	29.04.2019, 08:27	4
	cube2, а кроме точности, зачем это еще нужно ? А скорость вычисления в 20 раз ниже чем у стандартного извлечения корня. 0

@cube2 67 / 11 / 1 Регистрация: 29.03.2018 Сообщений: 37
	29.04.2019, 08:29 [ТС]	5
	Встроенное извлечение извлекает только квадратный корень, а мне нужен был любой степени 0

@Замабувараев COM‐пропагандист 859 / 768 / 147 Регистрация: 18.12.2014 Сообщений: 2,195 Записей в блоге: 4
	29.04.2019, 08:32	6
	Сообщение от cube2 Но она может находить только квадратный корень. Корень — это показатель степени меньше единицы. В бейсике всегда был оператор ^ для возведения числа в любую степень, даже дробную, что равносильно извлечению корня n-степени. 4

SoftIce es geht mir gut 11270 / 4752 / 1183 Регистрация: 27.07.2011 Сообщений: 11,439
	29.04.2019, 08:37	7
	Сообщение от Замабувараев В бейсике всегда был оператор ^ для возведения числа в любую степень, даже дробную, что равносильно извлечению корня n-степени Вот именно. Миниатюры 1