Составить программу формирования звуковых сигналов в соответствии с диаграммой

@hartmeyerorum8 · Регистрация: 12.03.2017

Студворк — интернет-сервис помощи студентам

Пару месяцев изучаем ассемблер, но ничего толком нам не объясняют. Дали вот такую задачу, в качестве итоговой, но я почти ничего не понимаю в этом. Помогите, пожалуйста.

Составить программу формирования звуковых сигналов в соответствии с диаграммой, которая представлена "лестницей" из 100 ступеней c убывающей частотой звука. Первая ступень частотой 1000, вторая 900, третья 800 и т.д. Интервал времени звучания каждой ступени равен T. Интервал времени T задать с клавиатуры, прерывание по ESC, число ступеней 100.

@Jin X · 24.04.2017, 17:54

Вот вам в лом перепечатать задание (мы должны эти каракули разбирать). И даже фотку развернуть нормально не можете. А кто-то должен за вас всё сделать...
Если надо помочь (а не сделать всё за вас), показывайте что сделано и где проблема конкретно.

Правила
4.7. Как можно более полно описывайте суть проблемы или вопроса, что было сделано для ее решения и какие результаты получены.
5.18. Запрещено размещать задания и решения в виде картинок и других файлов с их текстом.

@hartmeyerorum8 · 24.04.2017, 18:34 **[ТС]**

Извиняюсь. К сожалению, я ничего не могу сделать, так как не понимаю как.
Переписал задание:
Составить программу формирования звуковых сигналов в соответствии с диаграммой, которая представлена "лестницей" из 100 ступеней c убывающей частотой звука. Первая ступень частотой 1000, вторая 900, третья 800 и т.д. Интервал времени звучания каждой ступени равен T. Интервал времени T задать с клавиатуры, прерывание по ESC, число ступеней 100.

@Mikl___ · 24.04.2017, 18:39

hartmeyerorum8,
ищи в сети Джордейн Р. "Справочник программиста персональных компьютеров типа IBM PC, XT и AT". В ней найдешь главу о формировании звука системным динамиком и готовую программу

ФедосеевПавел · 24.04.2017, 21:39

https://www.cyberforum.ru/asm-... 50903.html

ФедосеевПавел · 28.04.2017, 19:57

hartmeyerorum8,
Воспользовался кодом для генерации звуков из темы https://www.cyberforum.ru/asm-... 50903.html

Ввод чисел взял из темы Ввод и вывод чисел в различных системах счисления
Если захотите - можете добавить обработку неправильного ввода чисел. Пример - в той же теме.

По правде, глядя на рисунок, полагаю, что ступеней не 100, а всего 10, но

Сообщение от hartmeyerorum8

число ступеней 100

а мне безразлично. При необходимости измените константу.

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
LOCALS
 
.model small
 
.stack 100h
 
.data
 
        Fstart  equ     1000    ;начальная частота
        Ffinish equ     100     ;конечная частота
        N       equ     100     ;количество ступеней
        deltaF  equ     (Fstart-Ffinish)/N      ;приращение частоты
        T       dw      0       ;время звучания ступени в милисекундах
        Delay   dd      0       ;время задержки в микросекундах для WaitFor
 
        kbdBuf  db      6,0,7 dup(0)    ;буфер ффода с клавиатуры
        CrLf    db      0Dh, 0Ah, '$'
        Prompt  db      'Input T (miliseconds): ', 0Dh, 0Ah, '$'
.code
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
@@InputT:
        mov     ah,     09h
        lea     dx,     Prompt
        int     21h
 
        mov     ah,     0Ah
        lea     dx,     kbdBuf
        int     21h
 
        lea     si,     kbdBuf+1
        lea     di,     T
        call    Str2Num
 
        mov     ah,     09h
        lea     dx,     CrLf
        int     21h
 
        ;пересчёт времени звучания в микросекунды
        mov     ax,     1000
        mul     T
        mov     word ptr Delay, ax
        mov     word ptr Delay+2,dx
 
        ;цикл генерации звуковых ступеней
        mov     ax,     Fstart
        mov     cx,     N
@@For:
        call    Sound
        call    WaitFor
        call    No_Sound
        sub     ax,     deltaF
        loop    @@For
 
        mov     ax,     4C00h
        int     21h
main    endp
 
