Найти открытый документ Word по названию

Sub ResultInfo()
    Dim str_Str As String
    Dim obj_Word   As Word.Application
    Dim obj_WDoc   As Word.Document
    Dim tabCurrent As Word.Table
    
    
    For Each obj_WDoc In Documents 'моя созданная проверка, в паре с If
    
        If obj_WDoc.Name = "Отчёт игры.doc" Then 
            obj_WDoc.Activate    'вот в этот блок If не заходит даже если уже открыт документ "Отчёт игры.doc"
 
        Else
            Set obj_Word = CreateObject("Word.Application")
            obj_Word.Visible = True
            'Set obj_WDoc = CreateObject("Word.Document")
 
            'Set tabCurrent = obj_WDoc.Tables.Add(obj_WDoc.Range, 1, 1)
            Set obj_WDoc = obj_Word.Documents.Add
                        With obj_WDoc
                .SaveAs Filename:="Отчёт игры.doc"
            End With
                        
            Set tabCurrent = obj_WDoc.Tables.Add(obj_WDoc.Range, 1, 2)
            With tabCurrent
                If .Style <> "Сетка таблицы" Then
                    .Style = "Сетка таблицы"
                End If
                .ApplyStyleHeadingRows = True
                .ApplyStyleLastRow = False
                .ApplyStyleFirstColumn = True
                .ApplyStyleLastColumn = False
                .ApplyStyleRowBands = True
                .ApplyStyleColumnBands = False
            End With
        End If
        
    Next obj_WDoc
End Sub

Sub ResultInfo()
    Dim str_Str As String
    Dim obj_Word   As Word.Application
    Dim obj_WDoc   As Word.Document
    Dim tabCurrent As Word.Table
    
    On Error Resume Next
    Set obj_WDoc = Documents("Отчёт игры.doc")
    If Err Then
      Err.Clear
      On Error GoTo 0
      Set obj_WDoc = Documents.Add
      Set tabCurrent = obj_WDoc.Tables.Add(obj_WDoc.Range, 1, 2)
      With tabCurrent
          If .Style <> "Сетка таблицы" Then
              .Style = "Сетка таблицы"
          End If
          .ApplyStyleHeadingRows = True
          .ApplyStyleLastRow = False
          .ApplyStyleFirstColumn = True
          .ApplyStyleLastColumn = False
          .ApplyStyleRowBands = True
          .ApplyStyleColumnBands = False
      End With
      obj_WDoc.SaveAs FileName:="Отчёт игры.doc", FileFormat:=wdFormatDocument
    End If
End Sub

Sub GetDocumentFromExcel()
    Dim objWord As Object, objDoc As Object
    On Error Resume Next
    Set objWord = GetObject(, "Word.Application")
    On Error GoTo 0
    If objWord Is Nothing Then 'Нет ни одного экземпляра приложения Word.
        MsgBox "Word не открыт, значит, и документ не открыт."
    Else 'Существует экземпляр приложения Word, поищем в нем документ.
        For Each objDoc In objWord.Documents
            If objDoc.Name = "Отчёт игры.doc" Then Exit For
        Next objDoc
        If objDoc Is Nothing Then
            MsgBox "Документ не открыт в существующем экземпляре приложения Word."
        Else
            MsgBox "Документ открыт."
            '...действия с документом (objDoc).
        End If
    End If
End Sub

  If objWord Is Nothing Then 'Нет ни одного экземпляра приложения Word.
        MsgBox "Word не открыт, значит, и документ не открыт."