Как отслеживать состояние формы (а именно ее перемещение) в период работы программы?

type
  TVForm = class abstract(TForm)
  private
    procedure WMMove(var Msg: TWMMove); message WM_MOVE; // <--- обработчик сообщения
  protected
    procedure DoMove; virtual; // <--- диспетчеризация 
  published
    property OnMove: TNotifyEvent read FOnMove write FOnMove; // <--- событие
  end;
 
implementation
 
procedure TVForm.DoMove;
begin
  if Assigned(FOnMove)
    then FOnMove(Self);
end;
 
procedure TVForm.WMMove(var Msg: TWMMove);
begin
  DoMove();
end;

procedure TForm1.FormCanResize(Sender: TObject; var NewWidth, NewHeight: Integer; var Resize: Boolean);
begin
  Label1.Caption := IntToStr(Form1.Left) + ' ' + IntToStr(Form1.Top)
end;

unit Unit1;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;
 
type
  TMoveEvent = procedure(Sender: TObject; const X,Y: integer) of object;
 
  TForm = class abstract(Vcl.Forms.TForm)
  strict private
    FOnMove: TMoveEvent;
  protected
    procedure WMMove(var msg: TWMMove); message WM_MOVE;
  public
    property OnMove: TMoveEvent read FOnMove write FOnMove;
  end;
 
  TForm1 = class(TForm)
    Label1: TLabel;
    procedure CatchMoving(Sender: TObject; const X,Y: integer);
    procedure FormCreate(Sender: TObject);
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
{ TForm }
 
procedure TForm.WMMove(var msg: TWMMove);
begin
  inherited;
  if Assigned(FOnMove) then FOnMove(Self,msg.XPos,msg.YPos);
end;
 
{ TForm1 }
 
procedure TForm1.CatchMoving(Sender: TObject; const X, Y: integer);
begin
  Label1.Caption:= Format('X: %d; Y: %d',[X,Y]);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  OnMove:= CatchMoving;
end;
 
end.