Генерация звуковых сигналов

LOCALS
 
.model small
 
.stack 100h
 
.data
 
        Fstart  equ     100     ;начальная частота
        Ffinish equ     5000    ;конечная частота
        N       equ     100     ;количество ступеней
        deltaF  equ     (Ffinish-Fstart)/N      ;приращение частоты
        Tsound  dw      10      ;время звучания ступени в милисекундах
        Tpause  dw      0       ;длительность паузы в милисекундах
        Ts      dd      0       ;время звучания ступени в микросекундах
        Tp      dd      0       ;длительность паузы в микросекундах
 
        Delay   dd      0       ;время задержки в микросекундах для WaitFor
 
        kbdBuf  db      6,0,7 dup(0)    ;буфер ффода с клавиатуры
        CrLf    db      0Dh, 0Ah, '$'
        Prompt  db      'Input Pause (miliseconds): ', 0Dh, 0Ah, '$'
.code
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
@@InputT:
        mov     ah,     09h
        lea     dx,     Prompt
        int     21h
 
        mov     ah,     0Ah
        lea     dx,     kbdBuf
        int     21h
 
        lea     si,     kbdBuf+1
        lea     di,     Tpause
        call    Str2Num
 
        mov     ah,     09h
        lea     dx,     CrLf
        int     21h
 
        ;пересчёт времени  в микросекунды
        mov     ax,     1000
        mul     Tpause
        mov     word ptr Tp, ax
        mov     word ptr Tp+2,dx
 
        mov     ax,     1000
        mul     Tsound
        mov     word ptr Ts, ax
        mov     word ptr Ts+2,dx
 
        ;цикл генерации звуковых ступеней
@@Loop:
        mov     ax,     word ptr Ts
        mov     word ptr Delay, ax
        mov     ax,     word ptr Ts+2
        mov     word ptr Delay+2,ax
 
        mov     ax,     Fstart
        mov     cx,     N
@@ForIncrease:
 
        call    Sound
        call    WaitFor
        call    No_Sound
        add     ax,     deltaF
 
        push    ax
        mov     ah,     01h
        int     16h
        pop     ax
        jz      @@NextIncrease
        push    ax
        mov     ah,     00h
        int     16h
        cmp     al,     1Bh
        pop     ax
        jz      @@Break
@@NextIncrease:
        loop    @@ForIncrease
 
        mov     ax,     Ffinish
        mov     cx,     N
@@ForDecrease:
        call    Sound
        call    WaitFor
        call    No_Sound
        sub     ax,     deltaF
 
        push    ax
        mov     ah,     01h
        int     16h
        pop     ax
        jz      @@NextDecrease
        push    ax
        mov     ah,     00h
        int     16h
        cmp     al,     1Bh
        pop     ax
        jz      @@Break
@@NextDecrease:
 
        loop    @@ForDecrease
 
        mov     ax,     word ptr Tp
        mov     word ptr Delay, ax
        mov     ax,     word ptr Tp+2
        mov     word ptr Delay+2,ax
        call    WaitFor
 
        jmp     @@Loop
 
@@Break:
        call    No_Sound
 
        mov     ax,     4C00h
        int     21h
main    endp
 
;Подача звука через встроенный спикер
;ах - частота звука
Sound      proc     near
    push     ax        ;сохранить регистры
    push     bx
    push     dx
    mov      bx,ax     ;частота
    mov      ax,34DDh
    mov      dx,12h    ;(dx,ax)=1193181
    cmp      dx,bx     ;если bx < 18Гц, то выход
    jnb      Done      ;чтобы избежать переполнения
    div      bx        ;ax=(dx,ax)/bx
    mov      bx,ax     ;счетчик таймера
    in       al,61h    ;порт РВ
    or       al,3      ;установить биты 0-1
    out      61h,al
    mov      al,00001011b   ;управляющее слово таймера:
                        ;канал 2, режим 3, двоичное слово
    mov      dx,43h    ;вывод в регистр режима
    out      dx,al     ;устанавливаем режим работы таймера
    dec      dx    ;порт 2-го канала
    mov      al,bl     ;младший байт счетчика
    out      dx,al     ;записываем
    mov      al,bh     ;старший байт счетчика
    out      dx,al     ;записываем
Done:   pop      dx        ;восстановить регистры
    pop      bx
    pop      ax
    ret        ;выход из подпрограммы
Sound      endp
 
;Прекращение подачи звука через встроенный спикер
No_Sound   proc     near
    push    ax  ;сохраняем регистр
    in  al,61h  ;порт РВ
    and al,not 3;сброс битов 0-1
    out 61h,al  ;возвращаем значение в порт
    pop ax  ;восстанавливаем регистр
    ret     ;выход из подпрограммы
No_Sound   endp
 
;Ожидание
;на входе:
; переменная Delay - время ожидания в микросекундах
WaitFor proc
        push    ax
        push    cx
        push    dx
        mov     ah,     86h
        mov     al,     00h
        mov     dx,     word ptr Delay
        mov     cx,     word ptr Delay+2
        int     15h
        pop     dx
        pop     cx
        pop     ax
        ret
WaitFor endp
 
; преобразования строки в число
; на входе:
; ds:[si] - строка с числом
; ds:[di] - адрес числа
; на выходе
; ds:[di] - число
; CY - флаг переноса (при ошибке - установлен, иначе - сброшен)
Str2Num proc
        push    ax
        push    bx
        push    cx
        push    dx
        push    ds
        push    es
 
        push    ds
        pop     es
 
        mov     cl, ds:[si]
        xor     ch, ch
 
        inc     si
 
        mov     bx, 10
        xor     ax, ax
 
@@Loop:
        mul     bx         ; умножаем ax на 10 ( dx:ax=ax*bx )
        mov     [di], ax   ; игнорируем старшее слово
        cmp     dx, 0      ; проверяем, результат на переполнение
        jnz     @@Error
 
        mov     al, [si]   ; Преобразуем следующий символ в число
        cmp     al, '0'
        jb      @@Error
        cmp     al, '9'
        ja      @@Error
        sub     al, '0'
        xor     ah, ah
        add     ax, [di]
        jc      @@Error    ; Если сумма больше 65535
        inc     si
 
        loop    @@Loop
 
        mov     [di], ax
        clc
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
@@Error:
        xor     ax, ax
        mov     [di], ax
        stc
        pop     es
        pop     ds
        pop     dx
        pop     cx
        pop     bx
        pop     ax
        ret
Str2Num endp
 
end     main