Добавление строки с заданным условием

Sub Procedure_1()
 
    Dim myLastRow As Long
    Dim myBlanksCount As Long
    Dim i As Long
    
    '1. Делаем действия, чтобы ускорить работу кода.
    '1.1. Отключаем обновление монитора.
    Application.ScreenUpdating = False
    '1.2. Отключаем пересчёт формул.
    Application.Calculation = xlCalculationManual
 
    '2. Определяем последнюю строку с данными.
        'Команда делает действие, аналогичное тому,
        'если в Excel сделать активной последнюю ячейку в столбце "A"
        'и нажать сочетание клавиш "Ctrl + стрелка вверх".
    myLastRow = Range("A" & Rows.Count).End(xlUp).Row
    
    'Двигаемся снизу вверх.
        'Двигаемся снизу вверх, т.к. при добавлении строк
        'порядковые номера строк будут меняться и сложнее будет
        'высчитывать, к какой следующей строке перейти.
    For i = myLastRow To 2 Step -1
        
        '3. Анализируем столбцы "C" и "D":
            'смотрим: есть ли что-нибудь в них.
        'Использую для этого VBA-Excel-функцию "CountA".
            'Она подсчитывает количество непустых ячеек.
            'В Excel есть аналогичная Excel-функция "СЧЁТЗ".
        myBlanksCount = Application.WorksheetFunction.CountA(Range("C" & i & ":D" & i))
        If myBlanksCount <> 0 Then
            
            '4. Добавляем нужное количество строк.
            '4.1. Копируем строку, т.к. в ней содержатся данные,
                'которые нужно вставить в другие строки.
            Rows(i).Copy
            '4.2. Вставляем скопированное ниже.
            'CopyOrigin - используется, чтобы копировать форматирование,
                'например, границы ячеек.
            Rows(i).Offset(1).Resize(myBlanksCount).Insert Shift:=xlShiftDown, CopyOrigin:=True
            
            '5. Переносим данные из столбцов "C" и "D" в столбец "B".
            
            'Если есть только одна рубрика, то не известно,
                'где она записана: в столбце "C" или "D". Поэтому
                'нужно сделать некоторые манипуляции.
            If myBlanksCount = 1 Then
            
                If IsEmpty(Range("C" & i)) = False Then
                    Range("B" & i).Offset(1, 0).Value = Range("C" & i).Value
                Else
                    Range("B" & i).Offset(1, 0).Value = Range("D" & i).Value
                End If
            
            'Если в обеих ячейках есть данные.
            Else
                Range("B" & i).Offset(1, 0).Value = Range("C" & i).Value
                Range("B" & i).Offset(2, 0).Value = Range("D" & i).Value
            End If
            
        End If
    
    Next i
    
    '6. Определяем последнюю строку с данными.
    myLastRow = Range("A" & Rows.Count).End(xlUp).Row
    
    '7. Удаляем данные из столбцов "C" и "D".
    'Я использую для удаления данныех "Formula", т.к.
        'если удалять другими способами, то иногда не вся информация удаляется.
    Range("C2:D" & myLastRow).Formula = ""
    
    '8. Выход из режима копирования.
    Application.CutCopyMode = False
    
    '9. Включаем то, что отключали.
    Application.ScreenUpdating = True
    Application.Calculation = xlCalculationAutomatic
    
End Sub