Вращение треугольника вокруг своей оси

Public Class Form1
    Private points As PointF() = {New PointF(100, 100), New PointF(100, 200), New PointF(300, 300)}
 
 
    Protected Overrides Sub OnLoad(e As EventArgs)
        MyBase.OnLoad(e)
        'При загрузке формы создаём таймер, который будет поворачивать точки на 2°
        'и обновлять форму каждые 200 мс
        Dim t As New Timer() With {.Interval = 200}
        AddHandler t.Tick, Sub()
                               points = Rotate(points, 2)
                               Invalidate()
                           End Sub
        t.Enabled = True
    End Sub
 
    ''' <summary>
    ''' Вращение трёх точек относительно центра вписанной окружности
    ''' </summary>
    ''' <param name="points">Точки</param>
    ''' <param name="angle">Угол вращения, в градусах</param>
    Private Function Rotate(points As PointF(), angle As Single) As PointF()
        Dim retval As PointF() = New PointF(2) {}
        Dim cen = GetCenter(points)
        Dim cos, sin As Double
        cos = Math.Cos(angle * Math.PI / 180)
        sin = Math.Sin(angle * Math.PI / 180)
        'вращаем каждую вершину относительно центра
        For i = 0 To points.Count - 1
            Dim pt = points(i)
            Dim vx, vy As Single
            vx = pt.X - cen.X
            vy = pt.Y - cen.Y
            'Записываем новые координаты
            retval(i) = New PointF(vx * cos - vy * sin + cen.X, vx * sin + vy * cos + cen.Y)
        Next
        Return retval
    End Function
    ''' <summary>
    ''' Отыскание центра вписанной окружности треугольника, заданного тремя точками
    ''' </summary>
    ''' <param name="points">Вершины треугольника</param>
    Private Function GetCenter(points As PointF()) As PointF
        Dim x, y As Single 'Координаты центра
        Dim a, b, c As Single 'Длины сторон
        a = Math.Sqrt((points(0).X - points(1).X) ^ 2 + (points(0).Y - points(1).Y) ^ 2)
        b = Math.Sqrt((points(1).X - points(2).X) ^ 2 + (points(1).Y - points(2).Y) ^ 2)
        c = Math.Sqrt((points(2).X - points(0).X) ^ 2 + (points(2).Y - points(0).Y) ^ 2)
 
        x = (a * points(2).X + b * points(0).X + c * points(1).X) / (a + b + c)
        y = (a * points(2).Y + b * points(0).Y + c * points(1).Y) / (a + b + c)
        Return New PointF(x, y)
    End Function
 
 
    Protected Overrides Sub OnPaint(e As PaintEventArgs)
        MyBase.OnPaint(e)
        e.Graphics.DrawPolygon(Pens.Red, points)
        Dim pt = GetCenter(points)
        e.Graphics.FillEllipse(Brushes.Blue, pt.X + 3, pt.Y + 3, 6, 6)
    End Sub
End Class