Организация циклической вставки данных

Sub Procedure_1()
 
    'В константе "myPath" указываем путь папки, где находятся
        'книги Excel, из которых нужно взять данные.
    Const myPath As String = "C:\Users\User\Desktop\Папка"
    
    Dim shActiveSheet As Excel.Worksheet
    Dim myCurrentFile As String
    Dim myPreviousFile As String
    Dim myFlag As Boolean
    
    'Отключаем всё, что может тормозить работу кода.
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual
 
    '1. Даём имя "shActiveSheet" активному листу. Через это имя
        'будем обращаться к активному листу.
    Set shActiveSheet = ActiveSheet
    
    '2. Для просмотра всех файлов в папке будем использовать
        'команду "Dir".
    
    '2.1. Помещаем в переменную "myCurrentFile" имя первого нужного файла.
    myCurrentFile = Dir(myPath & "\*.xlsm")
    
    '2.2. Делаем цикл до тех пор, пока в переменной "myCurrentFile"
        'будет имя файла. Файлы берутся в последовательности
        'по дате создания (нигде об этом не написано - узнали опытным путём).
    Do While myCurrentFile <> ""
        
        'Если обрабатываем первую книгу, то
            'на активном листе нет ещё формул.
        'Переменная "myFlag" используется, чтобы определять:
            'есть на листе формулы или нет.
        If myFlag = False Then
        
            '3. Помещаем на активный лист формулы.
            shActiveSheet.Range("A1:K1048576").FormulaArray = _
                "='" & myPath & "\[" & myCurrentFile & "]Лист1'!A1:K1048576"
        
        'Если в переменной "myFlag" содержится текст "True",
            'то на активном листе уже содержатся формулы и надо
            'только произвести замену в формулах.
        Else
        
            '4. Заменяю предыдущее имя файла в формулах на листе
                'на имя текущего файла.
            shActiveSheet.Columns("A:K").Replace _
                What:=myPreviousFile, Replacement:=myCurrentFile, _
                LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, _
                SearchFormat:=False, ReplaceFormat:=False
 
        End If
        
        '5. Здесь обработка данных в активной книге.
        'К активной книге нужно обращаться по имени "shActiveSheet".
        
        
        '6. Формулу помещаем только один раз, затем производим
            'в формуле замену имени одной книги на другое.
            'Поэтому делаем пометку.
        myFlag = True
        
        '7. Запоминаю имя предыдущего файла, чтобы его имя
            'заменить в формулах на листе Excel.
        myPreviousFile = myCurrentFile
        
        '8. Это взятие следующего имени файла с теми же
            'параметрами, что указаны в пункте 2.1.
        myCurrentFile = Dir
    
    Loop
    
    'Включаем то, что отключали.
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic
    
End Sub

Sub Procedure_1()
 
    'В константе "myPath" указываем путь папки, где находятся
        'книги Excel, из которых нужно взять данные.
    Const myPath As String = "C:\Users\User\Desktop\Папка"
    
    Dim shActiveSheet As Excel.Worksheet
    Dim shSheet_1 As Excel.Worksheet
    Dim myFile As String
    
    'Отключаем всё, что может тормозить работу кода.
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    Application.Calculation = xlCalculationManual
 
    '1. Даём имя "shActiveSheet" активному листу. Через это имя
        'будем обращаться к активному листу.
    Set shActiveSheet = ActiveSheet
    
    '2. Для просмотра всех файлов в папке будем использовать
        'команду "Dir" - может она будет обрабатывать файлы
        'в алфавитном порядке.
    
    '2.1. Помещаем в переменную "myFile" имя первого нужного файла.
    myFile = Dir(myPath & "\*.xlsm")
    
    '2.2. Делаем цикл до тех пор, пока в переменной "myFile"
    'будет имя файла.
    Do While myFile <> ""
 
        '3. Открываем файл и даём первому листу имя "shSheet_1".
        'Через это имя можно обращаться к листу.
        Set shSheet_1 = GetObject(PathName:=myPath & "\" & myFile).Worksheets(1)
 
        '4. Берём данные из файла и помещаем в активный лист.
        shSheet_1.Columns("A:K").Copy shActiveSheet.Range("A1")
 
        '5. Закрываем файл.
        shSheet_1.Parent.Close SaveChanges:=False
 
        '6. Здесь обработка данных в активной книге.
        'К активной книге нужно обращаться по имени "shActiveSheet".
        
        '7. Это взятие следующего имени файла с теми же
            'параметрами, что указаны в пункте 2.1.
        myFile = Dir
    
    Loop
    
    'Включаем то, что отключали.
    Application.ScreenUpdating = True
    Application.EnableEvents = True
    Application.Calculation = xlCalculationAutomatic
    
End Sub