;Подача звука через встроенный спикер
;ах - частота звука
Sound      proc     near
    push     ax        ;сохранить регистры
    push     bx
    push     dx
    mov      bx,ax     ;частота
    mov      ax,34DDh
    mov      dx,12h    ;(dx,ax)=1193181
    cmp      dx,bx     ;если bx < 18Гц, то выход
    jnb      Done      ;чтобы избежать переполнения
    div      bx        ;ax=(dx,ax)/bx
    mov      bx,ax     ;счетчик таймера
    in       al,61h    ;порт РВ
    or       al,3      ;установить биты 0-1
    out      61h,al
    mov      al,00001011b   ;управляющее слово таймера:
                        ;канал 2, режим 3, двоичное слово
    mov      dx,43h    ;вывод в регистр режима
    out      dx,al     ;устанавливаем режим работы таймера
    dec      dx    ;порт 2-го канала
    mov      al,bl     ;младший байт счетчика
    out      dx,al     ;записываем
    mov      al,bh     ;старший байт счетчика
    out      dx,al     ;записываем
Done:   pop      dx        ;восстановить регистры
    pop      bx
    pop      ax
    ret        ;выход из подпрограммы
Sound      endp
 
;Прекращение подачи звука через встроенный спикер
No_Sound   proc     near
    push    ax  ;сохраняем регистр
    in  al,61h  ;порт РВ
    and al,not 3;сброс битов 0-1
    out 61h,al  ;возвращаем значение в порт
    pop ax  ;восстанавливаем регистр
    ret     ;выход из подпрограммы
No_Sound   endp
 
;Ожидание
;на входе:
; переменная Delay - время ожидания в микросекундах
WaitFor proc
        push    ax
        push    cx
        push    dx
        mov     ah,     86h
        mov     al,     00h
        mov     dx,     word ptr Delay
        mov     cx,     word ptr Delay+2
        int     15h
        pop     dx
        pop     cx
        pop     ax
        ret
WaitFor endp
 
; преобразования строки в число
; на входе:
; ds:[si] - строка с числом
; ds:[di] - адрес числа
; на выходе
; ds:[di] - число
; CY - флаг переноса (при ошибке - установлен, иначе - сброшен)
Str2Num proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    ds
        push    es
 
        push    ds
        pop     es
 
        mov     cl, ds:[si]
        xor     ch, ch
 
        inc     si
 
        mov     bx, 10
        xor     ax, ax
 
@@Loop:
        mul     bx         ; умножаем ax на 10 ( dx:ax=ax*bx )
        mov     [di], ax   ; игнорируем старшее слово
        cmp     dx, 0      ; проверяем, результат на переполнение
        jnz     @@Error
 
        mov     al, [si]   ; Преобразуем следующий символ в число
        cmp     al, '0'
        jb      @@Error
        cmp     al, '9'
        ja      @@Error
        sub     al, '0'
        xor     ah, ah
        add     ax, [di]
        jc      @@Error    ; Если сумма больше 65535
        inc     si
 
        loop    @@Loop
 
        mov     [di], ax
        clc
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
@@Error:
        xor     ax, ax
        mov     [di], ax
        stc
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Str2Num endp
 
end     main

@hartmeyerorum8 · 29.04.2017, 19:29 **[ТС]**

Спасибо вам огромное!

@hartmeyerorum8 · 17.05.2017, 11:39 **[ТС]**

ФедосеевПавел, извиняюсь, а как сделать в этой программе прерывания по ESC?

@Jin X · 17.05.2017, 14:31

hartmeyerorum8, основной цикл:

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
        ;цикл генерации звуковых ступеней
        mov     ax,     Fstart
        mov     cx,     N
@@For:
        call    Sound
        call    WaitFor
        call    No_Sound
        sub     ax,     deltaF
 
        mov     ah,1
        int     16h
        jz      @@Loop
        xor     ah,ah
        int     16h
        cmp     ah,1
        je      @@Skip
@@Loop:        
        loop    @@For
@@Skip:
        mov     ax,     4C00h
        int     21h

Добавлено через 1 минуту
Теоретически можно убрать строки 12-14 (и 17), но тогда нажатия клавиша не будет "поглощена" и сработает после выхода из программы.

@hartmeyerorum8 · 17.05.2017, 15:54 **[ТС]**

Jin X, спасибо, а можно как-то сделать, чтобы пищание не звучало по циклу 4 раза, после того, как я вставил ваш кусок кода, а только один раз? Пробовал сделать, но что-то не то.

@Jin X · 18.05.2017, 00:04

hartmeyerorum8, ой, забыл ax сохранить

Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
LOCALS
 
.model small
 
.stack 100h
 
.data
 
        Fstart  equ     1000    ;начальная частота
        Ffinish equ     100     ;конечная частота
        N       equ     100     ;количество ступеней
        deltaF  equ     (Fstart-Ffinish)/N      ;приращение частоты
        T       dw      0       ;время звучания ступени в милисекундах
        Delay   dd      0       ;время задержки в микросекундах для WaitFor
 
        kbdBuf  db      6,0,7 dup(0)    ;буфер ффода с клавиатуры
        CrLf    db      0Dh, 0Ah, '$'
        Prompt  db      'Input T (miliseconds): ', 0Dh, 0Ah, '$'
