Создание файла

; masm dos com #
.model tiny
.286
.CODE
org 100h
BEGIN:  mov ah,3Ch
    mov cx,0; атрибуты файла
    mov dx,offset filename
    int 21h
    retn
filename db 'myfile.txt',0
END BEGIN

; masm dos com #
.286
.model tiny
.code
org 100h
start:  mov ah,5Bh
    mov cx,0; атрибуты файла
    mov dx,offset filename
    int 21h
    retn
filename db 'myfile.txt',0
end start

; masm dos com #
.286
.model tiny
.code
org 100h
start:  mov cx,0; атрибуты файла - обычный файл
    mov bx,2 ;режим доступа чтение-запись
    mov dx,10h 
    mov si,offset filename;указатель на имя файла 
    mov ah,6Ch
    int 21h ;создаем файл 
    retn
filename db 'myfile.txt',0
end start

; masm dos com #
.286
.model tiny
.code
org 100h
start:  mov cx,0; атрибуты файла - обычный файл
    mov bx,2 ;режим доступа чтение-запись
    mov dx,10h 
    mov si,offset filename;указатель на имя файла 
    mov ax,716Ch
    int 21h 
    retn
filename db 'myfile.txt',0
end start

; masm dos com #
.286
.model tiny
.code
org 100h
FCB struct
    drive_num   db ?
    file_name   db 8 dup(20h)
    file_ext    db 3 dup(20h)
    block_num   dw ?
    record_size dw ?
    file_size   dd ?
    file_data   dw ?
    rezerved    db 10 dup(?)
    current_rec db ?
    random_rec  dd ?
FCB ends
start:  mov ah,16h
    mov dx,offset fcb
    int 21h
    ret
fcb FCB <0,'myfile','txt'>
;0 - диск по умолчанию, далее 8-байтовое имя файла
;если меньше, то заполняется пробелами, далее 3-байтовое расширение
end start

; masm dos com #
.286
.model tiny
.code
org 100h
start:  mov bx,100h ;выделим блок памяти в 256 параграфов
    mov ah,4Ah       
    int 21h
    mov bx,offset parametrs ;указываем на блок параметров
    mov [bx+4],cs
    mov dx,offset filename
    mov ax,4B00h;загрузить и выполнить программу из командной строки
    int 21h
    retn        ;выход в DOS
command_line db N,'/c copy nul myfile.txt',0Dh
N = $-command_line-1;длина командной строки
;командная строка типа pascal, начинается с байта длины строки, заканчивается
;ASCII-кодом клавиши Enter (0Dh). При передаче команды CMD.EXE нужно указать /С перед 
;строкой (требование вызова вторичного командного процессора). Программу cmd.exe
;из папки windows\system32\ проще разместить в том же каталоге, что и программа
filename db 'cmd.exe',0
parametrs dw 0,command_line,5 dup(0);блок параметров
end start

; masm dos com #
.286
.model tiny
.code
org     100h
start:  mov ah,4Ah  ;модифицируем назначенную память
    mov bx,100h     ;новый размер блока в параграфах
    int 21h         
    mov bx,0FFFFh   ;требуемое число параметров для выполнения
    mov ah,48h  ;вделить блок памяти
    int 21h     ;возвращает в bx размер наибольшего доступного блока 
;памяти в параграфах
    mov ah,48h  ;вделить блок памяти, в bx действительно доступная память
    int 21h         ;возвращает в ах сегментный адрес выделенного блока
    mov es,ax       ;es:=new PSP
    mov ss,ax       ;ss:=new PSP
    xchg dx,ax      ;dx:=new PSP
    mov ah,26h  ;создать новый префикс программного сегмента
    int 21h         
    mov dx,offset filename
    mov di,80h      ;указатель на командную строку
    mov cx,(N+1)/2  ;копируем по два байта за раз, N округлен в большую 
;сторону к числу кратному два, поэтому добавочный movsb не нужен
    mov si,offset command_line
    rep movsw       ;создаем командную строку для запуска command.com
        mov ax,3D00h    ;открыть command.com на чтение
    int 21h
    xchg bx,ax  ;дескриптор файла в bx
    xor cx,cx       ;cx=dx=0
    xor dx,dx
    mov ax,4202h    ;установить файловый указатель на конец файла
    int 21h
    push ax         ;сохраним в стеке длину файла command.com
    mov ax,4200h    ;установить файловый указатель на начало файла
    int 21h
    mov dx,es       ;пересчитываем чему должен быть равен dx из расчета,
    add dx,10h      ;что cs*10h+dx=es*10h+100h
    mov cx,cs
    sub dx,cx
    shl dx,4        ;в dx адрес буфера, куда будет скопирован command.com
    pop cx      ;в сх число байтов для чтения 
    mov ah,3Fh  ;читаем command.com в буфер
    int 21h
    mov ah,3Eh  ;закрыть файл command.com
    int 21h
    mov ax,es       ;ds:=new PSP
    mov ds,ax       ;при старте СОМ-файла cs=ds=es=ss=PSP ip=100h
    push es         ;новое значение cs:=new PSP
    push 100h       ;новое значение ip:=100h
    retf            ;запускаем command.com для создания файла myfile.txt
filename db 'c:\windows\system32\command.com',0;полный путь к command.com
command_line db N-1,'/c copy > myfile.txt',0Dh
N = $ - command_line
db 0; если N нечетное, то скопируется и добавочный нулевой символ 
end     start

; masm dos com #
.286
.model tiny
.code
org 100h
start:
;получаем дальний адрес (cs:ip) обработчика 
;прерывания 21h из таблицы векторов прерывания
    push 0;сегментный адрес  таблицы векторов прерывания в es  
    pop es      
    mov di,es:[21h*4];смещение обработчика прерывания 21h в di
    mov si,es:[21h*4+2];сегмент обработчика прерывания 21h в si
;параметры для функции 3Ch прерывания 21h
    mov cx,0    ;аттрибуты файла (обычный файл)
    mov dx,offset filename;имя создаваемого файла
    mov ah,3Ch      ;номер функции
;три параметра в стек для возврата из прерывания
    pushf           
        push cs
        push offset @f  ;адрес возврата
;имитируем вызов int 21h
    push si     ;cs для int 21h
    push di     ;ip для int 21h
    retf        ;подменяем cs и ip
@@: mov ah,4Ch      ;выход из программы
    int 21h
filename db 'myfile.txt',0
end start

; masm dos com #
.286
.model tiny
.code
org 100h
FCB struct
    drive_num   db ?
    file_name   db 8 dup(20h)
    file_ext    db 3 dup(20h)
    block_num   dw ?
    record_size dw ?
    file_size   dd ?
    file_data   dw ?
    rezerved    db 10 dup(?)
    current_rec db ?
    random_rec  dd ?
FCB ends
start:  push offset @f    ; Занести в стек флаги, сегмент
    push cs           ;    и смещение адреса возврата
    pushf             ;    в обратном порядке.
    mov cl,16h
    mov dx,offset fcb
    jmp dword ptr ALT_DOS_PTR ; Выполнить функцию.
@@: mov ah,4Ch
    int 21h 
fcb FCB <0,'myfile','txt'>
;0 - диск по умолчанию, далее 8-байтовое имя файла
;если меньше, то заполняется пробелами, далее 3-байтовое расширение
ALT_DOS_PTR dw  0C0h,0;адрес для перехода в альтернативный обработчик
end start