Отслеживание закрытия файла процессом, запущенным через CreateProcess

Option Explicit
 
Private Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type
 
Private Declare Function SendMessageW Lib "user32" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowW" (ByVal lpClassName As Long, ByVal lpWindowName As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
 
Private Const WM_COPYDATA = &H4A
 
Private Sub Document_Close()
    Dim Answer          As VbMsgBoxResult
    Dim BookPath        As String
    Dim ReceiveWndTtile As String
    
    'Куда отправляем (Title окна) ?
    
    ReceiveWndTtile = "Get_WM_COPYDATA"
    
    BookPath = ActiveDocument.Path & "\" & ActiveDocument.Name
    
    With ActiveDocument
        ' Изменяем поведение программы, делая псевдо-перехват диалогового окна сохранения файла, эмулируя наше собственное.
        ' Иначе это окно возникнет в момент времени ПОСЛЕ возбуждения данного события,
        ' а нам ведь нужно отправить в другой процесс сообщение в момент времени - ПОСЛЕ сохранения документа, а не ДО.
        If Not .Saved Then
            Answer = MsgBox("Вы хотите сохранить изменения в " & .Name & "?", vbYesNoCancel Or vbExclamation)
            If vbYes = Answer Then
                .Save
                .Saved = True
            ElseIf vbNo = Answer Then
                .Saved = True   ' сообщаем документу, что несохраненных данных нет, таким образом стандартное окно не появится
            End If
        End If
        ' Если не была нажата кнопка "Отмена" -> документ в процессе закрытия, а исходный файл содержит актуальные данные.
        ' Документ все еще открыт Word-ом в режиме общего доступа, тем не менее его уже можно использовать другим процессом.
        If vbCancel <> Answer Then
            'MsgBox BookPath
            
            Dim hWnd As Long
            hWnd = FindWindow(0&, StrPtr(ReceiveWndTtile))
            
            If 0 <> hWnd Then
                Dim CDRec As COPYDATASTRUCT
                CDRec.dwData = 1                'ID
                CDRec.cbData = LenB(BookPath)   'Size of Data
                CDRec.lpData = StrPtr(BookPath) 'pointer to Data
                SendMessageW hWnd, WM_COPYDATA, hWnd, CDRec
                CloseHandle hWnd
            End If
        End If
    End With
End Sub