.code
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
@@InputT:
        mov     ah,     09h
        lea     dx,     Prompt
        int     21h
 
        mov     ah,     0Ah
        lea     dx,     kbdBuf
        int     21h
 
        lea     si,     kbdBuf+1
        lea     di,     T
        call    Str2Num
 
        mov     ah,     09h
        lea     dx,     CrLf
        int     21h
 
        ;пересчёт времени звучания в микросекунды
        mov     ax,     1000
        mul     T
        mov     word ptr Delay, ax
        mov     word ptr Delay+2,dx
 
        ;цикл генерации звуковых ступеней
        mov     dx,     Fstart
        mov     cx,     N
@@For:
        mov     ax,dx
        call    Sound
        call    WaitFor
        call    No_Sound
        sub     ax,     deltaF
        mov     dx,ax
 
        mov     ah,1
        int     16h
        jz      @@Loop
        xor     ah,ah
        int     16h
        cmp     ah,1
        je      @@Skip
@@Loop:        
        loop    @@For
@@Skip:
        mov     ax,     4C00h
        int     21h
main    endp
 
;Подача звука через встроенный спикер
;ах - частота звука
Sound      proc     near
    push     ax        ;сохранить регистры
    push     bx
    push     dx
    mov      bx,ax     ;частота
    mov      ax,34DDh
    mov      dx,12h    ;(dx,ax)=1193181
    cmp      dx,bx     ;если bx < 18Гц, то выход
    jnb      Done      ;чтобы избежать переполнения
    div      bx        ;ax=(dx,ax)/bx
    mov      bx,ax     ;счетчик таймера
    in       al,61h    ;порт РВ
    or       al,3      ;установить биты 0-1
    out      61h,al
    mov      al,00001011b   ;управляющее слово таймера:
                        ;канал 2, режим 3, двоичное слово
    mov      dx,43h    ;вывод в регистр режима
    out      dx,al     ;устанавливаем режим работы таймера
    dec      dx    ;порт 2-го канала
    mov      al,bl     ;младший байт счетчика
    out      dx,al     ;записываем
    mov      al,bh     ;старший байт счетчика
    out      dx,al     ;записываем
Done:   pop      dx        ;восстановить регистры
    pop      bx
    pop      ax
    ret        ;выход из подпрограммы
Sound      endp
 
;Прекращение подачи звука через встроенный спикер
No_Sound   proc     near
    push    ax  ;сохраняем регистр
    in  al,61h  ;порт РВ
    and al,not 3;сброс битов 0-1
    out 61h,al  ;возвращаем значение в порт
    pop ax  ;восстанавливаем регистр
    ret     ;выход из подпрограммы
No_Sound   endp
 
;Ожидание
;на входе:
; переменная Delay - время ожидания в микросекундах
WaitFor proc
        push    ax
        push    cx
        push    dx
        mov     ah,     86h
        mov     al,     00h
        mov     dx,     word ptr Delay
        mov     cx,     word ptr Delay+2
        int     15h
        pop     dx
        pop     cx
        pop     ax
        ret
WaitFor endp
 
; преобразования строки в число
; на входе:
; ds:[si] - строка с числом
; ds:[di] - адрес числа
; на выходе
; ds:[di] - число
; CY - флаг переноса (при ошибке - установлен, иначе - сброшен)
Str2Num proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    ds
        push    es
 
        push    ds
        pop     es
 
        mov     cl, ds:[si]
        xor     ch, ch
 
        inc     si
 
        mov     bx, 10
        xor     ax, ax
 
@@Loop:
        mul     bx         ; умножаем ax на 10 ( dx:ax=ax*bx )
        mov     [di], ax   ; игнорируем старшее слово
        cmp     dx, 0      ; проверяем, результат на переполнение
        jnz     @@Error
 
        mov     al, [si]   ; Преобразуем следующий символ в число
        cmp     al, '0'
        jb      @@Error
        cmp     al, '9'
        ja      @@Error
        sub     al, '0'
        xor     ah, ah
        add     ax, [di]
        jc      @@Error    ; Если сумма больше 65535
        inc     si
 
        loop    @@Loop
 
        mov     [di], ax
        clc
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
@@Error:
        xor     ax, ax
        mov     [di], ax
        stc
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Str2Num endp
 
end     main

@hartmeyerorum8 · 18.05.2017, 11:44 **[ТС]**

Jin X, благодарю, выручили.

