ActiveX EXE ! ✰

Option Explicit
 
Private Const p = " "
Private Const INFINITE = -1&
Private Const SYNCHRONIZE = &H100000
'
Private Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
'
Dim m_Fso As Object
Const mOCX = "Dialogs.ocx"
'
Private Property Get Fso() As Object 'As FileSystemObject '
    If m_Fso Is Nothing Then Set m_Fso = CreateObject("Scripting.FileSystemObject")
    Set Fso = m_Fso
End Property
'
 
Private Function RegSvr32(ByVal Path$, Optional Reg As Boolean = True) As Boolean
    '
    'Возвращает утверждение о зарегестрированной dll // Ocx
    'Арг: Зарегить/Отменить регистрацию
    '
    Dim hProc&, hShell&, Path34$
    On Error Resume Next
    Path = Fso.GetAbsolutePathName(Replace(Path, Chr(34), vbNullString))
    If Fso.FileExists(Path) = False Then Exit Function
    Path34 = Chr(34) & Path & Chr(34)
    hShell = Shell(IIf(Reg, "RegSvr32 /s", "RegSvr32 /s /u") & p & Path34)
    hProc = OpenProcess(SYNCHRONIZE, False, hShell)
    WaitForSingleObject hProc, 1000 'Подождать процесс регистрации
    CloseHandle hProc
    RegSvr32 = True
End Function
 
Private Sub Class_Initialize()
    Call RegSvr32(mOCX, True)
End Sub
 
Private Sub Class_Terminate()
    Call RegSvr32(mOCX, False)
End Sub