[Am186ES] Копировать данные из ячейки памяти в txt файл постоянно с периодом 2 мс

.model small
 
.stack 200h
 
.data
        szFileName              db      "data.dat", 0
        ;номер прерывания, изменяющего значение в ячейке - источнике данных
        IntN                    =       8
        ;размер буфера
        BufSize                 =       256;1 shl 12
        ;количество сохраняемых в файл буферов
        BufferCountMax          =       4
        ;адрес ячейки памяти - источника данных
        SrcSeg                  =       0040h
        SrcOffs                 =       006Ch
.data?
        Buffer1                 db      BufSize dup (?)
        Buffer2                 db      BufSize dup (?)
        BufPos                  dw      ?
        BufferToRead            dw      ?
        BufferMode1             dw      ?
        BufferMode2             dw      ?
        BuffersCount            dw      ?
        hFile                   dw      ?
.code
 
NewIntHandler   proc
        PUBLIC  old_int
        ;вызов исходного прерывания
        pushf
        call    dword ptr cs:[old_int]
        ;обработка результатов исходного прерывания:
        push    ax
        push    si
        push    ds
        mov     ax,     SrcSeg
        mov     ds,     ax
        mov     ax,     ds:[SrcOffs]
        mov     si,     @data
        mov     ds,     si
        ; - если активный буфер для данных готов для чтения, то взять его адрес
        cmp     [BufferToRead], 0
        jnz     @@buffer2
                cmp     [BufferMode1],  'R'
                jne     @@exit
                lea     si,     [Buffer1]
                jmp     @@end_if
        @@buffer2:
                cmp     [BufferMode2],  'R'
                jne     @@exit
                lea     si,     [Buffer2]
        @@end_if:
        ; - для активного готового буфера сохранить в текущую позицию
        ;считанные данные
        add     si,     [BufPos]
        mov     [si],   ax
        ; - если буфер заполнен, то пометить его готовым к записи в файл
        ;и сделать активным другой буфер
        mov     si,     [BufPos]
        add     si,     2
        cmp     si,     BufSize
        jb      @@upd_indx
                xor     si,     si
                cmp     [BufferToRead], 0
                jnz     @@upd_state_buf2
                        mov     [BufferMode1],  'W'
                        mov     [BufferToRead], 1
                        jmp     @@upd_indx
                @@upd_state_buf2:
                        mov     [BufferMode2],  'W'
                        mov     [BufferToRead], 0
        @@upd_indx:
        ; - обновить текущую позицию в буфере
        mov     [BufPos],       si
@@exit:
        pop     ds
        pop     si
        pop     ax
 
        iret
 
old_int dd      0               ; адрес старого обработчика
 
NewIntHandler   endp
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
        ;инициализация переменных:
        mov     [BufferMode1],  'R'     ;буфер 1 готов к записи данных от внешнего источника
        mov     [BufferMode2],  'R'     ;буфер 2 готов к записи данных от внешнего источника
        mov     [BufferToRead], 0       ;активен для записи буфер 1
        mov     [BufPos],       0
        mov     [BuffersCount], 0       ;записано в файл 0 буферов
        ;открытие файла для записи
        mov     ah,     3Ch
        mov     cx,     0       ;FileAttr
        lea     dx,     [szFileName]
        int     21h
        mov     [hFile],        ax
 
        ;установка нового прерывания
        mov     ax,     0
        mov     es,     ax
        mov     ax,     es:[IntN*4]
        mov     word ptr cs:[old_int],  ax
        mov     ax,     es:[IntN*4+2]
        mov     word ptr cs:[old_int+2],ax
        cli
        mov     word ptr es:[IntN*4],   offset NewIntHandler
        mov     word ptr es:[IntN*4+2], cs
        sti
        ;рабочий цикл:
        @@repeat:
                ; - если буфер готов для записи в файл
                cmp     [BufferMode1],  'W'
                jnz     @@test_buffer2
                lea     dx,     [Buffer1]
                mov     ax,     0
                jmp     @@store_buffer_to_file
        @@test_buffer2:
                cmp     [BufferMode2],  'W'
                jnz     @@until
                lea     dx,     [Buffer2]
                mov     ax,     1
        @@store_buffer_to_file:
                ; - то записать его в файл
                push    ax
                mov     ah,     40h
                mov     bx,     [hFile]
                mov     cx,     BufSize
                ;lea    dx,     [Buffer]
                int     21h
                inc     [BuffersCount]
                ; - пометить буфер готовым к приёму данных
                pop     ax
                cmp     ax,     0
                jnz     @@2
                        mov     [BufferMode1],  'R'     ;буфер 1 не готов к записи в файл
                        jmp     @@until
                @@2:
                        mov     [BufferMode2],  'R'     ;буфер 2 не готов к записи в файл
        @@until:
                cmp     [BuffersCount], BufferCountMax
        jb      @@repeat
        ;восстановление исходного прерывания
        push    ds
        lds     dx,     dword ptr cs:[old_int]  ; DS:DX = адрес обработчика
        mov     ax,     0
        mov     es,     ax
        cli
        mov     word ptr es:[IntN*4],    dx
        mov     word ptr es:[IntN*4+2],  ds
        sti
        pop     ds
        ;закрытие файла
        mov     ah,     3Eh
        mov     bx,     [hFile]
        int     21h
        ;завершение программы
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main