Составить программу формирования звуковых сигналов

LOCALS
 
.model small
 
.stack 100h
 
.data
        Delay   dd      1000000 ;время задержки в микросекундах для WaitFor
        kbEsc   db      1Bh     ;код ESC
.code
 
main    proc
        mov     ax,     @data
        mov     ds,     ax
 
        ;100 Гц
        mov     ax,     100
        call    Sound
        call    WaitFor
        call    No_Sound
        call    WaitFor
        ;500 Гц
        mov     ax,     500
        call    Sound
        call    WaitFor
        call    No_Sound
        call    WaitFor
        ;1000 Гц
        mov     ax,     1000
        call    Sound
        call    WaitFor
        call    No_Sound
        call    WaitFor
 
        ;5000 Гц
        mov     ax,     5000
        call    Sound
 
@@WaitEscapePressed:
        mov     ah,     08h
        int     21h
        cmp     al,     kbEsc
        jnz     @@WaitEscapePressed
 
        call    No_Sound
 
        mov     ax,     4C00h
        int     21h
main    endp
 
;Подача звука через встроенный спикер
;ах - частота звука
Sound      proc     near
    push     ax        ;сохранить регистры
    push     bx
    push     dx
    mov      bx,ax     ;частота
    mov      ax,34DDh
    mov      dx,12h    ;(dx,ax)=1193181
    cmp      dx,bx     ;если bx < 18Гц, то выход
    jnb      Done      ;чтобы избежать переполнения
    div      bx        ;ax=(dx,ax)/bx
    mov      bx,ax     ;счетчик таймера
    in       al,61h    ;порт РВ
    or       al,3      ;установить биты 0-1
    out      61h,al
    mov      al,00001011b   ;управляющее слово таймера:
                        ;канал 2, режим 3, двоичное слово
    mov      dx,43h    ;вывод в регистр режима
    out      dx,al     ;устанавливаем режим работы таймера
    dec      dx    ;порт 2-го канала
    mov      al,bl     ;младший байт счетчика
    out      dx,al     ;записываем
    mov      al,bh     ;старший байт счетчика
    out      dx,al     ;записываем
Done:   pop      dx        ;восстановить регистры
    pop      bx
    pop      ax
    ret        ;выход из подпрограммы
Sound      endp
 
;Прекращение подачи звука через встроенный спикер
No_Sound   proc     near
    push    ax  ;сохраняем регистр
    in  al,61h  ;порт РВ
    and al,not 3;сброс битов 0-1
    out 61h,al  ;возвращаем значение в порт
    pop ax  ;восстанавливаем регистр
    ret     ;выход из подпрограммы
No_Sound   endp
 
;Ожидание
;на входе:
; переменная Delay - время ожидания в микросекундах
WaitFor proc
        push    ax
        push    cx
        push    dx
        mov     ah,     86h
        mov     al,     00h
        mov     dx,     word ptr Delay
        mov     cx,     word ptr Delay+2
        int     15h
        pop     dx
        pop     cx
        pop     ax
        ret
WaitFor endp
 
end     main