Нужен исходник по созданию определенного количества папок

;---------------------------------------------
; RegJump Demo
; Copyright (C) ManHunter / PCL
; http://www.manhunter.ru
;---------------------------------------------
 
format PE GUI 4.0
entry start
 
include 'win32a.inc'
 
;---------------------------------------------
 
section '.data' data readable writeable
 
szClass db 'RegEdit_RegEdit',0
szList  db 'SysTreeView32',0
szReg   db '\HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\WINDOWS\CURRENTVERSION\',0
 
hRWnd dd ?
hWnd dd ?
ProcessId dd ?
hProcess dd ?
 
;---------------------------------------------
 
section '.code' code readable executable
 
  start:
        ; Найти окно редактора реестра
        invoke  FindWindow,szClass,NULL
        or      eax,eax
        jz      loc_exit
        mov     [hRWnd],eax
 
        ; Найти список в окне реестра
        invoke  FindWindowEx,[hRWnd],NULL,szList,NULL
        or      eax,eax
        jz      loc_exit
        mov     [hWnd],eax
 
        ; Получить хэндл процесса-владельца
        invoke  GetWindowThreadProcessId,[hRWnd],ProcessId
        invoke  OpenProcess,PROCESS_QUERY_INFORMATION,0,[ProcessId]
        or      eax,eax
        jz      loc_exit
        mov     [hProcess],eax
 
        ; Активировать окно редактора реестра
        invoke  ShowWindow,[hRWnd],SW_RESTORE
        invoke  SetForegroundWindow,[hRWnd]
        ; Установить фокус на список
        invoke  SetFocus,[hWnd]
        invoke  WaitForInputIdle,[hProcess],-1
 
        ; Вот тут непонятно :(
        invoke  SendMessage,[hRWnd],WM_COMMAND,10288h,0
        invoke  WaitForInputIdle,[hProcess],-1
 
        ; Перейти на верхний уровень списка
        mov     ebx,30
@@:
        invoke  SendMessage,[hWnd],WM_KEYDOWN,VK_LEFT,0
        invoke  WaitForInputIdle,[hProcess],-1
        sub     ebx,1
        jnz     @b
 
        ; Указатель на строку в названием ветки реестра
        mov     esi,szReg
loc_loop:
        lodsb
        or      al,al
        jz      loc_exit_clean
 
        cmp     al,'\'
        jne     @f
        ; Открыть ветку списка
        invoke  SendMessage,[hWnd],WM_KEYDOWN,VK_RIGHT,0
        invoke  WaitForInputIdle,[hProcess],-1
        jmp     loc_loop
@@:
        movzx   eax,al
        ; Поиск строки в списке
        invoke  SendMessage,[hWnd],WM_CHAR,eax,0
        invoke  WaitForInputIdle,[hProcess],-1
        jmp     loc_loop
loc_exit_clean:
        invoke  CloseHandle,[hProcess]
 
loc_exit:
        invoke  ExitProcess,0
 
;---------------------------------------------
 
section '.idata' import data readable writeable
 
  library kernel32,'kernel32.dll',\
          user32,'user32.dll'
 
  include 'api\kernel32.inc'
  include 'api\user32.inc'