Скрипт отправки на FTP и копирования ссылки в буфер обмена

Dragokas · Регистрация: 25.12.2011

Студворк — интернет-сервис помощи студентам

Решил поделиться полезняшкой:

1) Внести в код имя своего FTP-сервера, имя пользователя и пароль, корневую директорию.
1) Сохранить код в файл "FTP and ClipBoard.VBS"
2) Перетащить на него любой файл.

Получаем отправку на FTP и в буфере обмена уже готовую ссылочку.

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Rem Отправка на FTP и копирование ссылки в буфер (Visual Basic Script)
Dim objArgs, Server, DomainName, Port, User, Pass, Folder, rootFolder, CloseDOS, DosStr
 
'=== Данные учетной записи FTP ===
 
Server = "31.170.123.45"
DomainName = "http://NickName.16mb.com"
Port = "21"
User = "***"
Pass = "***"
 
'Папка на FTP, куда будут складываться файлы
rootFolder = "public_html" 'корневая
Folder = "Folder/SubFolder" 'подкаталог
 
'Флаг - закрывать консольное окно после передачи данных
CloseDOS = True
if not CloseDOS then DosStr = "&pause"
 
Set objArgs = wscript.Arguments
If objArgs.Count <> 0 Then 'Проверяем аргументы (Drag & Drop "путь к файлу")
    Dim FName, WSHShell, Link, FF, TmpFile, objFile
    
    'Получаем имя файла
    FName = Mid(objArgs(0), InStrRev(objArgs(0), "\") + 1)
    'Интернет-адрес
    Link = DomainName & "/" & Folder & "/" & FName
 
    Set WSHShell = CreateObject("WScript.Shell")
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    
    'Копируем в буфер обмена Windows
    WSHShell.Run "cmd.exe /C <nul set /p ""=" & Link & """ | CLIP", 0, False
 
    'Формируем строку коннекта для утилиты FTP
    TmpFile = WSHShell.ExpandEnvironmentStrings("%temp%") & "\temp_" & CInt(Rnd() * 1000)   
    'ForAppending = 8, ForReading = 1, ForWriting = 2
    Set objFile = objFSO.OpenTextFile (TmpFile, 2, True, 0) 'True - создать файл
        objFile.WriteLine "open " & Server & " " & Port
        objFile.WriteLine User
        objFile.WriteLine Pass
        objFile.WriteLine "cd " & rootFolder & "/" & Folder
        objFile.WriteLine "binary"
        objFile.WriteLine "put """ & objArgs(0) & """"
        objFile.WriteLine "disconnect"
        objFile.WriteLine "bye"
    objFile.Close
    
    'Добавляем утилиту FTP в исключения файрвола и запускаем
    WSHShell.Run "cmd.exe /c ""(netsh firewall add allowedprogram """ & WSHShell.ExpandEnvironmentStrings("%windir%") & _
      "\system32\ftp.exe"" ENABLE& ftp -s:""" & TmpFile & """" & DosStr & ")""", 1, True
 
    objFSO.DeleteFile TmpFile, True
 
    Set WSHShell = Nothing: Set objFile = Nothing: Set objFSO = Nothing
    
    wscript.echo "Путь к файлу на FTP: " & vbLf & Link & String(2, vbLf) & _
    "Путь к файлу скопирован в буфер обмена Windows."
  Else
    wscript.echo "Перетащите файл на VBS-сценарий"
End If
Set objArgs = Nothing

Единственное, я не понял как получить ссылку на файл с русскими буквами.
Визуально ссылочка выглядит так: http://Dragokas.16mb.com/Forum/Dl/Тест.txt
(сейчас такой файл у меня реально существует в указанной папке).
P.S. Переадресация на ссылку не будет работать (баг форума).
Но скачать не получается. Помогите, плиз.

Dragokas · 21.01.2013, 23:05 **[ТС]**

Чуть изменил код.

Развернуть код...

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Rem Отправка на FTP и копирование ссылки в буфер (Visual Basic Script)
Dim objArgs, Server, DomainName, Port, User, Pass, Folder, SystemFolder, CloseDOS, DosStr
 
'=== Данные учетной записи FTP ===
 
Server = "IP-адрес FTP"
DomainName = "http://Домен.16mb.com"
Port = "21"
User = ""
Pass = ""
 
'Папка на FTP, куда будут складываться файлы
SystemFolder = "public_html" 'Системная папка
Folder = "Forum/Dl" 'подкаталог
 
'Флаг - закрывать консольное окно после передачи данных
CloseDOS = True
if not CloseDOS then DosStr = "&pause"
 
Set objArgs = wscript.Arguments
If objArgs.Count <> 0 Then 'Проверяем аргументы (Drag & Drop "путь к файлу")
    Dim FName, WSHShell, Link, FF, TmpFile, objFile
    
    'Получаем имя файла
    FName = Mid(objArgs(0), InStrRev(objArgs(0), "\") + 1)
    'Интернет-адрес
    Link = DomainName & "/" & Folder & "/" & FName
 
    Set WSHShell = CreateObject("WScript.Shell")
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    
    'Копируем в буфер обмена Windows
    WSHShell.Run "cmd.exe /C <nul set /p ""=" & Link & """ | CLIP", 0, False
 
    'Формируем строку коннекта для утилиты FTP
    TmpFile = WSHShell.ExpandEnvironmentStrings("%temp%") & "\temp_" & CInt(Rnd() * 1000)   
    'ForAppending = 8, ForReading = 1, ForWriting = 2
    Set objFile = objFSO.OpenTextFile (TmpFile, 2, True, 0) 'True - создать файл
        objFile.WriteLine "open " & Server & " " & Port
        objFile.WriteLine User
        objFile.WriteLine Pass
        objFile.WriteLine "cd " & SystemFolder & "/" & Folder
        objFile.WriteLine "binary"
        objFile.WriteLine "hash"
        objFile.WriteLine "put """ & objArgs(0) & """"
        objFile.WriteLine "disconnect"
        objFile.WriteLine "bye"
    objFile.Close
    
    'Добавляем утилиту FTP в исключения файрвола и запускаем
    WSHShell.Run "cmd.exe /c ""(netsh firewall add allowedprogram """ & WSHShell.ExpandEnvironmentStrings("%windir%") & _
      "\system32\ftp.exe"" ENABLE& ftp -s:""" & TmpFile & """" & DosStr & ")""", 1, True
 
    objFSO.DeleteFile TmpFile, True
 
    Set WSHShell = Nothing: Set objFile = Nothing: Set objFSO = Nothing
    
    n = inputbox("Путь к файлу на FTP",,Link)
    'wscript.echo "Путь к файлу на FTP: " & vbLf & Link & String(2, vbLf) & _
    '"Путь к файлу скопирован в буфер обмена Windows."
  Else
    wscript.echo "Перетащите файл на VBS-сценарий"
End If
Set objArgs = Nothing

Теперь ссылку на наш файл в буфере обмена мы получаем сразу.
Когда файл будет докачан на сервер - появляется текстовое окно, откуда легко скопировать ссылку
на случай, если Вы случайно очистили буфер обмена.
Файлы с русскими буквами действительно не открываются в браузере, но такую ссылку спокойно качает
спец. менеджер, например бесплатный Download Master.

В скрипте использована утилита Clip, которой нет в составе Windows XP.
Можете взять альтернативу у Carl Peterson ConClip

Как этим добром проще пользоваться:
1. Сохранить с расширением VBS.
2. Зарегистрировать любой*, можно бесплатный хостинг с FTP.
3. Внести учетные данные в скрипт:

Server = "31.170.164.47"
DomainName = "http://Dragokas.16mb.com"
Port = "21"
User = ""
Pass = ""

Задать корневую системную папку (если такая используется сервером - это папка,
которая видна в FTP-менеджере, но она не входит в состав ссылки при скачивании файла).
Задать папку, куда по-умолчанию отправлять файлы.

SystemFolder = "public_html" 'Системная папка
Folder = "Forum/Dl" 'подкаталог

2. Поместить скрипт в системную папку SendTo
Как найти SendTo:
XP: Пуск -> Выполнить Sendto
или читаем MSKB 310270
Vista, Win 7...: Пуск, пишем в строке поиска Shell:Sendto и нажимаем {ENTER}.

*Где взять сервер FTP?
Например, здесь, которым я пользуюсь;
или вот целая тема рекомендаций: Хостинг с MySQL и возможностью доступа к БД удалённо

@sotik · 18.03.2014, 12:57

Скрипт работает не корректно.
Вобщем у меня окошко со ссылкой не появляется и висит консольное окно,а появляется только когда уберешь процесс ftp.
Все данные к ftp прописаны верно,файл закачивается,но пустой.

Dragokas · 19.03.2014, 02:00 **[ТС]**

sotik, сделайте скриншот момента на котором останавливается консольное окно.
Какой сервер используете?

@sotik · 19.03.2014, 03:07

он вас испугался.
Все заработало.
Наверно не хватало путей path к дополнительным утилитам,которые поместил в system32.
После перезагрузки компа все работает.
Спасибо.

Dragokas · 22.04.2023, 20:05 **[ТС]**

Современный вариант:

Полезные BAT/CMD скрипты

Новые блоги и статьи Все статьи Все блоги /
PhpStorm 2025.3: WSL Terminal всегда стартует в ~ and_y87 14.12.2025 PhpStorm 2025. 3: WSL Terminal всегда стартует в ~ (home), игнорируя директорию проекта Симптом: После обновления до PhpStorm 2025. 3 встроенный терминал WSL открывается в домашней директории. . .	Access VikBal 11.12.2025 Помогите пожалуйста !! Как объединить 2 одинаковые БД Access с разными данными.	Новый ноутбук volvo 07.12.2025 Всем привет. По скидке в "черную пятницу" взял себе новый ноутбук Lenovo ThinkBook 16 G7 на Амазоне: Ryzen 5 7533HS 64 Gb DDR5 1Tb NVMe 16" Full HD Display Win11 Pro	Музыка, написанная Искусственным Интеллектом volvo 04.12.2025 Всем привет. Некоторое время назад меня заинтересовало, что уже умеет ИИ в плане написания музыки для песен, и, собственно, исполнения этих самых песен. Стихов у нас много, уже вышли 4 книги, еще 3. . .	От async/await к виртуальным потокам в Python IndentationError 23.11.2025 Армин Ронахер поставил под сомнение async/ await. Создатель Flask заявляет: цветные функции - провал, виртуальные потоки - решение. Не threading-динозавры, а новое поколение лёгких потоков. Откат?. . .
Поиск "дружественных имён" СОМ портов Argus19 22.11.2025 Поиск "дружественных имён" СОМ портов На странице: https:/ / norseev. ru/ 2018/ 01/ 04/ comportlist_windows/ нашёл схожую тему. Там приведён код на С++, который показывает только имена СОМ портов, типа,. . .	Сколько Государство потратило денег на меня, обеспечивая инсулином. Programma_Boinc 20.11.2025 Сколько Государство потратило денег на меня, обеспечивая инсулином. Вот решила сделать интересный приблизительный подсчет, сколько государство потратило на меня денег на покупку инсулинов. . . .	Ломающие изменения в C#.NStar Alpha Etyuhibosecyu 20.11.2025 Уже можно не только тестировать, но и пользоваться C#. NStar - писать оконные приложения, содержащие надписи, кнопки, текстовые поля и даже изображения, например, моя игра "Три в ряд" написана на этом. . .	Мысли в слух kumehtar 18.11.2025 Кстати, совсем недавно имел разговор на тему медитаций с людьми. И обнаружил, что они вообще не понимают что такое медитация и зачем она нужна. Самые базовые вещи. Для них это - когда просто люди. . .	Создание Single Page Application на фреймах krapotkin 16.11.2025 Статья исключительно для начинающих. Подходы оригинальностью не блещут. В век Веб все очень привыкли к дизайну Single-Page-Application . Быстренько разберем подход "на фреймах". Мы делаем одну. . .

@sotik 2 / 2 / 0 Регистрация: 20.01.2014 Сообщений: 87
	18.03.2014, 12:57
	Скрипт работает не корректно. Вобщем у меня окошко со ссылкой не появляется и висит консольное окно,а появляется только когда уберешь процесс ftp. Все данные к ftp прописаны верно,файл закачивается,но пустой. 0

Dragokas 18030 / 7733 / 892 Регистрация: 25.12.2011 Сообщений: 11,502 Записей в блоге: 16
	19.03.2014, 02:00 [ТС]
	sotik, сделайте скриншот момента на котором останавливается консольное окно. Какой сервер используете? 0

@sotik 2 / 2 / 0 Регистрация: 20.01.2014 Сообщений: 87
	19.03.2014, 03:07
	он вас испугался. Все заработало. Наверно не хватало путей path к дополнительным утилитам,которые поместил в system32. После перезагрузки компа все работает. Спасибо. 0

Dragokas 18030 / 7733 / 892 Регистрация: 25.12.2011 Сообщений: 11,502 Записей в блоге: 16
	22.04.2023, 20:05 [ТС]
	Современный вариант: Полезные BAT/CMD скрипты 0

Скрипт отправки на FTP и копирования ссылки в буфер обмена

Решение