Новые блоги и статьи Все статьи Все блоги /
Символьное дифференцирование igorrr37 13.02.2026 / * Логарифм записывается как: (x-2)log(x^2+2) - означает логарифм (x^2+2) по основанию (x-2). Унарный минус обозначается как ! */ #include <iostream> #include <stack> #include <cctype>. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .	И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»
SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL3_image 8Observer8 10.02.2026 Содержание блога Библиотека SDL3_image содержит инструменты для расширенной работы с изображениями. Пошагово создадим проект для загрузки изображения формата PNG с альфа-каналом (с прозрачным. . .	Установка Qt-версии Lazarus IDE в Debian Trixie Xfce volvo 10.02.2026 В общем, достали меня глюки IDE Лазаруса, собранной с использованием набора виджетов Gtk2 (конкретно: если набирать текст в редакторе и вызвать подсказку через Ctrl+Space, то после закрытия окошка. . .

@hartmeyerorum8 0 / 0 / 0 Регистрация: 12.03.2017 Сообщений: 38

	Составить программу формирования звуковых сигналов в соответствии с диаграммой 24.04.2017, 15:20. Показов 5454. Ответов 11 Метки нет (Все метки) Пару месяцев изучаем ассемблер, но ничего толком нам не объясняют. Дали вот такую задачу, в качестве итоговой, но я почти ничего не понимаю в этом. Помогите, пожалуйста. Составить программу формирования звуковых сигналов в соответствии с диаграммой, которая представлена "лестницей" из 100 ступеней c убывающей частотой звука. Первая ступень частотой 1000, вторая 900, третья 800 и т.д. Интервал времени звучания каждой ступени равен T. Интервал времени T задать с клавиатуры, прерывание по ESC, число ступеней 100. Миниатюры 0

@Jin X Asm/C++/Delphi/Py/PHP/VBA 6812 / 2052 / 238 Регистрация: 14.12.2014 Сообщений: 4,304 Записей в блоге: 12
	24.04.2017, 17:54
	Вот вам в лом перепечатать задание (мы должны эти каракули разбирать). И даже фотку развернуть нормально не можете. А кто-то должен за вас всё сделать... Если надо помочь (а не сделать всё за вас), показывайте что сделано и где проблема конкретно. Правила 4.7. Как можно более полно описывайте суть проблемы или вопроса, что было сделано для ее решения и какие результаты получены. 5.18. Запрещено размещать задания и решения в виде картинок и других файлов с их текстом. 1

@hartmeyerorum8 0 / 0 / 0 Регистрация: 12.03.2017 Сообщений: 38
	24.04.2017, 18:34 [ТС]
	Извиняюсь. К сожалению, я ничего не могу сделать, так как не понимаю как. Переписал задание: Составить программу формирования звуковых сигналов в соответствии с диаграммой, которая представлена "лестницей" из 100 ступеней c убывающей частотой звука. Первая ступень частотой 1000, вторая 900, третья 800 и т.д. Интервал времени звучания каждой ступени равен T. Интервал времени T задать с клавиатуры, прерывание по ESC, число ступеней 100. 0

@Mikl___ Ушел с форума 16373 / 7685 / 1080 Регистрация: 11.11.2010 Сообщений: 13,759
	24.04.2017, 18:39
	hartmeyerorum8, ищи в сети Джордейн Р. "Справочник программиста персональных компьютеров типа IBM PC, XT и AT". В ней найдешь главу о формировании звука системным динамиком и готовую программу 1

ФедосеевПавел Модератор 8655 / 4491 / 1669 Регистрация: 01.02.2015 Сообщений: 13,899 Записей в блоге: 12
	24.04.2017, 21:39
	https://www.cyberforum.ru/asm-... 50903.html 0

@hartmeyerorum8 0 / 0 / 0 Регистрация: 12.03.2017 Сообщений: 38
	29.04.2017, 19:29 [ТС]
	Спасибо вам огромное! 0

@hartmeyerorum8 0 / 0 / 0 Регистрация: 12.03.2017 Сообщений: 38
	17.05.2017, 11:39 [ТС]
	ФедосеевПавел, извиняюсь, а как сделать в этой программе прерывания по ESC? 0

@hartmeyerorum8 0 / 0 / 0 Регистрация: 12.03.2017 Сообщений: 38
	17.05.2017, 15:54 [ТС]
	Jin X, спасибо, а можно как-то сделать, чтобы пищание не звучало по циклу 4 раза, после того, как я вставил ваш кусок кода, а только один раз? Пробовал сделать, но что-то не то. 0

@hartmeyerorum8 0 / 0 / 0 Регистрация: 12.03.2017 Сообщений: 38
	18.05.2017, 11:44 [ТС]
	Jin X, благодарю, выручили. 0

Составить программу формирования звуковых сигналов в соответствии с диаграммой

Решение