Перенести задачу с Pascal на С++

Program Matches;
 
Const
TaskID='f';
InFile=TaskID+'.in';
OutFile=TaskID+'.out';
 
Const
MaxN=42; { Ограничение на N }
MaxG=2*MaxN+1; { Ограничение на число вершин в графе }
Infinity=MaxLongInt; { "Бесконечное" расстояние }
 
Var
N:Integer; { }
Match:Array[1..MaxN]Of Record { Входные }
X1,Y1,X2,Y2:Integer; { данные }
Time:LongInt; { }
End; { }
 
NG:Integer; { }
Vertex:Array[1..MaxG]Of Record { }
X,Y:Integer; { Граф }
End; { }
Edge,Distance:Array[1..MaxG,1..MaxG]Of LongInt; { }
 
Res:Extended; { Минимальное время сгорания }
ResX,ResY:Integer; { Оптимальная точка поджога }
 
Procedure Load;
Var
I:Integer;
Begin
Assign(Input,InFile);
ReSet(Input);
Read(N);
For I:=1 To N Do 
With Match[I] Do
Read(X1,Y1,X2,Y2,Time);
Close(Input);
End;
 
 
 
Function GetVertex(VX,VY:Integer):Integer; 
{ Функция, возвращающая номер вершины с заданными координатами.
При отсутствии нужной вершины она создаётся }
Var
I:Integer;
Begin
For I:=1 To NG Do
With Vertex[I] Do
If (X=VX) And (Y=VY) Then Begin
GetVertex:=I;
Exit;
End;
 
Inc(NG); { Если нужная вершина не найдена }
With Vertex[NG] Do Begin
X:=VX;
Y:=VY;
For I:=1 To NG-1 Do Begin
Edge[I,NG]:=Infinity;
Edge[NG,I]:=Infinity;
End;
Edge[NG,NG]:=0;
End;
GetVertex:=NG;
End;
 
Procedure AddEdge(X1,Y1,X2,Y2:Integer; Time:Longint);
{ Функция, добавляющая ребро между двумя точками }
Var
A,B:Integer;
Begin
A:=GetVertex(X1,Y1);
B:=GetVertex(X2,Y2);
Edge[A,B]:=Time;
Edge[B,A]:=Time;
End;
 
Procedure BuildGraph; { Процедура построения графа }
Var
I:Integer;
Begin
NG:=0;
For I:=1 To N Do 
With Match[I] Do Begin
AddEdge(X1*2,Y1*2,X1+X2,Y1+Y2,Time);
AddEdge(X1+X2,Y1+Y2,X2*2,Y2*2,Time);
End;
End;
 
Procedure FindShortestPaths;
Var
K,I,J:Integer;
Begin
Distance:=Edge;
For K:=1 To NG Do
For I:=1 To NG Do If Distance[I,K]<Infinity Then
For J:=1 To NG Do If Distance[K,J]<Infinity Then
If Distance[I,K]+Distance[K,J]<Distance[I,J] Then
Distance[I,J]:=Distance[I,K]+Distance[K,J];
End;
 
 
 
Function BurnAt(At:Integer):Extended;
{ Функция, вычисляющая время сгорания при поджоге в точке At }
Var
I,J:Integer;
Cur,ThisEdge:Extended;
Begin
Cur:=0;
For I:=1 To NG Do If Distance[At,I]>Cur Then Cur:=Distance[At,I];
For I:=1 To NG Do
For J:=I+1 To NG Do If Edge[I,J]<Infinity Then Begin
If (Distance[At,I]<Distance[At,J]+Edge[I,J]) And 
(Distance[At,J]<Distance[At,I]+Edge[I,J]) Then Begin
If Distance[At,I]<Distance[At,J] Then
ThisEdge:=Distance[At,J]+(Edge[I,J]-(Distance[At,J]-Distance[At,I]))/2
Else
ThisEdge:=Distance[At,I]+(Edge[I,J]-(Distance[At,I]-Distance[At,J]))/2;
If ThisEdge>Cur Then Cur:=ThisEdge;
End;
End;
BurnAt:=Cur;
End;
 
Procedure Solve;
Var
I:Integer;
Cur:Extended;
Begin
Res:=Infinity;
For I:=1 To NG Do
With Vertex[I] Do
If Not Odd(X) And Not Odd(Y) Then Begin
Cur:=BurnAt(I);
If Cur<Res Then Begin
Res:=Cur;
ResX:=X Div 2;
ResY:=Y Div 2;
End;
End;
End;
 
Procedure Save;
Begin
Assign(Output,OutFile);
ReWrite(Output);
WriteLn(ResX,' ',ResY);
WriteLn(Res/2:0:2);
Close(Output);
End;
 
Begin
Load;
BuildGraph;
FindShortestPaths;
Solve;
Save;
End.