Копировать, выделить, вставить

Text1.Text = Clipboard.GetText

text1.text=clipboard.gettext()

Private Const WM_GETTEXTLENGTH = &HE
Private Const WM_GETTEXT = &HD
Private Const PS_SOLID = 0
Private Const BS_NULL = 1
Private Type POINTAPI
    X As Long
    Y As Long
End Type
Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Type LOGBRUSH
    lbStyle As Long
    lbColor As Long
    lbHatch As Long
End Type
Private Declare Function ClientToScreen Lib "user32" (ByVal hwnd As Long, lpPoint As POINTAPI) As Long
Private Declare Function WindowFromPoint Lib "user32" (ByVal xPoint As Long, ByVal yPoint As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function SetCapture Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseCapture Lib "user32" () As Long
Private Declare Function GetClientRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hdc As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Declare Function CreatePen Lib "gdi32" (ByVal nPenStyle As Long, ByVal nWidth As Long, ByVal crColor As Long) As Long
Private Declare Function CreateBrushIndirect Lib "gdi32" (lpLogBrush As LOGBRUSH) As Long
Private Declare Function InvalidateRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT, ByVal bErase As Long) As Long
Private Declare Function Rectangle Lib "gdi32" (ByVal hdc As Long, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Declare Function GetDC Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function ReleaseDC Lib "user32" (ByVal hwnd As Long, ByVal hdc As Long) As Long
 
Dim Capture As Boolean, SelWnd As Long, Old As Long, Pen As Long, Brush As Long
 
Private Sub cmdGetText_Click()
    Dim L As Long, Txt As String
    If SelWnd = 0 Then Exit Sub
    L = SendMessage(SelWnd, WM_GETTEXTLENGTH, 0, ByVal 0)
    If L = 0 Then Exit Sub
    Txt = Space(L + 1)
    Call SendMessage(SelWnd, WM_GETTEXT, L + 1, ByVal Txt)
    txtOutput.Text = Txt
End Sub
Private Sub cmdPick_Click()
    Dim lb As LOGBRUSH
    lb.lbStyle = BS_NULL
    Capture = True
    Old = 0
    Pen = CreatePen(PS_SOLID, 3, vbRed)
    Brush = CreateBrushIndirect(lb)
    SetCapture Me.hwnd
End Sub
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Capture Then
        Dim Pt As POINTAPI, Rc As RECT
        Capture = False
        Pt.X = X: Pt.Y = Y
        ClientToScreen Me.hwnd, Pt
        SelWnd = WindowFromPoint(Pt.X, Pt.Y)
        Me.Caption = SelWnd
        ReleaseCapture
        DeleteObject Pen
        DeleteObject Brush
        If Not (Old = 0) Then
            GetClientRect Old, Rc
            InvalidateRect Old, Rc, True
        End If
    End If
End Sub
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    If Capture Then
        Dim Rc As RECT, Pt As POINTAPI, Cur As Long, DC As Long, dcPen As Long, dcBrush As Long
        Pt.X = X: Pt.Y = Y
        ClientToScreen Me.hwnd, Pt
        Cur = WindowFromPoint(Pt.X, Pt.Y)
        If Not (Cur = Old) Then
            If Not (Old = 0) Then
                GetClientRect Old, Rc
                InvalidateRect Old, Rc, True
            End If
            GetClientRect Cur, Rc
            DC = GetDC(Cur)
            dcPen = SelectObject(DC, Pen)
            dcBrush = SelectObject(DC, Brush)
            Rectangle DC, Rc.Left, Rc.Top, Rc.Right, Rc.Bottom
            SelectObject DC, dcBrush
            SelectObject DC, dcPen
            ReleaseDC Cur, DC
            Old = Cur
        End If
    End If
End Sub