OwenLogic: перенос сетевых переменных в панель Weintek (EasyBuilder Pro)

@chcp 1251>nul
 
@rem Размещение утилиты - потокового редактора sed
@set sed_exe="C:\Program Files\binutils\ssed.exe"
@rem set sed_exe="C:\Program Files\binutils\sed\bin\sed.exe"
@set iconv_exe="C:\Program Files\binutils\iconv\bin\iconv.exe"
 
@rem Название исходного файла с экспортируемыми из Owen Logic тегами
@set source="ПР205_экспорт_сетевых_переменных_Slave.csv"
@rem Название итогового файла с тегами для Easy Builder (Weintek)
@set "target=result.csv"
@rem Название устройства, уже описанного в системных параметрах проекта Easy Builder
@rem Лучше на латинице, т.к. многобайтные символы сложнее обрабатывать
@set "device_name=MODBUS RTU (Zero-based Addressing)"
 
@rem Временный файл
@set "tmp_file=temp.$$1"
@rem Регулярное выражение для выделения полей в csv экспортируемых тегов
@set "field=([^;]*)[;]"
 
@rem Названия типов данных в кодировке UTF-8
@set "Owen_Unsigned_16=Long"
@set Owen_Float_32=Float
@set "Weintek_Unsigned_16=16-bit Unsigned"
@set "Weintek_Float_32=32-bit Float"
 
@rem Удалить заголовок (напечатать c 3 по последнюю строку)
@%sed_exe% -n "3,$p" %source%>%tmp_file%
@rem Переставить поля
@%sed_exe% -n -r "s/%field%%field%%field%%field%%field%%field%.*/\1\,%device_name%\,3x\,\4\,\"\6\"\,\2/p" %tmp_file%>%target%
@rem Заменить тип регистра "Long" на "16-bit Unsigned"
@rem Заменить тип регистра "Float" на "32-bit Float"
@%sed_exe% -r "s/%Owen_Unsigned_16%$/%Weintek_Unsigned_16%/" %target%>%tmp_file%
@%sed_exe% -r "s/%Owen_Float_32%$/%Weintek_Float_32%/" %tmp_file%>%target%
 
@rem Изменить кодировку с UTF-8 на CP1251
@%sed_exe% -n "1,$p" %target%>%tmp_file%
@%iconv_exe% -f UTF-8 -t CP1251 %tmp_file%>%target%
@del %tmp_file%